push sheeet

pkgs/by-name/uu/uucp/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoreconfHook,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uucp";
+  version = "1.07";
+
+  src = fetchurl {
+    url = "mirror://gnu/uucp/uucp-${finalAttrs.version}.tar.gz";
+    sha256 = "0b5nhl9vvif1w3wdipjsk8ckw49jj1w85xw1mmqi3zbcpazia306";
+  };
+
+  hardeningDisable = [ "format" ];
+
+  prePatch = ''
+    # do not set sticky bit in nix store
+    substituteInPlace Makefile.am \
+      --replace-fail 4555 0555
+    sed -i '/chown $(OWNER)/d' Makefile.am
+
+    # don't reply on implicitly defined `exit` function in `HAVE_VOID` test:
+    substituteInPlace configure.in \
+      --replace-fail '(void) exit (0)' '(void) (0)'
+  '';
+
+  patches = [
+    ./socklen_t.patch
+  ];
+
+  # Regenerate `configure`; the checked in version was generated in 2002 and
+  # contains snippets like `main(){return(0);}` that modern compilers dislike.
+  nativeBuildInputs = [ autoreconfHook ];
+
+  makeFlags = [ "AR:=$(AR)" ];
+
+  passthru.tests.version = testers.testVersion {
+    package = finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "Unix-unix cp over serial line, also includes cu program";
+    mainProgram = "uucp";
+
+    longDescription = ''
+      Taylor UUCP is a free implementation of UUCP and is the standard
+      UUCP used on the GNU system.  If you don't know what UUCP is chances
+      are, nowadays, that you won't need it.  If you do need it, you've
+      just found one of the finest UUCP implementations available.
+    '';
+
+    homepage = "https://www.gnu.org/software/uucp/uucp.html";
+
+    license = lib.licenses.gpl2Plus;
+
+    platforms = lib.platforms.all;
+    maintainers = [ ];
+  };
+})

pkgs/by-name/uu/uucp/socklen_t.patch

