push sheeet

pkgs/by-name/ta/taskflow/package.nix

@@ -0,0 +1,57 @@
+{
+  cmake,
+  doctest,
+  fetchFromGitHub,
+  lib,
+  replaceVars,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "taskflow";
+  version = "3.10.0";
+
+  src = fetchFromGitHub {
+    owner = "taskflow";
+    repo = "taskflow";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-s0A8zJoq0VfmAks9h4v63J7tPX5JnlNTzJJMilzc5yM=";
+  };
+
+  patches = [
+    (replaceVars ./unvendor-doctest.patch {
+      inherit doctest;
+    })
+  ];
+
+  postPatch = ''
+    rm -r 3rd-party
+
+    # tries to use x86 intrinsics on aarch64-darwin
+    sed -i '/^#if __has_include (<immintrin\.h>)/,/^#endif/d' taskflow/utility/os.hpp
+  '';
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  cmakeFlags = [
+    # building the tests implies running them in the buildPhase
+    (lib.cmakeBool "TF_BUILD_TESTS" finalAttrs.finalPackage.doCheck)
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "General-purpose Parallel and Heterogeneous Task Programming System";
+    homepage = "https://taskflow.github.io/";
+    changelog =
+      let
+        release = lib.replaceStrings [ "." ] [ "-" ] finalAttrs.version;
+      in
+      "https://taskflow.github.io/taskflow/release-${release}.html";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ dotlambda ];
+  };
+})

pkgs/by-name/ta/taskflow/unvendor-doctest.patch

@@ -0,0 +1,21 @@
+diff --git a/unittests/CMakeLists.txt b/unittests/CMakeLists.txt
+index c1fef333..eaf387ea 100644
+--- a/unittests/CMakeLists.txt
++++ b/unittests/CMakeLists.txt
+@@ -1,6 +1,6 @@
+ enable_testing()
+ 
+-include(${TF_3RD_PARTY_DIR}/doctest/doctest.cmake)
++include(@doctest@/lib/cmake/doctest/doctest.cmake)
+ 
+ list(APPEND TF_UNITTESTS 
+   test_utility 
+@@ -44,7 +44,7 @@ endif()
+ foreach(unittest IN LISTS TF_UNITTESTS)
+   add_executable(${unittest} ${unittest}.cpp)
+   target_link_libraries(${unittest} ${PROJECT_NAME} ${ATOMIC_LIBRARY} tf::default_settings)
+-  target_include_directories(${unittest} PRIVATE ${TF_3RD_PARTY_DIR}/doctest)
++  target_include_directories(${unittest} PRIVATE @doctest@/include/doctest)
+   doctest_discover_tests(${unittest})
+ endforeach()
+