push sheeet

pkgs/by-name/uh/uhd/fix-pkg-config.patch

@@ -0,0 +1,48 @@
+From 32944bbdbf2c7611e72ec9828464978ca42824ce Mon Sep 17 00:00:00 2001
+From: Jakob Kukla <jakob.kukla@gmail.com>
+Date: Fri, 12 Sep 2025 10:31:22 +0000
+Subject: [PATCH] cmake: support absolute paths for install dirs in pkg-config
+
+The GNUInstallDirs module supports absolute paths for CMAKE_INSTALL_LIBDIR and CMAKE_INSTALL_INCLUDEDIR. Some package managers like Nix depend on this behaviour. See https://github.com/NixOS/nixpkgs/issues/144170 for the nixpkgs tracking issue.
+---
+ host/CMakeLists.txt | 12 ++++++++++++
+ host/uhd.pc.in      |  4 ++--
+ 2 files changed, 14 insertions(+), 2 deletions(-)
+
+diff --git a/host/CMakeLists.txt b/host/CMakeLists.txt
+index 3e93ea1f0c..4cd0afad9d 100644
+--- a/host/CMakeLists.txt
++++ b/host/CMakeLists.txt
+@@ -559,6 +559,18 @@ if(CMAKE_CROSSCOMPILING)
+     set(UHD_PC_LIBS)
+ endif(CMAKE_CROSSCOMPILING)
+ 
++# Support absolute paths for LIBDIR and INCLUDEDIR
++if(IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
++    set(UHD_PC_LIBDIR "${CMAKE_INSTALL_LIBDIR}")
++else()
++    set(UHD_PC_LIBDIR "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
++endif()
++if(IS_ABSOLUTE "${CMAKE_INSTALL_INCLUDEDIR}")
++    set(UHD_PC_INCLUDEDIR "${CMAKE_INSTALL_INCLUDEDIR}")
++else()
++    set(UHD_PC_INCLUDEDIR "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
++endif()
++
+ configure_file(
+     ${CMAKE_CURRENT_SOURCE_DIR}/uhd.pc.in
+     ${CMAKE_CURRENT_BINARY_DIR}/uhd.pc
+diff --git a/host/uhd.pc.in b/host/uhd.pc.in
+index 4a5f67c969..f121e2fb70 100644
+--- a/host/uhd.pc.in
++++ b/host/uhd.pc.in
+@@ -1,7 +1,7 @@
+ prefix=@CMAKE_INSTALL_PREFIX@
+ exec_prefix=${prefix}
+-libdir=${exec_prefix}/@CMAKE_INSTALL_LIBDIR@
+-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@
++libdir=@UHD_PC_LIBDIR@
++includedir=@UHD_PC_INCLUDEDIR@
+ 
+ Name: @CPACK_PACKAGE_NAME@
+ Description: @CPACK_PACKAGE_DESCRIPTION_SUMMARY@

pkgs/by-name/uh/uhd/package.nix

@@ -0,0 +1,244 @@
+{
+  lib,
+  stdenv,
+  substitute,
+  fetchpatch,
+  fetchurl,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  # See https://files.ettus.com/manual_archive/v3.15.0.0/html/page_build_guide.html for dependencies explanations
+  boost,
+  ncurses,
+  enableCApi ? true,
+  enablePythonApi ? true,
+  python3,
+  enableExamples ? false,
+  enableUtils ? true,
+  libusb1,
+  # Disable dpdk for now due to compilation issues.
+  enableDpdk ? false,
+  dpdk,
+  # Devices
+  enableOctoClock ? true,
+  enableMpmd ? true,
+  enableB100 ? true,
+  enableB200 ? true,
+  enableUsrp1 ? true,
+  enableUsrp2 ? true,
+  enableX300 ? true,
+  enableX400 ? true,
+  enableN300 ? true,
+  enableN320 ? true,
+  enableE300 ? true,
+  enableE320 ? true,
+}:
+
+let
+  inherit (lib) optionals cmakeBool;
+in
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uhd";
+  # NOTE: Use the following command to update the package, and the uhdImageSrc attribute:
+  #
+  #     nix-shell maintainers/scripts/update.nix --argstr package uhd --argstr commit true
+  #
+  version = "4.9.0.0";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "EttusResearch";
+    repo = "uhd";
+    rev = "v${finalAttrs.version}";
+    # The updateScript relies on the `src` using `hash`, and not `sha256. To
+    # update the correct hash for the `src` vs the `uhdImagesSrc`
+    hash = "sha256-XA/ADJ0HjD6DxqFTVMwFa7tRgM56mHAEL+a0paWxKyM=";
+  };
+  # Firmware images are downloaded (pre-built) from the respective release on Github
+  uhdImagesSrc = fetchurl {
+    url = "https://github.com/EttusResearch/uhd/releases/download/v${finalAttrs.version}/uhd-images_${finalAttrs.version}.tar.xz";
+    # Please don't convert this to a hash, in base64, see comment near src's
+    # hash.
+    sha256 = "194gsmvn7gmwj7b1lw9sq0d0y0babbd0q1229qbb3qjc6f6m0p0y";
+  };
+  # This are the minimum required Python dependencies, this attribute might
+  # be useful if you want to build a development environment with a python
+  # interpreter able to import the uhd module.
+  pythonPath =
+    optionals (enablePythonApi || enableUtils) [
+      python3.pkgs.numpy
+      python3.pkgs.setuptools
+    ]
+    ++ optionals enableUtils [
+      python3.pkgs.requests
+      python3.pkgs.six
+
+      /*
+        These deps are needed for the usrp_hwd.py utility, however even if they
+        would have been added here, the utility wouldn't have worked because it
+        depends on an old python library mprpc that is not supported for Python >
+        3.8. See also report upstream:
+        https://github.com/EttusResearch/uhd/issues/744
+
+        python3.pkgs.gevent
+        python3.pkgs.pyudev
+        python3.pkgs.pyroute2
+      */
+    ];
+  passthru = {
+    runtimePython = python3.withPackages (ps: finalAttrs.pythonPath);
+    updateScript = [
+      ./update.sh
+      # Pass it this file name as argument
+      (builtins.unsafeGetAttrPos "pname" finalAttrs.finalPackage).file
+    ];
+  };
+
+  cmakeFlags = [
+    "-DENABLE_LIBUHD=ON"
+    "-DENABLE_USB=ON"
+    # Regardless of doCheck, we want to build the tests to help us gain
+    # confident that the package is OK.
+    "-DENABLE_TESTS=ON"
+    (cmakeBool "ENABLE_EXAMPLES" enableExamples)
+    (cmakeBool "ENABLE_UTILS" enableUtils)
+    (cmakeBool "ENABLE_C_API" enableCApi)
+    (cmakeBool "ENABLE_PYTHON_API" enablePythonApi)
+    /*
+      Otherwise python tests fail. Using a dedicated pythonEnv for either or both
+      nativeBuildInputs and buildInputs makes upstream's cmake scripts fail to
+      install the Python API as reported on our end at [1] (we don't want
+      upstream to think we are in a virtual environment because we use
+      python3.withPackages...).
+
+      Putting simply the python dependencies in the nativeBuildInputs and
+      buildInputs as they are now from some reason makes the `python` in the
+      checkPhase fail to find the python dependencies, as reported at [2]. Even
+      using nativeCheckInputs with the python dependencies, or using a
+      `python3.withPackages` wrapper in nativeCheckInputs, doesn't help, as the
+      `python` found in $PATH first is the one from nativeBuildInputs.
+
+      [1]: https://github.com/NixOS/nixpkgs/pull/307435
+      [2]: https://discourse.nixos.org/t/missing-python-package-in-checkphase/9168/
+
+      Hence we use upstream's provided cmake flag to control which python
+      interpreter they will use to run the the python tests.
+    */
+    "-DRUNTIME_PYTHON_EXECUTABLE=${lib.getExe finalAttrs.passthru.runtimePython}"
+    (cmakeBool "ENABLE_DPDK" enableDpdk)
+    # Devices
+    (cmakeBool "ENABLE_OCTOCLOCK" enableOctoClock)
+    (cmakeBool "ENABLE_MPMD" enableMpmd)
+    (cmakeBool "ENABLE_B100" enableB100)
+    (cmakeBool "ENABLE_B200" enableB200)
+    (cmakeBool "ENABLE_USRP1" enableUsrp1)
+    (cmakeBool "ENABLE_USRP2" enableUsrp2)
+    (cmakeBool "ENABLE_X300" enableX300)
+    (cmakeBool "ENABLE_X400" enableX400)
+    (cmakeBool "ENABLE_N300" enableN300)
+    (cmakeBool "ENABLE_N320" enableN320)
+    (cmakeBool "ENABLE_E300" enableE300)
+    (cmakeBool "ENABLE_E320" enableE320)
+    # TODO: Check if this still needed
+    # ABI differences GCC 7.1
+    # /nix/store/wd6r25miqbk9ia53pp669gn4wrg9n9cj-gcc-7.3.0/include/c++/7.3.0/bits/vector.tcc:394:7: note: parameter passing for argument of type 'std::vector<uhd::range_t>::iterator {aka __gnu_cxx::__normal_iterator<uhd::range_t*, std::vector<uhd::range_t> >}' changed in GCC 7.1
+  ]
+  ++ optionals stdenv.hostPlatform.isAarch32 [
+    "-DCMAKE_CXX_FLAGS=-Wno-psabi"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    # Present both here and in buildInputs for cross compilation.
+    python3
+    python3.pkgs.mako
+    # We add this unconditionally, but actually run wrapPythonPrograms only if
+    # python utilities are enabled
+    python3.pkgs.wrapPython
+  ];
+  buildInputs =
+    finalAttrs.pythonPath
+    ++ [
+      boost
+      libusb1
+    ]
+    ++ optionals enableExamples [
+      ncurses
+      ncurses.dev
+    ]
+    ++ optionals enableDpdk [
+      dpdk
+    ];
+
+  patches = [
+    ./fix-pkg-config.patch
+  ];
+
+  # many tests fails on darwin, according to ofborg
+  doCheck = !stdenv.hostPlatform.isDarwin;
+
+  doInstallCheck = true;
+
+  # Build only the host software
+  preConfigure = "cd host";
+
+  postPhases = [
+    "installFirmware"
+    "removeInstalledTests"
+  ]
+  ++ optionals (enableUtils && stdenv.hostPlatform.isLinux) [
+    "moveUdevRules"
+  ];
+
+  # UHD expects images in `$CMAKE_INSTALL_PREFIX/share/uhd/images`
+  installFirmware = ''
+    mkdir -p "$out/share/uhd/images"
+    tar --strip-components=1 -xvf "${finalAttrs.uhdImagesSrc}" -C "$out/share/uhd/images"
+  '';
+
+  # -DENABLE_TESTS=ON installs the tests, we don't need them in the output
+  removeInstalledTests = ''
+    rm -r $out/lib/uhd/tests
+  '';
+
+  # Moves the udev rules to the standard location, needed only if utils are
+  # enabled
+  moveUdevRules = ''
+    mkdir -p $out/lib/udev/rules.d
+    mv $out/lib/uhd/utils/uhd-usrp.rules $out/lib/udev/rules.d/
+  '';
+
+  # Wrap the python utilities with our pythonPath definition
+  postFixup = lib.optionalString (enablePythonApi && enableUtils) ''
+    wrapPythonPrograms
+  '';
+  disallowedReferences = optionals (!enablePythonApi && !enableUtils) [
+    python3
+  ];
+
+  meta = with lib; {
+    description = "USRP Hardware Driver (for Software Defined Radio)";
+    longDescription = ''
+      The USRP Hardware Driver (UHD) software is the hardware driver for all
+      USRP (Universal Software Radio Peripheral) devices.
+
+      USRP devices are designed and sold by Ettus Research, LLC and its parent
+      company, National Instruments.
+    '';
+    homepage = "https://uhd.ettus.com/";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux ++ platforms.darwin;
+    maintainers = with maintainers; [
+      bjornfor
+      fpletz
+      tomberek
+      doronbehar
+    ];
+  };
+})

pkgs/by-name/uh/uhd/update.sh

@@ -0,0 +1,27 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p jq nix nix-prefetch-github
+
+set -euo pipefail
+echoerr() { echo "$@" 1>&2; }
+
+fname="$1"
+echoerr got fname $fname
+shift
+latest_release=$(curl --silent https://api.github.com/repos/EttusResearch/uhd/releases/latest)
+version=$(jq -r '.tag_name' <<<"$latest_release" | cut -c2-)
+# Update version, if needed
+if grep -q 'version = "'$version $fname; then
+    echoerr Current version $version is the latest available
+    exit 0;
+fi
+echoerr got version $version
+sed -i -E 's/(version = ").*(";)/\1'$version'\2/g' $fname
+# Verify the sed command above did not fail
+grep -q $version $fname
+# Update srcHash
+srcHash="$(nix-prefetch-github EttusResearch uhd --rev v${version} | jq --raw-output .hash)"
+sed -i -E 's#(hash = ").*(";)#\1'$srcHash'\2#g' $fname
+grep -q $srcHash $fname
+imageHash="$(nix-prefetch-url https://github.com/EttusResearch/uhd/releases/download/v${version}/uhd-images_${version}.tar.xz)"
+sed -i -E 's#(sha256 = ").*(";)#\1'$imageHash'\2#g' $fname
+grep -q $imageHash $fname

pkgs/by-name/uh/uhdm/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  python3,
+  capnproto,
+  gtest,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uhdm";
+  # When updating this package, also consider updating surelog
+  version = "1.86";
+
+  src = fetchFromGitHub {
+    owner = "chipsalliance";
+    repo = "UHDM";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-f7QJJEP/jL69DdMJOL5WQdDZU+kBnnLi2eX37AoaXls=";
+    fetchSubmodules = false; # we use all dependencies from nix
+  };
+
+  nativeBuildInputs = [
+    cmake
+    (python3.withPackages (p: with p; [ orderedmultidict ]))
+    gtest
+  ];
+
+  buildInputs = [
+    capnproto
+  ];
+
+  cmakeFlags = [
+    "-DUHDM_USE_HOST_GTEST=On"
+    "-DUHDM_USE_HOST_CAPNP=On"
+  ];
+
+  doCheck = true;
+
+  checkPhase = ''
+    runHook preCheck
+
+    make test
+
+    runHook postCheck
+  '';
+
+  meta = {
+    description = "Universal Hardware Data Model";
+    homepage = "https://github.com/chipsalliance/UHDM";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      matthuszagh
+      hzeller
+    ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/uh/uhexen2/package.nix

@@ -0,0 +1,86 @@
+{
+  lib,
+  fetchgit,
+  SDL,
+  stdenv,
+  alsa-lib,
+  libGL,
+  libogg,
+  libvorbis,
+  libmad,
+  xdelta,
+}:
+
+stdenv.mkDerivation {
+  pname = "uhexen2";
+  version = "1.5.9";
+
+  src = fetchgit {
+    url = "https://git.code.sf.net/p/uhexen2/uhexen2";
+    sha256 = "0crdihbnb92awkikn15mzdpkj1x9s34xixf1r7fxxf762m60niks";
+    rev = "4ef664bc41e3998b0d2a55ff1166dadf34c936be";
+  };
+
+  buildInputs = [
+    SDL
+    alsa-lib
+    libGL
+    libogg
+    libvorbis
+    libmad
+    xdelta
+  ];
+
+  preBuild = ''
+    makeFiles=(
+        "engine/hexen2 glh2"
+        "engine/hexen2 clean"
+        "engine/hexen2 h2"
+        "engine/hexen2/server"
+        "engine/hexenworld/client glhw"
+        "engine/hexenworld/client clean"
+        "engine/hexenworld/client hw"
+        "engine/hexenworld/server"
+        "h2patch"
+    )
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+    for makefile in "''${makeFiles[@]}"; do
+          local flagsArray=(
+            -j$NIX_BUILD_CORES
+            SHELL=$SHELL
+            $makeFlags "''${makeFlagsArray[@]}"
+            $buildFlags "''${buildFlagsArray[@]}"
+          )
+          echoCmd 'build flags' ""''${flagsArray[@]}""
+          make  -C $makefile ""''${flagsArray[@]}""
+          unset flagsArray
+    done
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 engine/hexen2/{glhexen2,hexen2,server/h2ded} -t $out/bin
+    install -Dm755 engine/hexenworld/{client/glhwcl,client/hwcl,server/hwsv} -t $out/bin
+    install -Dm755 h2patch/h2patch -t $out/bin
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    broken = stdenv.hostPlatform.isDarwin;
+    description = "Cross-platform port of Hexen II game";
+    longDescription = ''
+      Hammer of Thyrion (uHexen2) is a cross-platform port of Raven Software's Hexen II source.
+      It is based on an older linux port, Anvil of Thyrion.
+      HoT includes countless bug fixes, improved music, sound and video modes, opengl improvements,
+      support for many operating systems and architectures, and documentation among many others.
+    '';
+    homepage = "https://uhexen2.sourceforge.net/";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ xdhampus ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/uh/uhk-agent/package.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  stdenv,
+  stdenvNoCC,
+  fetchurl,
+  appimageTools,
+  electron,
+  makeWrapper,
+  asar,
+  autoPatchelfHook,
+  libusb1,
+}:
+
+let
+  pname = "uhk-agent";
+  version = "8.0.0";
+
+  src = fetchurl {
+    url = "https://github.com/UltimateHackingKeyboard/agent/releases/download/v${version}/UHK.Agent-${version}-linux-x86_64.AppImage";
+    name = "${pname}-${version}.AppImage";
+    sha256 = "sha256-1XgmGAjLoxJ9ZyeaDSk8UC9fVVwkY83i+DRBRIQz7/M=";
+  };
+
+  appimageContents = appimageTools.extract {
+    inherit pname version src;
+  };
+in
+stdenvNoCC.mkDerivation {
+  inherit pname version src;
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [
+    asar
+    makeWrapper
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    (lib.getLib stdenv.cc.cc)
+    libusb1
+  ];
+
+  autoPatchelfIgnoreMissingDeps = [
+    "libc.musl-x86_64.so.1"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out"/{opt,share/applications}
+
+    cp -r --no-preserve=mode "${appimageContents}/resources"        "$out/opt/${pname}"
+    cp -r --no-preserve=mode "${appimageContents}/usr/share/icons"  "$out/share/icons"
+    cp -r --no-preserve=mode "${appimageContents}/${pname}.desktop" "$out/share/applications/${pname}.desktop"
+
+    substituteInPlace "$out/share/applications/${pname}.desktop" \
+      --replace "Exec=AppRun" "Exec=${pname}"
+
+    asar extract "$out/opt/${pname}/app.asar" "$out/opt/${pname}/app.asar.unpacked"
+    rm           "$out/opt/${pname}/app.asar"
+
+    makeWrapper "${electron}/bin/electron" "$out/bin/${pname}" \
+      --add-flags "$out/opt/${pname}/app.asar.unpacked" \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}" \
+      --set-default ELECTRON_IS_DEV 0 \
+      --inherit-argv0
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Configuration application of the Ultimate Hacking Keyboard";
+    homepage = "https://github.com/UltimateHackingKeyboard/agent";
+    license = licenses.unfreeRedistributable;
+    maintainers = with maintainers; [
+      ngiger
+      nickcao
+    ];
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+  };
+}

pkgs/by-name/uh/uhk-udev-rules/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  uhk-agent,
+  udevCheckHook,
+}:
+
+stdenv.mkDerivation {
+  pname = "uhk-udev-rules";
+  inherit (uhk-agent) version;
+
+  nativeBuildInputs = [
+    udevCheckHook
+  ];
+
+  doInstallCheck = true;
+
+  dontUnpack = true;
+  dontBuild = true;
+  installPhase = ''
+    runHook preInstall
+    install -D -m 644 ${uhk-agent.out}/opt/uhk-agent/rules/50-uhk60.rules $out/lib/udev/rules.d/50-uhk60.rules
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "udev rules for UHK keyboards from https://ultimatehackingkeyboard.com";
+    inherit (uhk-agent.meta) license;
+    maintainers = [ lib.maintainers.ngiger ];
+  };
+}

