push sheeet

pkgs/by-name/uw/uwsgi/additional-php-ldflags.patch

@@ -0,0 +1,13 @@
+diff --git a/plugins/php/uwsgiplugin.py b/plugins/php/uwsgiplugin.py
+index d930c44e..2fcbc22a 100644
+--- a/plugins/php/uwsgiplugin.py
++++ b/plugins/php/uwsgiplugin.py
+@@ -17,6 +17,8 @@ php_version = os.popen(PHPPATH + ' --version').read().rstrip().split('.')[0]
+ CFLAGS = [os.popen(PHPPATH + ' --includes').read().rstrip(), '-Wno-sign-compare']
+ LDFLAGS = os.popen(PHPPATH + ' --ldflags').read().rstrip().split()
+ 
++LDFLAGS.append(os.environ.get('UWSGICONFIG_PHP_LDFLAGS', []))
++
+ if ld_run_path:
+     LDFLAGS.append('-L%s' % ld_run_path)
+     os.environ['LD_RUN_PATH'] = ld_run_path

pkgs/by-name/uw/uwsgi/nixos.ini

@@ -0,0 +1,6 @@
+[uwsgi]
+plugin_dir = @pluginDir@
+main_plugin = @basePlugins@
+json = true
+yaml = false
+inherit = base

pkgs/by-name/uw/uwsgi/no-ext-session-php_session.h-on-NixOS.patch

@@ -0,0 +1,29 @@
+From 6b9b3559d8ce59eda6c5cd6f04224cebaaa5d0ea Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?=D0=94=D0=B0=D0=BC=D1=98=D0=B0=D0=BD=20=D0=93=D0=B5=D0=BE?=
+ =?UTF-8?q?=D1=80=D0=B3=D0=B8=D0=B5=D0=B2=D1=81=D0=BA=D0=B8?=
+ <gdamjan@gmail.com>
+Date: Tue, 8 Sep 2020 17:11:39 +0200
+Subject: [PATCH] no ext/session/php_session.h on NixOS
+
+on NixOS php_session.h is in its own package, and is not installed in
+ext/session/
+---
+ plugins/php/common.h | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/plugins/php/common.h b/plugins/php/common.h
+index 9bf1c069..be93f519 100644
+--- a/plugins/php/common.h
++++ b/plugins/php/common.h
+@@ -10,7 +10,7 @@
+ #endif
+ #include "ext/standard/info.h"
+ 
+-#include "ext/session/php_session.h"
++#include "php_session.h"
+ 
+ #include <uwsgi.h>
+ 
+-- 
+2.28.0
+

pkgs/by-name/uw/uwsgi/package.nix

