push sheeet

pkgs/by-name/vd/vde2/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  autoreconfHook,
+  libpcap,
+  wolfssl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vde2";
+  version = "2.3.3";
+
+  src = fetchFromGitHub {
+    owner = "virtualsquare";
+    repo = "vde-2";
+    rev = "v${version}";
+    sha256 = "sha256-Yf6QB7j5lYld2XtqhYspK4037lTtimoFc7nCavCP+mU=";
+  };
+
+  patches = lib.optionals stdenv.hostPlatform.isMusl [
+    (fetchpatch {
+      url = "https://git.alpinelinux.org/aports/plain/main/vde2/musl-build-fix.patch?id=ddee2f86a48e087867d4a2c12849b2e3baccc238";
+      sha256 = "0b5382v541bkxhqylilcy34bh83ag96g71f39m070jzvi84kx8af";
+    })
+  ];
+
+  preConfigure = lib.optionalString (lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11") ''
+    MACOSX_DEPLOYMENT_TARGET=10.16
+  '';
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  buildInputs = [
+    libpcap
+    wolfssl
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/virtualsquare/vde-2";
+    description = "Virtual Distributed Ethernet, an Ethernet compliant virtual network";
+    platforms = platforms.unix;
+    license = licenses.gpl2Plus;
+  };
+}

pkgs/by-name/vd/vdhcoapp/ffmpeg-filepicker.patch

