push sheeet

pkgs/by-name/ub/ubertooth/package.nix

@@ -0,0 +1,53 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  libbtbb,
+  libpcap,
+  libusb1,
+  bluez,
+  udevGroup ? "ubertooth",
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ubertooth";
+  version = "2020-12-R1";
+
+  src = fetchFromGitHub {
+    owner = "greatscottgadgets";
+    repo = "ubertooth";
+    rev = version;
+    sha256 = "11r5ag2l5xn4pr7ycicm30w9c3ldn9yiqj1sqnjc79csxl2vrcfw";
+  };
+
+  sourceRoot = "${src.name}/host";
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+  buildInputs = [
+    libbtbb
+    libpcap
+    libusb1
+    bluez
+  ];
+
+  cmakeFlags = lib.optionals stdenv.hostPlatform.isLinux [
+    "-DINSTALL_UDEV_RULES=TRUE"
+    "-DUDEV_RULES_PATH=etc/udev/rules.d"
+    "-DUDEV_RULES_GROUP=${udevGroup}"
+  ];
+
+  doInstallCheck = true;
+
+  meta = with lib; {
+    description = "Open source wireless development platform suitable for Bluetooth experimentation";
+    homepage = "https://github.com/greatscottgadgets/ubertooth";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ oxzi ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ub/ubi_reader/package.nix

@@ -0,0 +1,41 @@
+{
+  fetchFromGitHub,
+  gitUpdater,
+  lib,
+  python3,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "ubi_reader";
+  version = "0.8.10";
+  pyproject = true;
+  disabled = python3.pkgs.pythonOlder "3.9";
+
+  src = fetchFromGitHub {
+    owner = "onekey-sec";
+    repo = "ubi_reader";
+    rev = "v${version}";
+    hash = "sha256-fXJiQZ1QWUmkRM+WI8DSIsay9s1w3hKloRuCcUNwZjM=";
+  };
+
+  build-system = [ python3.pkgs.poetry-core ];
+
+  dependencies = [ python3.pkgs.lzallright ];
+
+  # There are no tests in the source
+  doCheck = false;
+
+  passthru = {
+    updateScript = gitUpdater {
+      rev-prefix = "v";
+      ignoredVersions = "_[a-z]+$";
+    };
+  };
+
+  meta = {
+    description = "Python scripts capable of extracting and analyzing the contents of UBI and UBIFS images";
+    homepage = "https://github.com/onekey-sec/ubi_reader";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ vlaci ];
+  };
+}

pkgs/by-name/ub/ubidump/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3,
+}:
+
+python3.pkgs.buildPythonApplication {
+  pname = "ubidump";
+  version = "0-unstable-2023-09-20";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "nlitsme";
+    repo = "ubidump";
+    rev = "c8cffcbb8c2d61ebece81dff643b8eccfe6d5642";
+    sha256 = "sha256-R568pV3bkdpNAexr8tfAbXVpvHEx/9r1KDWhDM+HyVg=";
+  };
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  dependencies = with python3.pkgs; [
+    setuptools # pkg_resources
+    python-lzo
+    crcmod
+  ];
+
+  meta = with lib; {
+    description = "View or extract the contents of UBIFS images";
+    homepage = "https://github.com/nlitsme/ubidump";
+    license = licenses.mit;
+    maintainers = with maintainers; [ sgo ];
+    mainProgram = "ubidump";
+  };
+}

pkgs/by-name/ub/ubports-click/package.nix