pkgs/by-name/uh/uhttpmock/package.nix

@@ -0,0 +1,61 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  meson,
+  mesonEmulatorHook,
+  ninja,
+  pkg-config,
+  gobject-introspection,
+  vala,
+  gtk-doc,
+  docbook-xsl-nons,
+  glib,
+  libsoup_2_4,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "uhttpmock";
+  version = "0.5.5";
+
+  outputs = [
+    "out"
+    "dev"
+    "devdoc"
+  ];
+
+  src = fetchFromGitLab {
+    domain = "gitlab.freedesktop.org";
+    owner = "pwithnall";
+    repo = "uhttpmock";
+    rev = version;
+    sha256 = "NuxiVVowZ8ilP9rcgapCe9OzFCpoOfZxZiSyjTeOrts=";
+  };
+
+  strictDeps = true;
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    vala
+    gtk-doc
+    docbook-xsl-nons
+  ]
+  ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
+    mesonEmulatorHook
+  ];
+
+  buildInputs = [
+    glib
+    libsoup_2_4
+  ];
+
+  meta = with lib; {
+    description = "Project for mocking web service APIs which use HTTP or HTTPS";
+    homepage = "https://gitlab.freedesktop.org/pwithnall/uhttpmock/";
+    license = licenses.lgpl21Plus;
+    maintainers = [ ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/uh/uhttpmock_1_0/package.nix

@@ -0,0 +1,62 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  meson,
+  mesonEmulatorHook,
+  ninja,
+  pkg-config,
+  gobject-introspection,
+  vala,
+  gtk-doc,
+  docbook-xsl-nons,
+  glib,
+  libsoup_3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uhttpmock";
+  version = "0.11.0";
+
+  outputs = [
+    "out"
+    "dev"
+    "devdoc"
+  ];
+
+  src = fetchFromGitLab {
+    domain = "gitlab.freedesktop.org";
+    owner = "pwithnall";
+    repo = "uhttpmock";
+    rev = finalAttrs.version;
+    hash = "sha256-itJhiPpAF5dwLrVF2vuNznABqTwEjVj6W8mbv1aEmE4=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    vala
+    gtk-doc
+    docbook-xsl-nons
+  ]
+  ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
+    mesonEmulatorHook
+  ];
+
+  propagatedBuildInputs = [
+    glib
+    libsoup_3
+  ];
+
+  meta = with lib; {
+    description = "Project for mocking web service APIs which use HTTP or HTTPS";
+    homepage = "https://gitlab.freedesktop.org/pwithnall/uhttpmock/";
+    license = licenses.lgpl21Plus;
+    teams = [ teams.gnome ];
+    platforms = platforms.linux;
+  };
+})