@@ -0,0 +1,46 @@
+diff --git a/src/converter.js b/src/converter.js
+index af7b4c3..20da407 100644
+--- a/src/converter.js
++++ b/src/converter.js
+@@ -1,4 +1,4 @@
+-import open from 'open';
++const open = import('open');
+ 
+ const os = require("os");
+ const path = require('path');
+@@ -9,9 +9,9 @@ const rpc = require('./weh-rpc');
+ 
+ const exec_dir = path.dirname(process.execPath);
+ 
+-const ffmpeg = findExecutableFullPath("ffmpeg", exec_dir);
+-const ffprobe = findExecutableFullPath("ffprobe", exec_dir);
+-const filepicker = findExecutableFullPath("filepicker", exec_dir);
++const ffmpeg = "@ffmpeg@/bin/ffmpeg";
++const ffprobe = "@ffmpeg@/bin/ffprobe";
++const filepicker = "@filepicker@";
+ 
+ if (!fileExistsSync(ffmpeg)) {
+   logger.error("ffmpeg not found. Install ffmpeg and make sure it's in your path.");
+diff --git a/src/main.js b/src/main.js
+index 47b92de..e2e9402 100644
+--- a/src/main.js
++++ b/src/main.js
+@@ -1,4 +1,4 @@
+-const config = require('config.json');
++const config = require('./config.json');
+ const converter = require('./converter');
+ const os = require("os");
+ 
+diff --git a/src/native-autoinstall.js b/src/native-autoinstall.js
+index 556a22b..c729568 100644
+--- a/src/native-autoinstall.js
++++ b/src/native-autoinstall.js
+@@ -1,7 +1,7 @@
+ const os = require("os");
+ const path = require("path");
+ const { spawn, exec } = require('child_process');
+-const config = require('config.json');
++const config = require('./config.json');
+ 
+ let fs;
+ if (process.versions.node.startsWith("10")) {

pkgs/by-name/vd/vdhcoapp/filepicker.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  atk,
+  gtk3,
+  glib,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "filepicker";
+  version = "1.0.1";
+
+  src = fetchFromGitHub {
+    owner = "paulrouget";
+    repo = "static-filepicker";
+    rev = "v${version}";
+    hash = "sha256-7sRzf3SA9RSBf4O36olXgka8c6Bufdb0qsuTofVe55s=";
+  };
+
+  cargoHash = "sha256-HUNBGG1+LsjaDsJS4p5aAdCRyltylQUtdydGSoUdNgo=";
+
+  buildInputs = [
+    atk
+    gtk3
+    glib
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  meta = with lib; {
+    description = "File picker used by VDHCoApp";
+    homepage = "https://github.com/paulrouget/static-filepicker";
+    license = licenses.gpl2;
+    mainProgram = "filepicker";
+    maintainers = with maintainers; [ hannesgith ];
+  };
+}

pkgs/by-name/vd/vdhcoapp/package.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+  nodejs,
+  ffmpeg,
+  callPackage,
+  replaceVars,
+  makeWrapper,
+  toml2json,
+  jq,
+}:
+buildNpmPackage rec {
+  pname = "vdhcoapp";
+  version = "2.0.19";
+
+  src = fetchFromGitHub {
+    owner = "aclap-dev";
+    repo = "vdhcoapp";
+    rev = "v${version}";
+    hash = "sha256-8xeZvqpRq71aShVogiwlVD3gQoPGseNOmz5E3KbsZxU=";
+  };
+
+  sourceRoot = "${src.name}/app";
+  npmDepsHash = "sha256-E032U2XZdyTER6ROkBosOTn7bweDXHl8voC3BQEz8Wg=";
+  dontNpmBuild = true;
+
+  nativeBuildInputs = [
+    makeWrapper
+    toml2json
+    jq
+  ];
+
+  patches = [
+    (replaceVars ./ffmpeg-filepicker.patch {
+      inherit ffmpeg;
+      filepicker = lib.getExe (callPackage ./filepicker.nix { });
+    })
+  ];
+
+  postPatch = ''
+    # Cannot use patch, setting placeholder here
+    substituteInPlace src/native-autoinstall.js \
+      --replace process.execPath "\"${placeholder "out"}/bin/vdhcoapp\""
+  '';
+
+  preBuild = ''
+    toml2json --pretty ../config.toml > src/config.json
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/opt/vdhcoapp
+    cp -r . "$out/opt/vdhcoapp"
+
+    makeWrapper ${nodejs}/bin/node $out/bin/vdhcoapp \
+      --add-flags $out/opt/vdhcoapp/src/main.js
+
+    generateManifest() {
+      type=$1
+      outputFolder=$2
+      mkdir -p $outputFolder
+      manifestName=$(jq -r '.meta.id' src/config.json).json
+      jq '.store.'$type'.manifest * (.meta | with_entries(select (.key == "description")) * {"name": .id}) * {"path" : "${placeholder "out"}/bin/vdhcoapp"}' src/config.json > $outputFolder/$manifestName
+    }
+
+    generateManifest google $out/etc/opt/chrome/native-messaging-hosts
+    generateManifest google $out/etc/chromium/native-messaging-hosts
+    generateManifest mozilla $out/lib/mozilla/native-messaging-hosts
+    generateManifest google $out/etc/opt/edge/native-messaging-hosts
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Companion application for the Video DownloadHelper browser add-on";
+    homepage = "https://www.downloadhelper.net/";
+    license = licenses.gpl2;
+    platforms = lib.platforms.linux;
+    maintainers = with maintainers; [ hannesgith ];
+    mainProgram = "vdhcoapp";
+  };
+}