@@ -0,0 +1,177 @@
+{
+  fetchFromGitLab,
+  fetchpatch,
+  gitUpdater,
+  lib,
+  stdenv,
+  testers,
+  autoreconfHook,
+  dbus,
+  dbus-test-runner,
+  dpkg,
+  getopt,
+  glib,
+  gobject-introspection,
+  json-glib,
+  libgee,
+  perl,
+  pkg-config,
+  properties-cpp,
+  python3Packages,
+  vala,
+  wrapGAppsHook3,
+}:
+
+let
+  self = python3Packages.buildPythonApplication rec {
+    pname = "click";
+    version = "0.5.2";
+    format = "other";
+
+    src = fetchFromGitLab {
+      owner = "ubports";
+      repo = "development/core/click";
+      rev = version;
+      hash = "sha256-AV3n6tghvpV/6Ew6Lokf8QAGBIMbHFAnp6G4pefVn+8=";
+    };
+
+    patches = [
+      # Remove when version > 0.5.2
+      (fetchpatch {
+        name = "0001-click-fix-Wimplicit-function-declaration.patch";
+        url = "https://gitlab.com/ubports/development/core/click/-/commit/8f654978a12e6f9a0b6ff64296ec5565e3ff5cd0.patch";
+        hash = "sha256-kio+DdtuagUNYEosyQY3q3H+dJM3cLQRW9wUKUcpUTY=";
+      })
+
+      # Remove when version > 0.5.2
+      (fetchpatch {
+        name = "0002-click-Add-uid_t-and-gid_t-to-the-ctypes-_typemap.patch";
+        url = "https://gitlab.com/ubports/development/core/click/-/commit/cbcd23b08b02fa122434e1edd69c2b3dcb6a8793.patch";
+        hash = "sha256-QaWRhxO61wAzULVqPLdJrLuBCr3+NhKmQlEPuYq843I=";
+      })
+    ];
+
+    postPatch = ''
+      # These should be proper Requires, using the header needs their headers
+      substituteInPlace lib/click/click-*.pc.in \
+        --replace-fail 'Requires.private' 'Requires'
+
+      # Don't completely override PKG_CONFIG_PATH
+      substituteInPlace click_package/tests/Makefile.am \
+        --replace-fail 'PKG_CONFIG_PATH=$(top_builddir)/lib/click' 'PKG_CONFIG_PATH=$(top_builddir)/lib/click:$(PKG_CONFIG_PATH)'
+
+      patchShebangs bin/click
+    '';
+
+    strictDeps = true;
+
+    pkgsBuildBuild = [
+      pkg-config
+    ];
+
+    nativeBuildInputs = [
+      autoreconfHook
+      dbus-test-runner # Always checking for this
+      getopt
+      gobject-introspection
+      perl
+      pkg-config
+      vala
+      wrapGAppsHook3
+    ];
+
+    buildInputs = [
+      glib
+      json-glib
+      libgee
+      properties-cpp
+    ];
+
+    propagatedBuildInputs = with python3Packages; [
+      python-debian
+      chardet
+      pygobject3
+      setuptools
+    ];
+
+    nativeCheckInputs = [
+      dbus
+      dpkg
+      python3Packages.unittestCheckHook
+    ];
+
+    checkInputs = with python3Packages; [
+      python-apt
+      six
+    ];
+
+    preConfigure = ''
+      export click_cv_perl_vendorlib=$out/${perl.libPrefix}
+      export PYTHON_INSTALL_FLAGS="--prefix=$out"
+    '';
+
+    configureFlags = [
+      "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
+      "--with-systemduserunitdir=${placeholder "out"}/lib/systemd/user"
+    ];
+
+    enableParallelBuilding = true;
+
+    doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+    disabledTestPaths = [
+      # From apt: Unable to determine a suitable packaging system type
+      "click_package/tests/integration/test_signatures.py"
+      "click_package/tests/test_build.py"
+      "click_package/tests/test_install.py"
+      "click_package/tests/test_scripts.py"
+    ];
+
+    preCheck = ''
+      export HOME=$TMP
+
+      # tests recompile some files for loaded predefines, doesn't use any optimisation level for it
+      # makes test output harder to read, so make the warning go away
+      export NIX_CFLAGS_COMPILE+=" -U_FORTIFY_SOURCE"
+
+      # Haven'tbeen able to get them excluded via disabledTest{s,Paths}, just deleting them
+      for path in $disabledTestPaths; do
+        rm -v $path
+      done
+    '';
+
+    preFixup = ''
+      makeWrapperArgs+=(
+        --prefix LD_LIBRARY_PATH : "$out/lib"
+      )
+    '';
+
+    passthru = {
+      updateScript = gitUpdater { };
+    };
+
+    meta = {
+      description = "Tool to build click packages, mainly used for Ubuntu Touch";
+      homepage = "https://gitlab.com/ubports/development/core/click";
+      changelog = "https://gitlab.com/ubports/development/core/click/-/blob/${version}/ChangeLog";
+      license = lib.licenses.gpl3Only;
+      mainProgram = "click";
+      maintainers = with lib.maintainers; [
+        ilyakooo0
+      ];
+      teams = [ lib.teams.lomiri ];
+      platforms = lib.platforms.linux;
+      pkgConfigModules = [
+        "click-0.4"
+      ];
+    };
+  };
+in
+self
+// {
+  passthru = self.passthru // {
+    tests.pkg-config = testers.hasPkgConfigModules {
+      package = self;
+    };
+  };
+}

pkgs/by-name/ub/ubports-pdk/package.nix