@@ -0,0 +1,194 @@
+{
+  stdenv,
+  nixosTests,
+  lib,
+  pkg-config,
+  jansson,
+  pcre2,
+  libxcrypt,
+  expat,
+  zlib,
+  # plugins: list of strings, eg. [ "python3" ]
+  plugins ? [ ],
+  pam,
+  withPAM ? stdenv.hostPlatform.isLinux,
+  systemd,
+  withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
+  libcap,
+  withCap ? stdenv.hostPlatform.isLinux,
+  python3,
+  ncurses,
+  ruby,
+  php,
+  makeWrapper,
+  fetchFromGitHub,
+}:
+
+let
+  php-embed = php.override {
+    embedSupport = true;
+    apxs2Support = false;
+  };
+
+  available = lib.listToAttrs [
+    (lib.nameValuePair "python3" {
+      interpreter = python3.pythonOnBuildForHost.interpreter;
+      path = "plugins/python";
+      inputs = [
+        python3
+        ncurses
+      ];
+      install = ''
+        install -Dm644 uwsgidecorators.py $out/${python3.sitePackages}/uwsgidecorators.py
+        ${python3.pythonOnBuildForHost.executable} -m compileall $out/${python3.sitePackages}/
+        ${python3.pythonOnBuildForHost.executable} -O -m compileall $out/${python3.sitePackages}/
+      '';
+    })
+    (lib.nameValuePair "rack" {
+      path = "plugins/rack";
+      inputs = [ ruby ];
+    })
+    (lib.nameValuePair "cgi" {
+      # usage: https://uwsgi-docs.readthedocs.io/en/latest/CGI.html?highlight=cgi
+      path = "plugins/cgi";
+      inputs = [ ];
+    })
+    (lib.nameValuePair "php" {
+      # usage: https://uwsgi-docs.readthedocs.io/en/latest/PHP.html#running-php-apps-with-nginx
+      path = "plugins/php";
+      inputs = [
+        php-embed
+        php-embed.extensions.session
+        php-embed.extensions.session.dev
+        php-embed.unwrapped.dev
+      ]
+      ++ php-embed.unwrapped.buildInputs;
+    })
+  ];
+
+  getPlugin =
+    name:
+    let
+      all = lib.concatStringsSep ", " (lib.attrNames available);
+    in
+    if lib.hasAttr name available then
+      lib.getAttr name available // { inherit name; }
+    else
+      throw "Unknown UWSGI plugin ${name}, available : ${all}";
+
+  needed = map getPlugin plugins;
+in
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uwsgi";
+  version = "2.0.30";
+
+  src = fetchFromGitHub {
+    owner = "unbit";
+    repo = "uwsgi";
+    tag = finalAttrs.version;
+    hash = "sha256-I03AshxZyxrRmtYUH1Q+B6ISykjYRMGG+ZQSHRS7vDs=";
+  };
+
+  patches = [
+    ./no-ext-session-php_session.h-on-NixOS.patch
+    ./additional-php-ldflags.patch
+  ];
+
+  nativeBuildInputs = [
+    makeWrapper
+    pkg-config
+    python3
+  ];
+
+  buildInputs = [
+    jansson
+    pcre2
+    libxcrypt
+  ]
+  ++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
+    expat
+    zlib
+  ]
+  ++ lib.optional withPAM pam
+  ++ lib.optional withSystemd systemd
+  ++ lib.optional withCap libcap
+  ++ lib.concatMap (x: x.inputs) needed;
+
+  basePlugins = lib.concatStringsSep "," (
+    lib.optional withPAM "pam" ++ lib.optional withSystemd "systemd_logger"
+  );
+
+  UWSGI_INCLUDES = lib.optionalString withCap "${libcap.dev}/include";
+
+  passthru = {
+    inherit python3;
+    tests.uwsgi = nixosTests.uwsgi;
+  };
+
+  postPatch = ''
+    for f in uwsgiconfig.py plugins/*/uwsgiplugin.py; do
+      substituteInPlace "$f" \
+        --replace pkg-config "$PKG_CONFIG"
+    done
+    sed -e "s/ + php_version//" -i plugins/php/uwsgiplugin.py
+  '';
+
+  configurePhase = ''
+    runHook preConfigure
+
+    export pluginDir=$out/lib/uwsgi
+    substituteAll ${./nixos.ini} buildconf/nixos.ini
+
+    runHook postConfigure
+  '';
+
+  # this is a hack to make the php plugin link with session.so (which on nixos is a separate package)
+  # the hack works in coordination with ./additional-php-ldflags.patch
+  UWSGICONFIG_PHP_LDFLAGS = lib.optionalString (builtins.any (x: x.name == "php") needed) (
+    lib.concatStringsSep "," [
+      "-Wl"
+      "-rpath=${php-embed.extensions.session}/lib/php/extensions/"
+      "--library-path=${php-embed.extensions.session}/lib/php/extensions/"
+      "-l:session.so"
+    ]
+  );
+
+  buildPhase = ''
+    runHook preBuild
+
+    mkdir -p $pluginDir
+    python3 uwsgiconfig.py --build nixos
+    ${lib.concatMapStringsSep ";" (
+      x:
+      "${x.preBuild or ""}\n ${x.interpreter or "python3"} uwsgiconfig.py --plugin ${x.path} nixos ${x.name}"
+    ) needed}
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 uwsgi $out/bin/uwsgi
+    ${lib.concatMapStringsSep "\n" (x: x.install or "") needed}
+
+    runHook postInstall
+  '';
+
+  postFixup = lib.optionalString (builtins.any (x: x.name == "php") needed) ''
+    wrapProgram $out/bin/uwsgi --set PHP_INI_SCAN_DIR ${php-embed}/lib
+  '';
+
+  meta = {
+    description = "Fast, self-healing and developer/sysadmin-friendly application container server coded in pure C";
+    homepage = "https://uwsgi-docs.readthedocs.org/en/latest/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      schneefux
+      globin
+    ];
+    platforms = lib.platforms.unix;
+    mainProgram = "uwsgi";
+  };
+})