pkgs/by-name/vd/vdmfec/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vdmfec";
+  version = "1.0";
+
+  src = fetchurl {
+    url = "http://members.tripod.com/professor_tom/archives/${pname}-${version}.tgz";
+    sha256 = "0i7q4ylx2xmzzq778anpkj4nqir5gf573n1lbpxnbc10ymsjq2rm";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+  ];
+
+  meta = with lib; {
+    description = "Program that adds error correction blocks";
+    homepage = "http://members.tripod.com/professor_tom/archives/index.html";
+    maintainers = [ maintainers.ar1a ];
+    license = with licenses; [
+      gpl2 # for vdmfec
+      bsd2 # for fec
+    ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/vd/vdo/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  installShellFiles,
+  libuuid,
+  lvm2_dmeventd, # <libdevmapper-event.h>
+  zlib,
+  python3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vdo";
+  version = "8.3.1.1";
+
+  src = fetchFromGitHub {
+    owner = "dm-vdo";
+    repo = "vdo";
+    rev = version;
+    hash = "sha256-6oX3ngsBPhE6XsMfliWw5Qzu3UosnsIFIAFRCqckU7U=";
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  buildInputs = [
+    libuuid
+    lvm2_dmeventd
+    zlib
+    python3.pkgs.wrapPython
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    pyyaml
+  ];
+
+  pythonPath = propagatedBuildInputs;
+
+  makeFlags = [
+    "DESTDIR=${placeholder "out"}"
+    "INSTALLOWNER="
+    # all of these paths are relative to DESTDIR and have defaults that don't work for us
+    "bindir=/bin"
+    "defaultdocdir=/share/doc"
+    "mandir=/share/man"
+    "python3_sitelib=${python3.sitePackages}"
+  ];
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    installShellCompletion --bash $out/usr/share/bash-completion/completions/*
+    rm -rv $out/usr
+
+    wrapPythonPrograms
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/dm-vdo/vdo";
+    description = "Set of userspace tools for managing pools of deduplicated and/or compressed block storage";
+    # platforms are defined in https://github.com/dm-vdo/vdo/blob/master/utils/uds/atomicDefs.h
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "s390-linux"
+      "powerpc64-linux"
+      "powerpc64le-linux"
+    ];
+    license = with licenses; [ gpl2Plus ];
+    maintainers = [ ];
+  };
+}

pkgs/by-name/vd/vdpauinfo/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoreconfHook,
+  pkg-config,
+  libvdpau,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vdpauinfo";
+  version = "1.5";
+
+  src = fetchurl {
+    url = "https://gitlab.freedesktop.org/vdpau/vdpauinfo/-/archive/${version}/${pname}-${version}.tar.bz2";
+    hash = "sha256-uOs/r8Ow7KvSpY1NhD2A+D4Qs6iWJe4fZGfVj6nIiCw=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+
+  buildInputs = [ libvdpau ];
+
+  meta = with lib; {
+    homepage = "https://people.freedesktop.org/~aplattner/vdpau/";
+    description = "Tool to query the Video Decode and Presentation API for Unix (VDPAU) abilities of the system";
+    license = licenses.mit; # expat version
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ vcunat ];
+    mainProgram = "vdpauinfo";
+  };
+}

pkgs/by-name/vd/vdrift/0001-Ignore-missing-data-for-installation.patch

@@ -0,0 +1,27 @@
+From 7ebe252a8488a63675d1c50c0faa1bdc5ff97889 Mon Sep 17 00:00:00 2001
+From: Linus Heckemann <git@sphalerite.org>
+Date: Fri, 5 Jan 2018 21:27:28 +0100
+Subject: [PATCH] Ignore missing data for installation
+
+This is for packaging vdrift separately from its data in nixpkgs.
+---
+ SConstruct | 3 ---
+ 1 file changed, 3 deletions(-)
+
+diff --git a/SConstruct b/SConstruct
+index 4394de0b..beef29a4 100644
+--- a/SConstruct
++++ b/SConstruct
+@@ -511,9 +511,6 @@ env.Alias(target = 'bin-package', source = bin_archive)
+ #----------------#
+ Export(['env', 'version', 'src_dir', 'bin_dir'])
+ if 'install' in COMMAND_LINE_TARGETS:
+-    if not os.path.isfile('data/SConscript'):
+-        raise 'VDrift data not found. Please make sure data is placed in vdrift directory. See README.md and http://wiki.vdrift.net.' 
+-    SConscript('data/SConscript')
+     # desktop appdata installation
+     install_desktop = env.Install(env['destdir'] + env['prefix'] + '/share/applications', 'vdrift.desktop')
+     install_appdata = env.Install(env['destdir'] + env['prefix'] + '/share/appdata', 'vdrift.appdata.xml')
+-- 
+2.15.0
+

pkgs/by-name/vd/vdrift/package.nix

@@ -0,0 +1,95 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchsvn,
+  pkg-config,
+  scons,
+  libGLU,
+  libGL,
+  SDL2,
+  SDL2_image,
+  libvorbis,
+  libX11,
+  bullet,
+  curl,
+  gettext,
+  writeShellScriptBin,
+
+  data ? fetchsvn {
+    url = "svn://svn.code.sf.net/p/vdrift/code/vdrift-data";
+    rev = "1446";
+    sha256 = "sha256-KEu49GAOfenPyuaUItt6W9pkuqUNpXgmTSFuc7ThljQ=";
+  },
+}:
+let
+  version = "unstable-2021-09-05";
+  bin = stdenv.mkDerivation {
+    pname = "vdrift";
+    inherit version;
+
+    src = fetchFromGitHub {
+      owner = "vdrift";
+      repo = "vdrift";
+      rev = "7e9e00c8612b2014d491f026dd86b03f9fb04dcd";
+      sha256 = "sha256-DrzRF4WzwEXCNALq0jz8nHWZ1oYTEsdrvSYVYI1WkTI=";
+    };
+
+    postPatch = ''
+      substituteInPlace src/SConscript \
+        --replace-fail sdl2-config "${lib.getExe' (lib.getDev SDL2) "sdl2-config"}"
+    '';
+
+    nativeBuildInputs = [
+      pkg-config
+      scons
+    ];
+    buildInputs = [
+      libGLU
+      libGL
+      SDL2
+      SDL2_image
+      libvorbis
+      libX11
+      bullet
+      curl
+      gettext
+    ];
+
+    patches = [
+      ./0001-Ignore-missing-data-for-installation.patch
+    ];
+
+    buildPhase = ''
+      runHook preBuild
+      substituteInPlace SConstruct \
+        --replace-fail /usr/local "$out" \
+        --replace-fail pkg-config "${stdenv.cc.targetPrefix}pkg-config"
+      export CXXFLAGS="$(${stdenv.cc.targetPrefix}pkg-config --cflags SDL2_image)"
+      scons -j$NIX_BUILD_CORES
+      runHook postBuild
+    '';
+
+    meta = {
+      description = "Car racing game";
+      mainProgram = "vdrift";
+      homepage = "https://vdrift.net/";
+      license = lib.licenses.gpl2Plus;
+      maintainers = [ ];
+      platforms = lib.platforms.linux;
+    };
+  };
+  wrappedName = "vdrift-${version}-with-data-${toString data.rev}";
+in
+(writeShellScriptBin "vdrift" ''
+  export VDRIFT_DATA_DIRECTORY="${data}"
+  exec ${bin}/bin/vdrift "$@"
+'').overrideAttrs
+  (_: {
+    name = wrappedName;
+    meta = bin.meta // {
+      hydraPlatforms = [ ];
+    };
+    unwrapped = bin;
+    inherit bin data;
+  })

pkgs/by-name/vd/vdrsymbols/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "vdrsymbols";
+  version = "20100612";
+
+  src = fetchurl {
+    url = "http://andreas.vdr-developer.org/fonts/download/${pname}-ttf-${version}.tgz";
+    hash = "sha256-YxB+JcDkta5are+OQyP/WKDL0vllgn0m26bU9mQ3C/Q=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm444 -t "$out/share/fonts/truetype" *.ttf
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "DejaVu fonts with additional symbols used by VDR";
+    homepage = "http://andreas.vdr-developer.org/fonts/";
+    platforms = platforms.all;
+    maintainers = with maintainers; [ ck3d ];
+
+    # Copyright (c) 2003 by Bitstream, Inc. All Rights Reserved.
+    # Copyright (c) 2006 by Tavmjong Bah. All Rights Reserved.
+    # DejaVu changes are in public domain
+    # See https://dejavu-fonts.github.io/License.html for details
+    license = with licenses; [
+      bitstreamVera
+      publicDomain
+    ];
+  };
+}