push sheeet

pkgs/by-name/tb/tbls/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  testers,
+  tbls,
+}:
+
+buildGoModule rec {
+  pname = "tbls";
+  version = "1.89.0";
+
+  src = fetchFromGitHub {
+    owner = "k1LoW";
+    repo = "tbls";
+    tag = "v${version}";
+    hash = "sha256-zgn1/GEfF4K23JqoI6OjqzmvutnAVhmmt0sEp+1b2DE=";
+  };
+
+  vendorHash = "sha256-hupOff2cJ+UrJFgMyDu3XYvEjyE/XvvyqiQq408wJsw=";
+
+  excludedPackages = [ "scripts/jsonschema" ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  CGO_CFLAGS = [ "-Wno-format-security" ];
+
+  preCheck = ''
+    # Remove tests that require additional services.
+    rm -f \
+       datasource/*_test.go \
+       drivers/*/*_test.go
+  '';
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd tbls \
+      --bash <($out/bin/tbls completion bash) \
+      --fish <($out/bin/tbls completion fish) \
+      --zsh <($out/bin/tbls completion zsh)
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = tbls;
+    command = "tbls version";
+    inherit version;
+  };
+
+  meta = {
+    description = "Tool to generate documentation based on a database structure";
+    homepage = "https://github.com/k1LoW/tbls";
+    changelog = "https://github.com/k1LoW/tbls/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ azahi ];
+    mainProgram = "tbls";
+  };
+}

pkgs/by-name/tb/tboot/package.nix

@@ -0,0 +1,57 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  openssl,
+  perl,
+  trousers,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "tboot";
+  version = "1.11.9";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/tboot/${pname}-${version}.tar.gz";
+    hash = "sha256-uCbJatmt1qYLuWdCATeCS4mNrpJ+UUBJa1rDgjE37Z0=";
+  };
+
+  buildInputs = [
+    openssl
+    trousers
+    zlib
+  ];
+
+  enableParallelBuilding = true;
+
+  preConfigure = ''
+    substituteInPlace tboot/Makefile --replace /usr/bin/perl ${perl}/bin/perl
+
+    for a in lcptools-v2 tb_polgen utils; do
+      substituteInPlace "$a/Makefile" --replace /usr/sbin /sbin
+    done
+    substituteInPlace docs/Makefile --replace /usr/share /share
+  '';
+
+  postPatch = ''
+    # compute the allocated size from the pointed type, to avoid the warning
+    substituteInPlace lcptools-v2/pconf_legacy.c \
+      --replace-fail "digest = malloc(SHA1_DIGEST_SIZE);" \
+        "digest = malloc(sizeof *digest);"
+  '';
+
+  installFlags = [ "DESTDIR=$(out)" ];
+
+  meta = {
+    description = "Pre-kernel/VMM module that uses Intel(R) TXT to perform a measured and verified launch of an OS kernel/VMM";
+    homepage = "https://sourceforge.net/projects/tboot/";
+    changelog = "https://sourceforge.net/p/tboot/code/ci/v${version}/tree/CHANGELOG";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ ak ];
+    platforms = [
+      "x86_64-linux"
+      "i686-linux"
+    ];
+  };
+}

pkgs/by-name/tb/tbox/libtbox.pc.in

@@ -0,0 +1,10 @@
+prefix=@out@
+exec_prefix=${prefix}
+libdir=@out@/lib
+includedir=@out@/include
+
+Name: tbox
+Description: A glib-like multi-platform c library
+Version: @version@
+Libs: -L${libdir} -ltbox
+Cflags: -I${includedir}

pkgs/by-name/tb/tbox/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "tbox";
+  version = "1.7.7";
+
+  src = fetchFromGitHub {
+    owner = "tboox";
+    repo = "tbox";
+    rev = "v${version}";
+    hash = "sha256-piPfPg3NAvP2zhWgtPlNvlAHoqIU77TE/kd1B/6GIuc=";
+  };
+
+  configureFlags = [
+    "--hash=y"
+    "--charset=y"
+    "--float=y"
+    "--demo=n"
+  ];
+
+  postInstall = ''
+    mkdir -p $out/lib/pkgconfig
+    substituteAll ${./libtbox.pc.in} $out/lib/pkgconfig/libtbox.pc
+  '';
+
+  meta = with lib; {
+    description = "Glib-like multi-platform c library";
+    homepage = "https://docs.tboox.org";
+    license = licenses.asl20;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ wineee ];
+  };
+}

pkgs/by-name/tb/tbtools/package.nix

@@ -0,0 +1,46 @@
+{
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  pkg-config,
+  rustPlatform,
+  stdenv,
+  systemd,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "tbtools";
+  version = "0.6.0";
+
+  src = fetchFromGitHub {
+    owner = "intel";
+    repo = "tbtools";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-xLMnB8KliwHVU5y4L7K0a43gfdhLKFxnAx4wxGL9xMc=";
+  };
+
+  cargoHash = "sha256-QuiDI2/XzhUKF7BGnoKeJ2143keJtmi+8WG1MpulLZo=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    systemd
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Thunderbolt/USB4 debugging tools";
+    homepage = "https://github.com/intel/tbtools";
+    license = lib.licenses.mit;
+    mainProgram = "tblist";
+    maintainers = with lib.maintainers; [
+      felixsinger
+    ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/tb/tbump/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  fetchPypi,
+  python3Packages,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "tbump";
+  version = "6.11.0";
+  pyproject = true;
+
+  disabled = python3Packages.pythonOlder "3.8";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "tbump";
+    hash = "sha256-OF5xDu3wqKb/lZzx6fPP0XyHNhcTL8DsX2Ka8MNVyHA=";
+  };
+
+  pythonRelaxDeps = [ "tomlkit" ];
+
+  build-system = with python3Packages; [ poetry-core ];
+
+  dependencies = with python3Packages; [
+    docopt
+    schema
+    packaging
+    poetry-core
+    tomlkit
+    cli-ui
+  ];
+
+  meta = {
+    description = "Bump software releases";
+    homepage = "https://github.com/your-tools/tbump";
+    license = lib.licenses.bsd3;
+    mainProgram = "tbump";
+    maintainers = with lib.maintainers; [ slashformotion ];
+  };
+}