@@ -0,0 +1,26 @@
+diff --git a/unix/portnm.c b/unix/portnm.c
+index 9eda4ab..019337c 100644
+--- a/unix/portnm.c
++++ b/unix/portnm.c
+@@ -32,7 +32,7 @@ zsysdep_port_name (ftcp_port)
+ 
+ #if HAVE_TCP
+   {
+-    size_t clen;
++    socklen_t clen;
+     struct sockaddr s;
+ 
+     clen = sizeof (struct sockaddr);
+diff --git a/unix/tcp.c b/unix/tcp.c
+index 1bbcec7..af52cab 100644
+--- a/unix/tcp.c
++++ b/unix/tcp.c
+@@ -395,7 +395,7 @@ ftcp_open (qconn, ibaud, fwait, fuser)
+   while (! FGOT_SIGNAL ())
+     {
+       sockaddr_storage speer;
+-      size_t clen;
++      socklen_t clen;
+       int onew;
+       pid_t ipid;
+ 

pkgs/by-name/uu/uudeview/matherr.patch

@@ -0,0 +1,19 @@
+diff --git a/tcl/uutcl.c b/tcl/uutcl.c
+index f101f2ce52b..71c24688dc4 100644
+--- a/tcl/uutcl.c
++++ b/tcl/uutcl.c
+@@ -48,14 +48,6 @@
+ #include <tcl.h>
+ #endif
+
+-/*
+- * The following variable is a special hack that is needed in order for
+- * Sun shared libraries to be used for Tcl.
+- */
+-
+-extern int matherr();
+-int *tclDummyMathPtr = (int *) matherr;
+-
+ #include <uudeview.h>
+ #include <uuint.h>
+ #include <fptools.h>

pkgs/by-name/uu/uudeview/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  tcl,
+  tk,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation {
+  pname = "uudeview";
+  version = "0.5.20-unstable-2025-03-20";
+
+  src = fetchFromGitHub {
+    owner = "hannob";
+    repo = "uudeview";
+    rev = "7640bc56aa5016cdc9c139eb1ab3ec874e47c744";
+    hash = "sha256-IdHxkrXe+2I+aJpZ0bhimXq4xEXE9HDXrL5DtCs7MKk=";
+  };
+
+  buildInputs = [
+    tcl
+    tk
+  ];
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  configureFlags = [
+    "--enable-tk=${tk.dev}"
+    "--enable-tcl=${tcl}"
+  ];
+
+  postPatch = ''
+    substituteInPlace tcl/xdeview --replace "exec uuwish" "exec $out/bin/uuwish"
+  '';
+
+  meta = {
+    description = "Nice and Friendly Decoder";
+    homepage = "http://www.fpx.de/fp/Software/UUDeview/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ woffs ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/uu/uutils-coreutils/package.nix

@@ -0,0 +1,123 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  rustPlatform,
+  cargo,
+  python3Packages,
+  versionCheckHook,
+  nix-update-script,
+
+  prefix ? "uutils-",
+  buildMulticallBinary ? true,
+
+  selinuxSupport ? false,
+  libselinux,
+
+  acl,
+}:
+
+assert selinuxSupport -> lib.meta.availableOn stdenv.hostPlatform libselinux;
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uutils-coreutils";
+  version = "0.2.2";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "coreutils";
+    tag = finalAttrs.version;
+    hash = "sha256-VcwdCi40Tm8J3t0qFSFGvRwW6B5cCDj1wm+H3i20axo=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) src;
+    name = "uutils-coreutils-${finalAttrs.version}";
+    hash = "sha256-/QNOrfqdMviOVP1Fzorc6RAsgLDSKtg/MXfXJEzxwMc=";
+  };
+
+  patches = [
+    ./selinux_no_auto_detect.diff
+  ];
+
+  buildInputs =
+    lib.optionals (lib.meta.availableOn stdenv.hostPlatform acl) [
+      acl
+    ]
+    ++ lib.optionals selinuxSupport [
+      libselinux
+    ];
+
+  nativeBuildInputs = [
+    rustPlatform.bindgenHook
+    rustPlatform.cargoSetupHook
+    python3Packages.sphinx
+  ];
+
+  makeFlags = [
+    "CARGO=${lib.getExe cargo}"
+    "PREFIX=${placeholder "out"}"
+    "PROFILE=release"
+    "SELINUX_ENABLED=${if selinuxSupport then "1" else "0"}"
+    "INSTALLDIR_MAN=${placeholder "out"}/share/man/man1"
+    # Explicitly enable acl, and if requested selinux.
+    # We cannot rely on SELINUX_ENABLED here since our explicit assignment
+    # overrides its effect in the makefile.
+    "BUILD_SPEC_FEATURE=${
+      lib.concatStringsSep "," (
+        # We can always enable acl, on non-Linux, libc provides the headers,
+        # only in Linux we need to add the acl lib to buildInputs.
+        [
+          "feat_acl"
+        ]
+        ++ (lib.optionals selinuxSupport [
+          "feat_selinux"
+        ])
+      )
+    }"
+  ]
+  ++ lib.optionals (prefix != null) [ "PROG_PREFIX=${prefix}" ]
+  ++ lib.optionals buildMulticallBinary [ "MULTICALL=y" ];
+
+  env = lib.optionalAttrs selinuxSupport {
+    SELINUX_INCLUDE_DIR = ''${libselinux.dev}/include'';
+    SELINUX_LIB_DIR = lib.makeLibraryPath [
+      libselinux
+    ];
+    SELINUX_STATIC = "0";
+  };
+
+  # too many impure/platform-dependent tests
+  doCheck = false;
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  versionCheckProgram =
+    let
+      prefix' = lib.optionalString (prefix != null) prefix;
+    in
+    "${placeholder "out"}/bin/${prefix'}ls";
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Cross-platform Rust rewrite of the GNU coreutils";
+    longDescription = ''
+      uutils is an attempt at writing universal (as in cross-platform)
+      CLI utils in Rust. This repo is to aggregate the GNU coreutils rewrites.
+    '';
+    homepage = "https://github.com/uutils/coreutils";
+    changelog = "https://github.com/uutils/coreutils/releases/tag/${finalAttrs.version}";
+    maintainers = with lib.maintainers; [
+      siraben
+      matthiasbeyer
+    ];
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uutils-coreutils/selinux_no_auto_detect.diff

@@ -0,0 +1,36 @@
+diff --git a/GNUmakefile b/GNUmakefile
+index 20dc731d3..400e5b84f 100644
+--- a/GNUmakefile
++++ b/GNUmakefile
+@@ -69,19 +69,6 @@ TOYBOX_SRC  := $(TOYBOX_ROOT)/toybox-$(TOYBOX_VER)
+ #------------------------------------------------------------------------
+ OS ?= $(shell uname -s)
+ 
+-ifdef SELINUX_ENABLED
+-	override SELINUX_ENABLED := 0
+-# Now check if we should enable it (only on non-Windows)
+-	ifneq ($(OS),Windows_NT)
+-		ifeq ($(shell if [ -x /sbin/selinuxenabled ] && /sbin/selinuxenabled 2>/dev/null; then echo 0; else echo 1; fi),0)
+-			override SELINUX_ENABLED := 1
+-$(info /sbin/selinuxenabled successful)
+-	    else
+-$(info SELINUX_ENABLED=1 but /sbin/selinuxenabled failed)
+-		endif
+-	endif
+-endif
+-
+ # Possible programs
+ PROGS       := \
+ 	base32 \
+@@ -200,8 +187,10 @@ endif
+ 
+ ifneq ($(OS),Windows_NT)
+ 	PROGS := $(PROGS) $(UNIX_PROGS)
++	ifeq ($(SELINUX_ENABLED),1)
+ # Build the selinux command even if not on the system
+-	PROGS := $(PROGS) $(SELINUX_PROGS)
++		PROGS := $(PROGS) $(SELINUX_PROGS)
++	endif
+ # Always use external libstdbuf when building with make (Unix only)
+ 	CARGOFLAGS += --features feat_external_libstdbuf
+ endif

pkgs/by-name/uu/uutils-diffutils/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-diffutils";
+  version = "0.4.2";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "diffutils";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-IAgrCkhUC2Tkh+OM1lorpmD0GpsHUauLgU0KcmsvKb4=";
+  };
+
+  cargoHash = "sha256-SiZIp0rJXl0ZqKaxLPtV1nypxSqKXW+NoFLxCVpW4OY=";
+
+  checkFlags = [
+    # called `Result::unwrap()` on an `Err` value: Os { code: 2, kind: NotFound, message: "No such file or directory" }
+    "--skip=ed_diff::tests::test_permutations"
+    "--skip=ed_diff::tests::test_permutations_reverse"
+    "--skip=ed_diff::tests::test_permutations_empty_lines"
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    changelog = "https://github.com/uutils/diffutils/releases/tag/${finalAttrs.version}";
+    description = "Drop-in replacement of diffutils in Rust";
+    homepage = "https://github.com/uutils/diffutils";
+    license = lib.licenses.mit;
+    mainProgram = "diffutils";
+    maintainers = with lib.maintainers; [ defelo ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uutils-findutils/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  nix-update-script,
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-findutils";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "findutils";
+    tag = finalAttrs.version;
+    hash = "sha256-i+ryTF2hlZFbyFft/769c800FkzL26E4snUsxU79sKY=";
+  };
+
+  cargoHash = "sha256-gtaD2jqnGhoJGw9FAJefnU9BSGIODi/RrhTeB3MC69U=";
+
+  postInstall = ''
+    rm $out/bin/testing-commandline
+  '';
+
+  checkFlags = [
+    # assertion failed: deps.get_output_as_string().contains("./test_data/simple/subdir")
+    "--skip=find::tests::test_find_newer_xy_before_changed_time"
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/bin/find";
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    changelog = "https://github.com/uutils/findutils/releases/tag/${finalAttrs.version}";
+    description = "Rust implementation of findutils";
+    homepage = "https://github.com/uutils/findutils";
+    license = lib.licenses.mit;
+    mainProgram = "find";
+    maintainers = with lib.maintainers; [
+      defelo
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uuu/completion.bash

@@ -0,0 +1,4 @@
+_uuu_autocomplete() {
+    COMPREPLY=($(uuu $1 $2 $3))
+}
+complete -o nospace -F _uuu_autocomplete  uuu

pkgs/by-name/uu/uuu/package.nix

@@ -0,0 +1,74 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+
+  cmake,
+  installShellFiles,
+  pkg-config,
+
+  bzip2,
+  libusb1,
+  openssl,
+  tinyxml-2,
+  zlib,
+  zstd,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uuu";
+  version = "1.5.233";
+
+  src = fetchFromGitHub {
+    owner = "nxp-imx";
+    repo = "mfgtools";
+    rev = "uuu_${finalAttrs.version}";
+    hash = "sha256-x3C9bEE99XOIpnPjVV7Je5mfdhwN0nTkiuBxrwWZ7CI=";
+  };
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "uuu_([0-9.]+)"
+    ];
+  };
+
+  nativeBuildInputs = [
+    cmake
+    installShellFiles
+    pkg-config
+  ];
+
+  buildInputs = [
+    bzip2
+    libusb1
+    openssl
+    tinyxml-2
+    zlib
+    zstd
+  ];
+
+  postPatch = ''
+    # Avoid the need of calling Git during the build.
+    echo "uuu_${finalAttrs.version}" > .tarball-version
+  '';
+
+  postInstall = ''
+    installShellCompletion --bash --name uuu.bash ${./completion.bash}
+
+    mkdir -p $out/lib/udev/rules.d
+    cat <($out/bin/uuu -udev) > $out/lib/udev/rules.d/70-uuu.rules
+  '';
+
+  doInstallCheck = true;
+
+  meta = with lib; {
+    description = "Freescale/NXP I.MX Chip image deploy tools";
+    homepage = "https://github.com/nxp-imx/mfgtools";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ otavio ];
+    mainProgram = "uuu";
+    platforms = platforms.all;
+  };
+})