@@ -0,0 +1,69 @@
+{
+  stdenvNoCC,
+  lib,
+  fetchFromGitHub,
+  unstableGitUpdater,
+  bash,
+  coreutils,
+  dosfstools,
+  makeWrapper,
+  mtools,
+  wget,
+  which,
+  xz,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "ubports-pdk";
+  version = "0-unstable-2025-06-23";
+
+  src = fetchFromGitHub {
+    owner = "ubports";
+    repo = "ubports-pdk";
+    rev = "f97daec1a96f9427b23e35c8cc12e7c21fe893fd";
+    hash = "sha256-s9GC5TiIQSn5JGRy3TU5COdbcW9cDZZ8eQpflSffyOw=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildInputs = [
+    bash
+    coreutils
+    dosfstools
+    mtools
+    wget
+    which
+    xz
+  ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+
+    install -Dm755 ubuntu-touch-pdk $out/share/ubuntu-touch-pdk/ubuntu-touch-pdk
+    cp -R scripts $out/share/ubuntu-touch-pdk/
+
+    makeWrapper $out/share/ubuntu-touch-pdk/ubuntu-touch-pdk $out/bin/ubuntu-touch-pdk \
+      --prefix PATH : ${lib.makeBinPath finalAttrs.finalPackage.buildInputs}
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    description = "Platform Development Kit for Ubuntu Touch";
+    homepage = "https://github.com/ubports/ubports-pdk";
+    license = lib.licenses.gpl3Only;
+    mainProgram = "ubuntu-touch-pdk";
+    maintainers = with lib.maintainers; [ OPNA2608 ];
+    platforms = lib.platforms.unix;
+    # setup wants to use brew to install extra prerequisites
+    broken = stdenvNoCC.hostPlatform.isDarwin;
+  };
+})

pkgs/by-name/ub/ubridge/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libpcap,
+  nix-update-script,
+  testers,
+  ubridge,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ubridge";
+  version = "0.9.19";
+
+  src = fetchFromGitHub {
+    owner = "GNS3";
+    repo = "ubridge";
+    tag = "v${version}";
+    hash = "sha256-utzXLPF0VszMZORoik5/0lKhiyKO9heKuNO4KPsPVsI=";
+  };
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail "/usr/local/bin" "$out/bin" \
+      --replace-fail "setcap" "#setcap"
+  '';
+
+  buildInputs = [ libpcap ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    install -Dm755 ubridge $out/bin/ubridge
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    tests.version = testers.testVersion {
+      package = ubridge;
+      command = "ubridge -v";
+    };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Bridge for UDP tunnels, Ethernet, TAP, and VMnet interfaces";
+    longDescription = ''
+      uBridge is a simple application to create user-land bridges between
+      various technologies. Currently bridging between UDP tunnels, Ethernet
+      and TAP interfaces is supported. Packet capture is also supported.
+    '';
+    homepage = "https://github.com/GNS3/ubridge";
+    changelog = "https://github.com/GNS3/ubridge/releases/tag/v${version}";
+    license = lib.licenses.gpl3Plus;
+    mainProgram = "ubridge";
+    maintainers = with lib.maintainers; [
+      anthonyroussel
+    ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+  };
+}

pkgs/by-name/ub/ubuntu-classic/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchgit,
+  gitUpdater,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "ubuntu-classic";
+  version = "0.83-6ubuntu2";
+
+  src = fetchgit {
+    url = "https://git.launchpad.net/ubuntu/+source/fonts-ubuntu-classic";
+    rev = "import/${finalAttrs.version}";
+    hash = "sha256-GrpBVgisVu7NklFYqkEqYi0hui/pCHlsM3Ky4mEUq90=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -m444 -Dt $out/share/fonts/truetype/ubuntu *.ttf
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = gitUpdater { rev-prefix = "import/"; };
+
+  meta = with lib; {
+    description = "Ubuntu Classic font";
+    longDescription = "The Ubuntu typeface has been specially
+    created to complement the Ubuntu tone of voice. It has a
+    contemporary style and contains characteristics unique to
+    the Ubuntu brand that convey a precise, reliable and free attitude.";
+    homepage = "https://design.ubuntu.com/font";
+    changelog = "https://git.launchpad.net/ubuntu/+source/fonts-ubuntu-classic/tree/FONTLOG.txt?h=${finalAttrs.src.rev}";
+    license = licenses.ufl;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ bobby285271 ];
+  };
+})

