push sheeet

pkgs/by-name/ty/typst/package.nix

@@ -0,0 +1,79 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  openssl,
+  nix-update-script,
+  versionCheckHook,
+  callPackage,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "typst";
+  version = "0.13.1";
+
+  src = fetchFromGitHub {
+    owner = "typst";
+    repo = "typst";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-vbBwIQt4xWZaKpXgFwDsRQIQ0mmsQPRR39m8iZnnuj0=";
+  };
+
+  cargoHash = "sha256-4kVj2BODEFjLcrh5sxfcgsdLF2Zd3K1GnhA4DEz1Nl4=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+  ];
+
+  env = {
+    GEN_ARTIFACTS = "artifacts";
+    OPENSSL_NO_VENDOR = true;
+    # to not have "unknown hash" in help output
+    TYPST_VERSION = finalAttrs.version;
+  };
+
+  # Fix for "Found argument '--test-threads' which wasn't expected, or isn't valid in this context"
+  postPatch = ''
+    substituteInPlace tests/src/tests.rs --replace-fail 'ARGS.num_threads' 'ARGS.test_threads'
+    substituteInPlace tests/src/args.rs --replace-fail 'num_threads' 'test_threads'
+  '';
+
+  postInstall = ''
+    installManPage crates/typst-cli/artifacts/*.1
+    installShellCompletion \
+      crates/typst-cli/artifacts/typst.{bash,fish} \
+      --zsh crates/typst-cli/artifacts/_typst
+  '';
+
+  cargoTestFlags = [ "--workspace" ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  passthru = {
+    updateScript = nix-update-script { };
+    packages = callPackage ./typst-packages.nix { };
+    withPackages = callPackage ./with-packages.nix { };
+  };
+
+  meta = {
+    changelog = "https://github.com/typst/typst/releases/tag/v${finalAttrs.version}";
+    description = "New markup-based typesetting system that is powerful and easy to learn";
+    homepage = "https://github.com/typst/typst";
+    license = lib.licenses.asl20;
+    mainProgram = "typst";
+    maintainers = with lib.maintainers; [
+      figsoda
+      kanashimia
+      RossSmyth
+    ];
+  };
+})

pkgs/by-name/ty/typst/typst-packages.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  callPackage,
+}:
+
+let
+  toPackageName = name: version: "${name}_${lib.replaceStrings [ "." ] [ "_" ] version}";
+in
+lib.makeExtensible (
+  final:
+  lib.recurseIntoAttrs (
+    lib.foldlAttrs (
+      packageSet: pname: versionSet:
+      packageSet
+      // (lib.foldlAttrs (
+        subPackageSet: version: packageSpec:
+        subPackageSet
+        // {
+          ${toPackageName pname version} = callPackage (
+            {
+              lib,
+              buildTypstPackage,
+              fetchzip,
+            }:
+            buildTypstPackage (finalAttrs: {
+              inherit pname version;
+
+              src = fetchzip {
+                inherit (packageSpec) hash;
+                url = "https://packages.typst.org/preview/${finalAttrs.pname}-${finalAttrs.version}.tar.gz";
+                stripRoot = false;
+              };
+
+              typstDeps = builtins.filter (x: x != null) (
+                lib.map (d: (lib.attrsets.attrByPath [ d ] null final)) packageSpec.typstDeps
+              );
+
+              meta = {
+                inherit (packageSpec) description;
+                maintainers = with lib.maintainers; [ cherrypiejam ];
+                license = lib.map (lib.flip lib.getAttr lib.licensesSpdx) packageSpec.license;
+              }
+              // (if packageSpec ? "homepage" then { inherit (packageSpec) homepage; } else { });
+            })
+          ) { };
+        }
+      ) { } versionSet)
+      // {
+        ${pname} = final.${toPackageName pname (lib.last (lib.attrNames versionSet))};
+      }
+    ) { } (lib.importTOML ./typst-packages-from-universe.toml)
+  )
+)

pkgs/by-name/ty/typst/with-packages.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  buildEnv,
+  typstPackages,
+  makeBinaryWrapper,
+  typst,
+}:
+
+lib.makeOverridable (
+  { ... }@typstPkgs:
+  f:
+  buildEnv {
+    inherit (typst) meta;
+    name = "${typst.name}-env";
+
+    paths = lib.foldl' (acc: p: acc ++ lib.singleton p ++ p.propagatedBuildInputs) [ ] (f typstPkgs);
+
+    pathsToLink = [ "/lib/typst-packages" ];
+
+    nativeBuildInputs = [ makeBinaryWrapper ];
+
+    postBuild = ''
+      export TYPST_LIB_DIR="$out/lib/typst/packages"
+      mkdir -p $TYPST_LIB_DIR
+
+      mv $out/lib/typst-packages $TYPST_LIB_DIR/preview
+
+      cp -r ${typst}/share $out/share
+      mkdir -p $out/bin
+
+      makeWrapper "${lib.getExe typst}" "$out/bin/typst" --set TYPST_PACKAGE_CACHE_PATH $TYPST_LIB_DIR
+    '';
+  }
+) typstPackages