push sheeet

pkgs/by-name/vv/vvenc/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  gitUpdater,
+  testers,
+  cmake,
+  nlohmann_json,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vvenc";
+  version = "1.13.1";
+
+  outputs = [
+    "out"
+    "lib"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "fraunhoferhhi";
+    repo = "vvenc";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-DPR1HmUYTjhKI+gTHERtxqThZ5oKKMoqYsfE709IrhA=";
+  };
+
+  patches = [ ./unset-darwin-cmake-flags.patch ];
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals stdenv.cc.isGNU [
+      "-Wno-maybe-uninitialized"
+      "-Wno-uninitialized"
+    ]
+  );
+
+  buildInputs = [ nlohmann_json ];
+
+  nativeBuildInputs = [ cmake ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "VVENC_INSTALL_FULLFEATURE_APP" true)
+    (lib.cmakeBool "VVENC_ENABLE_THIRDPARTY_JSON" true)
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru = {
+    updateScript = gitUpdater {
+      rev-prefix = "v";
+      ignoredVersions = "rc";
+    };
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    homepage = "https://github.com/fraunhoferhhi/vvenc";
+    description = "Fraunhofer Versatile Video Encoder";
+    license = lib.licenses.bsd3Clear;
+    mainProgram = "vvencapp";
+    pkgConfigModules = [ "libvvenc" ];
+    maintainers = with lib.maintainers; [ jopejoe1 ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/vv/vvenc/unset-darwin-cmake-flags.patch

@@ -0,0 +1,9 @@
+--- a/source/Lib/vvenc/CMakeLists.txt	2025-01-14 23:26:14
++++ b/source/Lib/vvenc/CMakeLists.txt	2025-01-14 23:26:43
+@@ -174,6 +174,4 @@
+ set_target_properties( ${LIB_NAME} PROPERTIES
+                                    VERSION ${PROJECT_VERSION}
+                                    SOVERSION ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
+-                                   INSTALL_NAME_DIR ${CMAKE_INSTALL_PREFIX}/lib
+-                                   MACOSX_RPATH FALSE
+                                    FOLDER lib )

pkgs/by-name/vv/vvvvvv/package.nix

@@ -0,0 +1,102 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  fetchurl,
+  cmake,
+  makeWrapper,
+  copyDesktopItems,
+  makeDesktopItem,
+  faudio,
+  physfs,
+  SDL2,
+  tinyxml-2,
+  makeAndPlay ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vvvvvv";
+  version = "2.4.2";
+
+  src = fetchFromGitHub {
+    owner = "TerryCavanagh";
+    repo = "VVVVVV";
+    rev = version;
+    hash = "sha256-SYXuA7RJ0x4d1Lyvmk/R2nofEt5k7OJ91X6w3sGQOhg=";
+    fetchSubmodules = true;
+  };
+
+  dataZip = fetchurl {
+    url = "https://thelettervsixtim.es/makeandplay/data.zip";
+    name = "data.zip";
+    hash = "sha256-x2eAlZT2Ry2p9WE252ZX44ZA1YQWSkYRIlCsYpPswOo=";
+    meta.license = lib.licenses.unfree;
+  };
+
+  nativeBuildInputs = [
+    cmake
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  buildInputs = [
+    faudio
+    physfs
+    SDL2
+    tinyxml-2
+  ];
+
+  cmakeDir = "../desktop_version";
+
+  cmakeFlags = [
+    "-DBUNDLE_DEPENDENCIES=OFF"
+  ]
+  ++ lib.optional makeAndPlay "-DMAKEANDPLAY=ON";
+
+  desktopItems = [
+    (makeDesktopItem {
+      type = "Application";
+      name = "VVVVVV";
+      desktopName = "VVVVVV";
+      comment = meta.description;
+      exec = "vvvvvv";
+      icon = "VVVVVV";
+      terminal = false;
+      categories = [ "Game" ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 VVVVVV $out/bin/vvvvvv
+    install -Dm644 "$src/desktop_version/icon.ico" "$out/share/pixmaps/VVVVVV.png"
+    cp -r "$src/desktop_version/fonts/" "$out/share/"
+    cp -r "$src/desktop_version/lang/" "$out/share/"
+
+    wrapProgram $out/bin/vvvvvv \
+      --add-flags "-assets ${dataZip}" \
+      --add-flags "-langdir $out/share/lang" \
+      --add-flags "-fontsdir $out/share/fonts"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description =
+      "A retro-styled platform game"
+      + lib.optionalString makeAndPlay " (redistributable, without original levels)";
+    longDescription = ''
+      VVVVVV is a platform game all about exploring one simple mechanical
+      idea - what if you reversed gravity instead of jumping?
+    ''
+    + lib.optionalString makeAndPlay ''
+      (Redistributable version, doesn't include the original levels.)
+    '';
+    homepage = "https://thelettervsixtim.es";
+    changelog = "https://github.com/TerryCavanagh/VVVVVV/releases/tag/${src.rev}";
+    license = licenses.unfree;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}