push sheeet
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s

This commit is contained in:
Dark Steveneq
2025-10-09 14:15:47 +02:00
commit 646b892680
49168 changed files with 5897842 additions and 0 deletions

View File

@@ -0,0 +1,58 @@
{
lib,
stdenv,
fetchurl,
versionCheckHook,
libusb1,
zlib,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "ucon64";
version = "2.2.2";
src = fetchurl {
url = "https://sourceforge.net/projects/ucon64/files/ucon64/ucon64-${finalAttrs.version}/ucon64-${finalAttrs.version}-src.tar.gz/download";
name = "ucon64-${finalAttrs.version}-src.tar.gz";
hash = "sha256-4QCtSjD2wZq96Y42HGoOysTkBHf1TPt1SYxczSH7Ohg=";
};
buildInputs = [
zlib
libusb1
];
sourceRoot = "ucon64-${finalAttrs.version}-src/src";
# Disable parallel on ARM (sys/io.h is x86-only)
configureFlags = lib.optionals (!stdenv.hostPlatform.isx86) [
"--disable-parallel"
];
makeFlags = [
"CC=${stdenv.cc.targetPrefix}cc"
];
installPhase = ''
runHook preInstall
install -Dm755 ucon64 -t $out/bin/
runHook postInstall
'';
nativeInstallCheckInputs = [
versionCheckHook
];
versionCheckProgramArg = "--version";
doInstallCheck = true;
meta = {
description = "Tool to backup video game cartridges and perform various ROM operations";
homepage = "https://ucon64.sourceforge.io/";
license = lib.licenses.gpl2Plus;
maintainers = with lib.maintainers; [ liberodark ];
mainProgram = "ucon64";
};
})