push sheeet

pkgs/by-name/vb/vbam/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  cairo,
+  cmake,
+  fetchFromGitHub,
+  ffmpeg,
+  gettext,
+  wxGTK32,
+  gtk3,
+  libGLU,
+  libGL,
+  openal,
+  pkg-config,
+  SDL2,
+  sfml_2,
+  zip,
+  zlib,
+  wrapGAppsHook3,
+  gsettings-desktop-schemas,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "visualboyadvance-m";
+  version = "2.1.11";
+  src = fetchFromGitHub {
+    owner = "visualboyadvance-m";
+    repo = "visualboyadvance-m";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-OtJ632H449kPRY1i4Ydlcc1tgG00Mv622KrCyJ80OF4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    cairo
+    ffmpeg
+    gettext
+    libGLU
+    libGL
+    openal
+    SDL2
+    sfml_2
+    zip
+    zlib
+    wxGTK32
+    gtk3
+    gsettings-desktop-schemas
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_FFMPEG" true)
+    (lib.cmakeBool "ENABLE_LINK" true)
+    (lib.cmakeFeature "SYSCONFDIR" "etc")
+    (lib.cmakeBool "ENABLE_SDL" true)
+  ];
+
+  meta = {
+    description = "Merge of the original Visual Boy Advance forks";
+    license = lib.licenses.gpl2;
+    maintainers = with lib.maintainers; [
+      lassulus
+      netali
+    ];
+    homepage = "https://vba-m.com/";
+    platforms = lib.platforms.linux;
+    mainProgram = "visualboyadvance-m";
+  };
+})

pkgs/by-name/vb/vbindiff/package.nix

@@ -0,0 +1,26 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  ncurses,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vbindiff";
+  version = "3.0_beta5";
+
+  buildInputs = [ ncurses ];
+
+  src = fetchurl {
+    url = "https://www.cjmweb.net/vbindiff/${pname}-${version}.tar.gz";
+    sha256 = "1f1kj4jki08bnrwpzi663mjfkrx4wnfpzdfwd2qgijlkx5ysjkgh";
+  };
+
+  meta = {
+    description = "Terminal visual binary diff viewer";
+    homepage = "https://www.cjmweb.net/vbindiff/";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.unix;
+    mainProgram = "vbindiff";
+  };
+}

pkgs/by-name/vb/vboot_reference/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitiles,
+  pkg-config,
+  libuuid,
+  openssl,
+  libyaml,
+  xz,
+}:
+
+stdenv.mkDerivation {
+  pname = "vboot_reference";
+  version = "135.16209";
+
+  src = fetchFromGitiles {
+    url = "https://chromium.googlesource.com/chromiumos/platform/vboot_reference";
+    rev = "bf4b21294a1c2c6b94f400819d3fce4a905b3afe"; # refs/heads/release-R135-16209.B
+    hash = "sha256-frg7NkK173wAHJRedtbJI5jI8Kee/VkByh5DCUzD9OA=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    libuuid
+    libyaml
+    openssl
+    xz
+  ];
+
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail "ar qc" '${stdenv.cc.bintools.targetPrefix}ar qc'
+    # Drop flag unrecognized by GCC 9 (for e.g. aarch64-linux)
+    substituteInPlace Makefile \
+      --replace-fail "-Wno-unknown-warning" ""
+
+    patchShebangs scripts
+  '';
+
+  makeFlags = [
+    "DESTDIR=$(out)"
+    "HOST_ARCH=${stdenv.hostPlatform.parsed.cpu.name}"
+    "USE_FLASHROM=0"
+    # Upstream has weird opinions about DESTDIR
+    # https://chromium.googlesource.com/chromiumos/platform/vboot_reference/+/refs/heads/release-R135-16209.B/Makefile#51
+    "UB_DIR=${placeholder "out"}/bin"
+    "UL_DIR=${placeholder "out"}/lib"
+    "UI_DIR=${placeholder "out"}/include/vboot"
+    "US_DIR=${placeholder "out"}/share/vboot"
+  ];
+
+  postInstall = ''
+    mkdir -p $out/share/vboot
+    cp -r tests/devkeys* $out/share/vboot/
+  '';
+
+  meta = {
+    description = "Chrome OS partitioning and kernel signing tools";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.jmbaur ];
+  };
+}