push sheeet

pkgs/by-name/vy/vym/package.nix

@@ -0,0 +1,86 @@
+{
+  lib,
+  cmake,
+  fetchFromGitHub,
+  pkg-config,
+  qt5,
+  stdenv,
+  replaceVars,
+  unzip,
+  zip,
+}:
+
+let
+  inherit (qt5)
+    qtbase
+    qtscript
+    qtsvg
+    wrapQtAppsHook
+    ;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vym";
+  version = "2.9.26";
+
+  src = fetchFromGitHub {
+    owner = "insilmaril";
+    repo = "vym";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-5cHhv9GDjJvSqGJ+7fI0xaWCiXw/0WP0Bem/ZRV8Y7M=";
+  };
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  patches = [
+    (replaceVars ./patches/0000-fix-zip-paths.diff {
+      zipPath = "${lib.getExe zip}";
+      unzipPath = "${lib.getExe unzip}";
+    })
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    qtbase
+    qtscript
+    qtsvg
+  ];
+
+  qtWrapperArgs = [
+    "--prefix PATH : ${
+      lib.makeBinPath [
+        unzip
+        zip
+      ]
+    }"
+  ];
+
+  strictDeps = true;
+
+  meta = {
+    homepage = "http://www.insilmaril.de/vym/";
+    description = "Mind-mapping software";
+    longDescription = ''
+      VYM (View Your Mind) is a tool to generate and manipulate maps which show
+      your thoughts. Such maps can help you to improve your creativity and
+      effectivity. You can use them for time management, to organize tasks, to
+      get an overview over complex contexts, to sort your ideas etc.
+
+      Maps can be drawn by hand on paper or a flip chart and help to structure
+      your thoughs. While a tree like structure like shown on this page can be
+      drawn by hand or any drawing software vym offers much more features to
+      work with such maps.
+    '';
+    license = with lib.licenses; [ gpl2Plus ];
+    mainProgram = "vym";
+    maintainers = [ ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/vy/vym/patches/0000-fix-zip-paths.diff

@@ -0,0 +1,21 @@
+diff -Naur source-old/src/main.cpp source-new/src/main.cpp
+--- source-old/src/main.cpp	1969-12-31 21:00:01.000000000 -0300
++++ source-new/src/main.cpp	2022-10-23 22:30:00.463905363 -0300
+@@ -286,13 +286,10 @@
+     // Platform specific settings
+     vymPlatform = QSysInfo::prettyProductName();
+ 
+-#if defined(Q_OS_WINDOWS)
+-    // Only Windows 10 has tar. Older windows versions not supported.
+-    zipToolPath = "tar";
+-#else
+-    zipToolPath = "/usr/bin/zip";
+-    unzipToolPath = "/usr/bin/unzip";
+-#endif
++    // Nixpkgs-specific hack
++    zipToolPath = "@zipPath@";
++    unzipToolPath = "@unzipPath@";
++
+     iconPath = vymBaseDir.path() + "/icons/";
+     flagsPath = vymBaseDir.path() + "/flags/";
+ 

pkgs/by-name/vy/vyxal/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  stdenvNoCC,
+  clangStdenv,
+  fetchFromGitHub,
+  fetchurl,
+  mill,
+  which,
+}:
+
+let
+  # we need to lock the mill version, because an update will change the
+  # fetched internal dependencies, thus breaking the deps FOD
+  lockedMill = mill.overrideAttrs (oldAttrs: rec {
+    # should ideally match the version listed inside the `.mill-version` file of the source
+    version = "0.11.12";
+    src = fetchurl {
+      url = "https://github.com/com-lihaoyi/mill/releases/download/${version}/${version}-assembly";
+      hash = "sha256-k4/oMHvtq5YXY8hRlX4gWN16ClfjXEAn6mRIoEBHNJo=";
+    };
+  });
+in
+clangStdenv.mkDerivation (finalAttrs: {
+  pname = "vyxal";
+  version = "3.4.9";
+
+  src = fetchFromGitHub {
+    owner = "Vyxal";
+    repo = "Vyxal";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-8hA4u9zz8jm+tlSZ88z69/PUFNYk7+i3jtgUntgDgPE=";
+  };
+
+  # make sure to resolve all dependencies needed
+  deps = stdenvNoCC.mkDerivation {
+    name = "vyxal-${finalAttrs.version}-deps";
+    inherit (finalAttrs) src;
+
+    nativeBuildInputs = [ lockedMill ];
+
+    buildPhase = ''
+      runHook preBuild
+
+      export JAVA_TOOL_OPTIONS="-Duser.home=$(mktemp -d)"
+      export COURSIER_CACHE=$out/.coursier
+
+      mill native.prepareOffline --all
+
+      runHook postBuild
+    '';
+
+    outputHashAlgo = "sha256";
+    outputHashMode = "recursive";
+    outputHash = "sha256-yXKzntb498b8ZLYq7w+s1Brj+pvPN9otdkdY8QGVHPs=";
+  };
+
+  nativeBuildInputs = [
+    lockedMill
+    which
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    export JAVA_TOOL_OPTIONS="-Duser.home=$(mktemp -d)"
+    export COURSIER_CACHE=${finalAttrs.deps}/.coursier
+
+    mill native.nativeLink
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 out/native/nativeLink.dest/out $out/bin/vyxal
+    runHook postInstall
+  '';
+
+  meta = {
+    changelog = "https://github.com/Vyxal/Vyxal/releases/tag/v${finalAttrs.version}";
+    description = "Code-golfing language that has aspects of traditional programming languages";
+    homepage = "https://github.com/Vyxal/Vyxal";
+    license = lib.licenses.mit;
+    mainProgram = "vyxal";
+    maintainers = with lib.maintainers; [ tomasajt ];
+    platforms = lib.platforms.all;
+  };
+})