pkgs/by-name/ub/ubuntu-sans-mono/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  gitUpdater,
+  rename,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "ubuntu-sans-mono";
+  version = "1.006";
+
+  src = fetchFromGitHub {
+    owner = "canonical";
+    repo = "Ubuntu-Sans-Mono-fonts";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-EFZZnMZTQHo2Tr9/rtb7C5gAlQ/0uYT+MQ1gKkqQ5hE=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -m444 -Dt $out/share/fonts/truetype/ubuntu-sans fonts/variable/*
+    ${rename}/bin/rename 's/\[.*\]//' $out/share/fonts/truetype/ubuntu-sans/*
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = with lib; {
+    description = "Ubuntu Font Family (Mono)";
+    longDescription = "The Ubuntu Font Family are a set of matching libre/open fonts.
+    The fonts were originally developed in 2010–2011,
+    further expanded and improved in 2015,
+    and expanded again in 2022–2023 when variable fonts were added.";
+    homepage = "https://design.ubuntu.com/font";
+    changelog = "https://github.com/canonical/Ubuntu-Sans-Mono-fonts/blob/${finalAttrs.src.rev}/FONTLOG.txt";
+    license = licenses.ufl;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ jopejoe1 ];
+  };
+})

pkgs/by-name/ub/ubuntu-sans/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  gitUpdater,
+  rename,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "ubuntu-sans";
+  version = "1.006";
+
+  src = fetchFromGitHub {
+    owner = "canonical";
+    repo = "Ubuntu-Sans-fonts";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-PvDNQaOgJUb3/ubhqVSUMfinxfbhuQ0BnqYs3xshrhc=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -m444 -Dt $out/share/fonts/truetype/ubuntu-sans fonts/variable/*
+    ${rename}/bin/rename 's/\[.*\]//' $out/share/fonts/truetype/ubuntu-sans/*
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = with lib; {
+    description = "Ubuntu Font Family";
+    longDescription = "The Ubuntu Font Family are a set of matching libre/open fonts.
+    The fonts were originally developed in 2010–2011,
+    further expanded and improved in 2015,
+    and expanded again in 2022–2023 when variable fonts were added.";
+    homepage = "https://design.ubuntu.com/font";
+    changelog = "https://github.com/canonical/Ubuntu-Sans-fonts/blob/${finalAttrs.src.rev}/FONTLOG.txt";
+    license = licenses.ufl;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ jopejoe1 ];
+  };
+})

pkgs/by-name/ub/ubuntu-themes/package.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gnome-icon-theme,
+  adwaita-icon-theme,
+  gtk-engine-murrine,
+  gtk3,
+  hicolor-icon-theme,
+  humanity-icon-theme,
+  python3Packages,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ubuntu-themes";
+  version = "24.04";
+
+  src = fetchurl {
+    url = "https://launchpad.net/ubuntu/+archive/primary/+sourcefiles/ubuntu-themes/${version}-0ubuntu1/ubuntu-themes_${version}.orig.tar.gz";
+    hash = "sha256-/SMwwDaSUe86SXNe7U9Sh7SzzlC4yOXVA+urAIxeDxk=";
+  };
+
+  nativeBuildInputs = [
+    gtk3
+    python3Packages.python
+  ];
+
+  propagatedBuildInputs = [
+    gnome-icon-theme
+    adwaita-icon-theme
+    humanity-icon-theme
+    hicolor-icon-theme
+  ];
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  dontDropIconThemeCache = true;
+
+  postPatch = ''
+    patchShebangs .
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/themes
+    cp -a Ambiance $out/share/themes
+    cp -a Radiance $out/share/themes
+
+    mkdir -p $out/share/icons
+    cp -a LoginIcons        $out/share/icons
+    cp -a ubuntu-mobile     $out/share/icons
+    cp -a ubuntu-mono-dark  $out/share/icons
+    cp -a ubuntu-mono-light $out/share/icons
+
+    for theme in $out/share/icons/*; do
+      gtk-update-icon-cache $theme
+    done
+
+    mkdir -p $out/share/icons/hicolor/48x48/apps
+    cp -a distributor-logo.png $out/share/icons/hicolor/48x48/apps
+
+    runHook postInstall
+  '';
+
+  dontCheckForBrokenSymlinks = true;
+
+  meta = {
+    description = "Ubuntu monochrome and Suru icon themes, Ambiance and Radiance themes, and Ubuntu artwork";
+    homepage = "https://launchpad.net/ubuntu-themes";
+    license = with lib.licenses; [
+      cc-by-sa-40
+      gpl3
+    ];
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.romildo ];
+  };
+}

pkgs/by-name/ub/ubus/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  cmake,
+  fetchgit,
+  libubox,
+  libjson,
+}:
+
+stdenv.mkDerivation {
+  pname = "ubus";
+  version = "unstable-2023-12-18";
+
+  src = fetchgit {
+    url = "https://git.openwrt.org/project/ubus.git";
+    rev = "65bb027054def3b94a977229fd6ad62ddd32345b";
+    hash = "sha256-n82Ub0IiuvWbnlDCoN+0hjo/1PbplEbc56kuOYMrHxQ=";
+  };
+
+  cmakeFlags = [ "-DBUILD_LUA=OFF" ];
+  buildInputs = [
+    libubox
+    libjson
+  ];
+  nativeBuildInputs = [ cmake ];
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) [
+      "-Wno-error=gnu-folding-constant"
+    ]
+  );
+
+  meta = with lib; {
+    description = "OpenWrt system message/RPC bus";
+    homepage = "https://git.openwrt.org/?p=project/ubus.git;a=summary";
+    license = licenses.lgpl21Only;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ mkg20001 ];
+  };
+}