pkgs/by-name/uh/uhub/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  openssl,
+  sqlite,
+  pkg-config,
+  systemd,
+  tlsSupport ? false,
+}:
+
+assert tlsSupport -> openssl != null;
+
+stdenv.mkDerivation {
+  pname = "uhub";
+  version = "unstable-2019-12-13";
+
+  src = fetchFromGitHub {
+    owner = "janvidar";
+    repo = "uhub";
+    rev = "35d8088b447527f56609b85b444bd0b10cd67b5c";
+    hash = "sha256-CdTTf82opnpjd7I9TTY+JDEZSfdGFPE0bq/xsafwm/w=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+  buildInputs = [
+    sqlite
+    systemd
+  ]
+  ++ lib.optional tlsSupport openssl;
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace "/usr/lib/uhub/" "$out/plugins" \
+      --replace "/etc/uhub" "$TMPDIR"
+  '';
+
+  cmakeFlags = [
+    "-DSYSTEMD_SUPPORT=ON"
+    "-DSSL_SUPPORT=${if tlsSupport then "ON" else "OFF"}"
+  ];
+
+  meta = with lib; {
+    description = "High performance peer-to-peer hub for the ADC network";
+    homepage = "https://www.uhub.org/";
+    license = licenses.gpl3;
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/uh/uhubctl/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  which,
+  pkg-config,
+  libusb1,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "uhubctl";
+  version = "2.6.0";
+
+  src = fetchFromGitHub {
+    owner = "mvp";
+    repo = "uhubctl";
+    rev = "v${version}";
+    sha256 = "sha256-mpeDePHLsa4sGe2+8X9KQ8AYn7wtybDnaZzxnf4oETQ=";
+  };
+
+  nativeBuildInputs = [
+    which
+    pkg-config
+  ];
+
+  buildInputs = [ libusb1 ];
+
+  installFlags = [ "prefix=${placeholder "out"}" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mvp/uhubctl";
+    description = "Utility to control USB power per-port on smart USB hubs";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [
+      prusnak
+      carlossless
+    ];
+    platforms = with platforms; linux ++ darwin;
+    mainProgram = "uhubctl";
+  };
+}