push sheeet

pkgs/by-name/wa/wallutils/000-add-nixos-dirs-to-default-wallpapers.patch

@@ -0,0 +1,26 @@
+From 2643b06889605e6096174fb48dcb64a49b252217 Mon Sep 17 00:00:00 2001
+From: Michael Weiss <dev.primeos@gmail.com>
+Date: Sun, 17 Nov 2019 20:30:08 +0100
+Subject: [PATCH] lscollection: Add NixOS paths to DefaultWallpaperDirectories
+
+---
+ collections.go | 3 +++
+ 1 file changed, 3 insertions(+)
+
+diff --git a/collections.go b/collections.go
+index be04d41..cc79c56 100644
+--- a/collections.go
++++ b/collections.go
+@@ -22,6 +22,9 @@ const (
+ 
+ // DefaultWallpaperDirectories lists the default locations to look for wallpapers
+ var DefaultWallpaperDirectories = []string{
++	"/run/current-system/sw/share/pixmaps",
++	"/run/current-system/sw/share/wallpapers",
++	"/run/current-system/sw/share/backgrounds",
+ 	"/usr/share/pixmaps",
+ 	"/usr/share/wallpapers",
+ 	"/usr/share/backgrounds",
+-- 
+2.23.0
+

pkgs/by-name/wa/wallutils/package.nix

@@ -0,0 +1,77 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  libX11,
+  libXcursor,
+  libXmu,
+  libXpm,
+  libheif,
+  pkg-config,
+  wayland,
+  xbitmaps,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "wallutils";
+  version = "5.14.2";
+
+  src = fetchFromGitHub {
+    owner = "xyproto";
+    repo = "wallutils";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-mcleLQIBG8L5cpA4QYZpDsBdZbJlyDx7XXwDtAV4sjU=";
+  };
+
+  vendorHash = null;
+
+  patches = [
+    ./000-add-nixos-dirs-to-default-wallpapers.patch
+  ];
+
+  excludedPackages = [
+    "./pkg/event/cmd" # Development tools
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    libX11
+    libXcursor
+    libXmu
+    libXpm
+    libheif
+    wayland
+    xbitmaps
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  preCheck = ''
+    export XDG_RUNTIME_DIR=$(mktemp -d)
+  '';
+
+  checkFlags =
+    let
+      skippedTests = [
+        "TestClosest" # Requiring Wayland or X
+        "TestEveryMinute" # Blocking
+        "TestNewSimpleEvent" # Blocking
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  meta = {
+    description = "Utilities for handling monitors, resolutions, and (timed) wallpapers";
+    inherit (finalAttrs.src.meta) homepage;
+    license = lib.licenses.bsd3;
+    maintainers = [ ];
+    inherit (wayland.meta) platforms;
+    badPlatforms = lib.platforms.darwin;
+  };
+})