push sheeet

pkgs/by-name/wu/wuffs/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  buildGoModule,
+  makeBinaryWrapper,
+  replaceVars,
+  testers,
+}:
+let
+  compiler =
+    if stdenv.cc.isClang then
+      "clang"
+    else if stdenv.cc.isGNU then
+      "gcc"
+    else
+      throw "unsupported compiler";
+in
+buildGoModule (finalAttrs: {
+  pname = "wuffs";
+  version = "0.4.0-alpha.9";
+
+  outputs = [
+    "out"
+    "dev"
+    "lib"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "google";
+    repo = "wuffs";
+    tag = "v" + finalAttrs.version;
+    hash = "sha256-XbupK4QYnPudUlO5tRWrQRncGHITzJL//Yk/E7WNxYk=";
+  };
+
+  vendorHash = null;
+
+  strictDeps = true;
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  subPackages = [
+    "cmd/wuffs-c"
+    "cmd/wuffs"
+  ];
+
+  # There are no checks
+  doCheck = false;
+
+  postInstall =
+    let
+      pkgconfig = replaceVars ./wuffs.pc {
+        LIB = placeholder "lib";
+        DEV = placeholder "dev";
+        DESCRIPTION = finalAttrs.meta.description;
+        VERSION = finalAttrs.version;
+      };
+    in
+    ''
+      wrapProgram "$out/bin/wuffs" \
+        --prefix PATH : "$out/bin"
+
+      "$out/bin/wuffs" gen std/...
+      "$out/bin/wuffs" genlib -ccompilers=${compiler}
+
+      install -Dm444 -t "$lib/lib" gen/lib/c/${compiler}-dynamic/libwuffs.*
+
+      install -Dm444 release/c/wuffs-unsupported-snapshot.c "$dev/include/wuffs/wuffs-v0.4.c"
+
+      install -Dm444 ${pkgconfig} "$dev/lib/pkgconfig/wuffs.pc"
+    '';
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = {
+    homepage = "https://github.com/google/wuffs";
+    description = "memory-safe programming language and standard library for wrangling untrusted data";
+    mainProgram = "wuffs";
+    pkgConfigModules = [ "wuffs" ];
+    license = with lib.licenses; [
+      mit
+      asl20
+    ];
+    maintainers = with lib.maintainers; [
+      RossSmyth
+    ];
+  };
+})

pkgs/by-name/wu/wuffs/wuffs.pc

@@ -0,0 +1,13 @@
+prefix=@LIB@
+exec_prefix=${prefix}
+libdir=${prefix}/lib
+includedir=@DEV@/include/wuffs
+
+Name: wuffs
+Description: @DESCRIPTION@
+Version: @VERSION@
+Requires:
+Conflicts:
+Libs: -L${libdir} -lwuffs
+Libs.private:
+Cflags: -I${includedir}

pkgs/by-name/wu/wush/package.nix

@@ -0,0 +1,36 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+let
+  version = "0.4.1";
+in
+buildGoModule {
+  pname = "wush";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "coder";
+    repo = "wush";
+    rev = "v${version}";
+    hash = "sha256-K83peIfr1+OHuuq6gdgco0RhfF1tAAewb4pxNT6vV+w=";
+  };
+
+  vendorHash = "sha256-3/DDtqVj7NNoJlNmKC+Q+XGS182E9OYkKMZ/2viANNQ=";
+
+  ldflags = [
+    "-s -w -X main.version=${version}"
+  ];
+
+  env.CGO_ENABLED = 0;
+
+  meta = {
+    homepage = "https://github.com/coder/wush";
+    description = "Transfer files between computers via WireGuard";
+    changelog = "https://github.com/coder/wush/releases/tag/v${version}";
+    license = lib.licenses.cc0;
+    mainProgram = "wush";
+    maintainers = with lib.maintainers; [ abbe ];
+  };
+}

pkgs/by-name/wu/wuzz/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  fetchpatch,
+}:
+
+buildGoModule rec {
+  pname = "wuzz";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "asciimoo";
+    repo = "wuzz";
+    rev = "v${version}";
+    sha256 = "sha256-H0soiKOytchfcFx17az0pGoFbA+hhXLxGJVdaARvnDc=";
+  };
+
+  patches = [
+    # go 1.19 support
+    # https://github.com/asciimoo/wuzz/pull/146
+    (fetchpatch {
+      url = "https://github.com/asciimoo/wuzz/commit/bb4c4fff794f160920df1d3b87541b28f071862c.patch";
+      hash = "sha256-nbgwmST36nB5ia3mgZvkwAVqJfznvFnNyzdoyo51kLg=";
+    })
+  ];
+
+  vendorHash = "sha256-oIm6DWSs6ZDKi6joxydguSXxqtGyKP21cmWtz8MkeIQ=";
+
+  meta = with lib; {
+    homepage = "https://github.com/asciimoo/wuzz";
+    description = "Interactive cli tool for HTTP inspection";
+    license = licenses.agpl3Only;
+    mainProgram = "wuzz";
+  };
+}