push sheeet

pkgs/by-name/tx/txr/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  coreutils,
+  libffi,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "txr";
+  version = "302";
+
+  src = fetchurl {
+    url = "https://www.kylheku.com/cgit/txr/snapshot/txr-${finalAttrs.version}.tar.bz2";
+    hash = "sha256-8N4BLtYiGOBJ0Jo5rmqTh1mNjqwSp8LX2dkGwnw271Q=";
+  };
+
+  buildInputs = [ libffi ];
+
+  enableParallelBuilding = true;
+
+  doCheck = true;
+  checkTarget = "tests";
+
+  postPatch = ''
+    substituteInPlace tests/017/realpath.tl --replace /usr/bin /bin
+    substituteInPlace tests/017/realpath.expected --replace /usr/bin /bin
+
+    substituteInPlace tests/018/process.tl --replace /usr/bin/env ${lib.getBin coreutils}/bin/env
+  '';
+
+  preCheck =
+    let
+      disabledTests = lib.concatStringsSep " " [
+        # - tries to set sticky bits
+        "tests/018/chmod.tl"
+        # - warning: unbound function crypt
+        "tests/018/crypt.tl"
+      ];
+    in
+    ''
+      rm ${disabledTests}
+    '';
+
+  postInstall = ''
+    mkdir -p $out/share/vim-plugins/txr/{syntax,ftdetect}
+
+    cp {tl,txr}.vim $out/share/vim-plugins/txr/syntax/
+
+    cat > $out/share/vim-plugins/txr/ftdetect/txr.vim <<EOF
+      au BufRead,BufNewFile *.txr set filetype=txr | set lisp
+      au BufRead,BufNewFile *.tl,*.tlo set filetype=tl | set lisp
+    EOF
+    mkdir -p $out/share/nvim
+    ln -s $out/share/vim-plugins/txr $out/share/nvim/site
+  '';
+
+  meta = {
+    homepage = "https://nongnu.org/txr";
+    description = "Original, New Programming Language for Convenient Data Munging";
+    longDescription = ''
+      TXR is a general-purpose, multi-paradigm programming language. It
+      comprises two languages integrated into a single tool: a text scanning and
+      extraction language referred to as the TXR Pattern Language (sometimes
+      just "TXR"), and a general-purpose dialect of Lisp called TXR Lisp.
+
+      TXR can be used for everything from "one liner" data transformation tasks
+      at the command line, to data scanning and extracting scripts, to full
+      application development in a wide range of areas.
+    '';
+    changelog = "https://www.kylheku.com/cgit/txr/tree/RELNOTES?h=txr-${finalAttrs.version}";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [
+      dtzWill
+    ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/tx/txt2man/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  coreutils,
+  gawk,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "txt2man";
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "mvertes";
+    repo = "txt2man";
+    rev = "txt2man-${version}";
+    hash = "sha256-Aqi5PNNaaM/tr9A/7vKeafYKYIs/kHbwHzE7+R/9r9s=";
+  };
+
+  makeFlags = [
+    "prefix=${placeholder "out"}"
+  ];
+
+  postPatch = ''
+    for f in bookman src2man txt2man; do
+      substituteInPlace $f \
+        --replace "gawk" "${gawk}/bin/gawk" \
+        --replace "(date" "(${coreutils}/bin/date" \
+        --replace "=cat" "=${coreutils}/bin/cat" \
+        --replace "cat <<" "${coreutils}/bin/cat <<" \
+        --replace "expand" "${coreutils}/bin/expand" \
+        --replace "(uname" "(${coreutils}/bin/uname"
+    done
+  '';
+
+  doCheck = true;
+
+  checkPhase = ''
+    # gawk and coreutils are part of stdenv but will not
+    # necessarily be in PATH at runtime.
+    sh -c 'unset PATH; printf hello | ./txt2man'
+  '';
+
+  meta = with lib; {
+    description = "Convert flat ASCII text to man page format";
+    homepage = "http://mvertes.free.fr/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ bjornfor ];
+  };
+}

pkgs/by-name/tx/txt2tags/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "txt2tags";
+  version = "3.9";
+
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "txt2tags";
+    repo = "txt2tags";
+    tag = version;
+    hash = "sha256-PwPGJJg79ny13gEb1WmgIVHcXQppI/j5mhIyOZjR19k=";
+  };
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  postPatch = ''
+    substituteInPlace test/lib.py \
+      --replace-fail 'TXT2TAGS = os.path.join(TEST_DIR, "..", "txt2tags.py")' \
+                     'TXT2TAGS = "${placeholder "out"}/bin/txt2tags"' \
+      --replace-fail "[PYTHON] + TXT2TAGS" "TXT2TAGS"
+  '';
+
+  checkPhase = ''
+    ${python3.interpreter} test/run.py
+  '';
+
+  pythonImportsCheck = [ "txt2tags" ];
+
+  meta = {
+    changelog = "https://github.com/txt2tags/txt2tags/blob/${src.rev}/CHANGELOG.md";
+    description = "Convert between markup languages";
+    mainProgram = "txt2tags";
+    homepage = "https://txt2tags.org/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      dotlambda
+      kovirobi
+    ];
+  };
+}

pkgs/by-name/tx/txtpbfmt/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+buildGoModule {
+  pname = "txtpbfmt";
+  version = "0-unstable-2025-09-03";
+
+  src = fetchFromGitHub {
+    owner = "protocolbuffers";
+    repo = "txtpbfmt";
+    rev = "cf07efcaeff78f7d945f844d506daf4cad5a9229";
+    hash = "sha256-A/rmMtYLaTEkP02DLaYu/1nwaQ7EWacvcl0ri5Zx5zs=";
+  };
+
+  vendorHash = "sha256-iWY0b6PAw9BhA8WrTEECnVAKWTGXuIiGvOi9uhJO4PI=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version=branch" ];
+  };
+
+  meta = {
+    description = "Formatter for text proto files";
+    homepage = "https://github.com/protocolbuffers/txtpbfmt";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ aaronjheng ];
+    mainProgram = "txtpbfmt";
+  };
+}

pkgs/by-name/tx/txtw/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cairo,
+}:
+
+stdenv.mkDerivation rec {
+  version = "0.4";
+  pname = "txtw";
+
+  src = fetchFromGitHub {
+    owner = "baskerville";
+    repo = "txtw";
+    rev = version;
+    sha256 = "17yjdgdd080fsf5r1wzgk6vvzwsa15gcwc9z64v7x588jm1ryy3k";
+  };
+
+  buildInputs = [ cairo ];
+
+  prePatch = ''sed -i "s@/usr/local@$out@" Makefile'';
+
+  meta = with lib; {
+    description = "Compute text widths";
+    homepage = "https://github.com/baskerville/txtw";
+    maintainers = with maintainers; [ lihop ];
+    license = licenses.unlicense;
+    platforms = platforms.linux;
+    mainProgram = "txtw";
+  };
+}