push sheeet

pkgs/by-name/xt/xteddy/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  pkg-config,
+  xorg,
+  imlib2,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xteddy";
+  version = "2.2-5";
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "games-team";
+    repo = "xteddy";
+    rev = "debian/${version}";
+    sha256 = "0rm7w78d6qajq4fvi4agyqm0c70f3c1i0cy2jdb6kqql2k8w78qy";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+  ];
+  buildInputs = [
+    imlib2
+    xorg.libX11
+    xorg.libXext
+  ];
+
+  patches = [
+    "${src}/debian/patches/10_libXext.patch"
+    "${src}/debian/patches/wrong-man-page-section.patch"
+  ];
+
+  postPatch = ''
+    sed -i "s:/usr/games/xteddy:$out/bin/xteddy:" xtoys
+    sed -i "s:/usr/share/xteddy:$out/share/xteddy:" xtoys
+  '';
+
+  postInstall = ''
+    cp -R images $out/share/images
+    # remove broken test script
+    rm $out/bin/xteddy_test
+  '';
+
+  postFixup = ''
+    # this is needed, because xteddy expects images to reside
+    # in the current working directory
+    wrapProgram $out/bin/xteddy --chdir "$out/share/images/"
+  '';
+
+  meta = with lib; {
+    description = "Cuddly teddy bear for your X desktop";
+    homepage = "https://weber.itn.liu.se/~stegu/xteddy/";
+    license = licenses.gpl2;
+    maintainers = [ maintainers.xaverdh ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/xt/xtensor-blas/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  openblas,
+  xtensor,
+  xtl,
+  doctest,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xtensor-blas";
+  version = "0.23.0";
+
+  src = fetchFromGitHub {
+    owner = "xtensor-stack";
+    repo = "xtensor-blas";
+    tag = finalAttrs.version;
+    hash = "sha256-3g84TMOBWq9q8O6GipwdsugjGhPwkZE1cXbRsnVp3Ls=";
+  };
+
+  # test case THREW exception: Could not find workspace size for gelsd
+  postPatch = ''
+    substituteInPlace test/CMakeLists.txt \
+      --replace-fail "test_lapack.cpp" "" \
+      --replace-fail "test_linalg.cpp" "" \
+      --replace-fail "test_qr.cpp" "" \
+      --replace-fail "test_lstsq.cpp" ""
+  '';
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    openblas
+    xtensor
+    xtl
+  ];
+  nativeCheckInputs = [ doctest ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTS" finalAttrs.finalPackage.doCheck)
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Extension to the xtensor library offering bindings to BLAS and LAPACK";
+    homepage = "https://github.com/xtensor-stack/xtensor-blas";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ jherland ];
+  };
+})

pkgs/by-name/xt/xtensor/package.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  doctest,
+  enableAssertions ? false,
+  enableBoundChecks ? false, # Broadcasts don't pass bound checks
+  nlohmann_json,
+  xtl,
+  xsimd,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xtensor";
+  version = "0.27.1";
+
+  src = fetchFromGitHub {
+    owner = "xtensor-stack";
+    repo = "xtensor";
+    tag = finalAttrs.version;
+    hash = "sha256-bvy2nF368rtVwUfGgSE1Zmpcze1nPwUbskXbf8flPt4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+  propagatedBuildInputs = [
+    nlohmann_json
+    xtl
+    xsimd
+  ];
+
+  cmakeFlags = [
+    # Always build the tests, even if not running them, because testing whether
+    # they can be built is a test in itself.
+    (lib.cmakeBool "BUILD_TESTS" true)
+    (lib.cmakeBool "XTENSOR_ENABLE_ASSERT" enableAssertions)
+    (lib.cmakeBool "XTENSOR_CHECK_DIMENSION" enableBoundChecks)
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+  nativeCheckInputs = [
+    doctest
+  ];
+  checkTarget = "xtest";
+
+  meta = {
+    description = "Multi-dimensional arrays with broadcasting and lazy computing";
+    homepage = "https://github.com/xtensor-stack/xtensor";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ cpcloud ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/xt/xterm/package.nix

@@ -0,0 +1,121 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  xorg,
+  ncurses,
+  freetype,
+  fontconfig,
+  pkg-config,
+  makeWrapper,
+  nixosTests,
+  pkgsCross,
+  gitUpdater,
+  enableDecLocator ? true,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xterm";
+  version = "402";
+
+  src = fetchurl {
+    urls = [
+      "ftp://ftp.invisible-island.net/xterm/${pname}-${version}.tgz"
+      "https://invisible-mirror.net/archives/xterm/${pname}-${version}.tgz"
+    ];
+    hash = "sha256-UmDFeTzVZMaeU+9vUowArwZq5ntC0CE3+374+v5wu3o=";
+  };
+
+  patches = [ ./sixel-256.support.patch ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    makeWrapper
+    pkg-config
+    fontconfig
+  ];
+
+  buildInputs = [
+    xorg.libXaw
+    xorg.xorgproto
+    xorg.libXt
+    xorg.libXext
+    xorg.libX11
+    xorg.libSM
+    xorg.libICE
+    ncurses
+    freetype
+    xorg.libXft
+    xorg.luit
+  ];
+
+  configureFlags = [
+    "--enable-wide-chars"
+    "--enable-256-color"
+    "--enable-sixel-graphics"
+    "--enable-regis-graphics"
+    "--enable-load-vt-fonts"
+    "--enable-i18n"
+    "--enable-doublechars"
+    "--enable-luit"
+    "--enable-mini-luit"
+    "--with-tty-group=tty"
+    "--with-app-defaults=$(out)/lib/X11/app-defaults"
+  ]
+  ++ lib.optional enableDecLocator "--enable-dec-locator";
+
+  env = {
+    # Work around broken "plink.sh".
+    NIX_LDFLAGS = "-lXmu -lXt -lICE -lX11 -lfontconfig";
+  }
+  // lib.optionalAttrs stdenv.hostPlatform.isMusl {
+    # Various symbols missing without this define: TAB3, NLDLY, CRDLY, BSDLY, FFDLY, CBAUD
+    NIX_CFLAGS_COMPILE = "-D_GNU_SOURCE";
+  };
+
+  # Hack to get xterm built with the feature of releasing a possible setgid of 'utmp',
+  # decided by the sysadmin to allow the xterm reporting to /var/run/utmp
+  # If we used the configure option, that would have affected the xterm installation,
+  # (setgid with the given group set), and at build time the environment even doesn't have
+  # groups, and the builder will end up removing any setgid.
+  postConfigure = ''
+    echo '#define USE_UTMP_SETGID 1'
+  '';
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    for bin in $out/bin/*; do
+      wrapProgram $bin --set XAPPLRESDIR $out/lib/X11/app-defaults/
+    done
+
+    install -D -t $out/share/applications xterm.desktop
+    install -D -t $out/share/icons/hicolor/48x48/apps icons/xterm-color_48x48.xpm
+  '';
+
+  passthru = {
+    tests = {
+      customTest = nixosTests.xterm;
+      standardTest = nixosTests.terminal-emulators.xterm;
+      musl = pkgsCross.musl64.xterm;
+    };
+
+    updateScript = gitUpdater {
+      # No nicer place to find latest release.
+      url = "https://github.com/ThomasDickey/xterm-snapshots.git";
+      rev-prefix = "xterm-";
+      # Tags that end in letters are unstable
+      ignoredVersions = "[a-z]$";
+    };
+  };
+
+  meta = {
+    homepage = "https://invisible-island.net/xterm";
+    license = with lib.licenses; [ mit ];
+    maintainers = with lib.maintainers; [ nequissimus ];
+    platforms = with lib.platforms; linux ++ darwin;
+    changelog = "https://invisible-island.net/xterm/xterm.log.html";
+    mainProgram = "xterm";
+  };
+}

pkgs/by-name/xt/xterm/sixel-256.support.patch

@@ -0,0 +1,11 @@
+--- xterm-325/graphics.c	2016-05-17 03:04:40.000000000 -0700
++++ xterm-325/graphics.c	2016-06-11 16:37:29.552584281 -0700
+@@ -667,7 +667,7 @@
+     case 330:
+ 	return 4U;
+     case 340:
+-	return 16U;
++	return 256U;
+     case 382:
+ 	return 2U;
+     default:

pkgs/by-name/xt/xtermcontrol/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  version = "3.10";
+  pname = "xtermcontrol";
+
+  src = fetchurl {
+    url = "https://thrysoee.dk/xtermcontrol/xtermcontrol-${version}.tar.gz";
+    sha256 = "sha256-Prl7HZ2KrhutT+LEHKOj27ENLWfmykWZqh9jGkBQPe4=";
+  };
+
+  meta = {
+    description = "Enables dynamic control of xterm properties";
+    longDescription = ''
+      Enables dynamic control of xterm properties.
+      It makes it easy to change colors, title, font and geometry of a running xterm, as well as to report the current settings of these properties.
+      Window manipulations de-/iconify, raise/lower, maximize/restore and reset are also supported.
+      To complete the feature set; xtermcontrol lets advanced users issue any xterm control sequence of their choosing.
+    '';
+    homepage = "http://thrysoee.dk/xtermcontrol";
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.derchris ];
+    mainProgram = "xtermcontrol";
+  };
+}

pkgs/by-name/xt/xteve/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "xteve";
+  version = "2.2.0.200";
+
+  src = fetchFromGitHub {
+    owner = "xteve-project";
+    repo = "xTeVe";
+    rev = version;
+    hash = "sha256-hD4GudSkGZO41nR/CgcMg/SqKjpAO1yJDkfwa8AUges=";
+  };
+
+  vendorHash = "sha256-oPkSWpqNozfSFLIFsJ+e2pOL6CcR91YHbqibEVF2aSk=";
+
+  meta = with lib; {
+    description = "M3U Proxy for Plex DVR and Emby Live TV";
+    homepage = "https://github.com/xteve-project/xTeVe";
+    license = licenses.mit;
+    maintainers = with maintainers; [ nrhelmi ];
+    mainProgram = "xteve";
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+}

pkgs/by-name/xt/xtf/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  fetchgit,
+  unstableGitUpdater,
+  stdenv,
+  doxygen,
+  graphviz,
+  python3Packages,
+}:
+
+stdenv.mkDerivation {
+  pname = "xtf";
+  version = "0-unstable-2025-07-26";
+
+  outputs = [
+    "out" # xtf-runner and test suite.
+    "doc" # Autogenerated HTML documentation website.
+    "dev" # Development headers.
+  ];
+
+  src = fetchgit {
+    url = "https://xenbits.xenproject.org/git-http/xtf.git";
+    rev = "0cbf4c35b06b2b285fc325b8458132e844c5cf0e";
+    hash = "sha256-sCNHhh6ZkMder1PSokfukKfcP8cVIIz8NiHH/4Yx3sE=";
+  };
+
+  nativeBuildInputs =
+    (with python3Packages; [
+      python
+      wrapPython
+    ])
+    ++ [
+      doxygen
+      graphviz
+    ];
+
+  buildFlags = [ "doxygen" ];
+
+  installFlags = [
+    "xtfdir=$(out)/share/xtf"
+  ];
+
+  postInstall =
+    # Much like Xen, XTF installs its files to dist/nix/store/*/*,
+    # so we need to copy them to the right place.
+    ''
+      mkdir -p ''${!outputBin}/share
+      cp -prvd dist/nix/store/*/* ''${!outputBin}
+    ''
+    # The documentation and development headers aren't in the dist/
+    # folder, so we copy those too.
+    + ''
+      mkdir -p ''${!outputDoc}/share/doc/xtf
+      cp -prvd docs/autogenerated/html ''${!outputDoc}/share/doc/xtf
+
+      mkdir -p ''${!outputDev}/include
+      cp -prvd include ''${!outputDev}
+    ''
+    # Wrap xtf-runner, and link it to $out/bin.
+    # This is necessary because the real xtf-runner should
+    # be in the same directory as the tests/ directory.
+    + ''
+      wrapPythonProgramsIn "''${!outputBin}/share/xtf" "''${!outputBin} $pythonPath"
+      mkdir -p ''${!outputBin}/bin
+      ln -s ''${!outputBin}/share/xtf/xtf-runner ''${!outputBin}/bin/xtf-runner
+    '';
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    description = "Xen Test Framework and Suite for creating microkernel-based tests";
+    homepage = "https://xenbits.xenproject.org/docs/xtf/index.html";
+    license = lib.licenses.bsd2;
+    teams = [ lib.teams.xen ];
+    mainProgram = "xtf-runner";
+    platforms = lib.lists.intersectLists lib.platforms.linux lib.platforms.x86_64;
+  };
+}

pkgs/by-name/xt/xtitle/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libxcb,
+  xcbutil,
+  xcbutilwm,
+  git,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xtitle";
+  version = "0.4.4";
+
+  src = fetchFromGitHub {
+    owner = "baskerville";
+    repo = "xtitle";
+    rev = version;
+    hash = "sha256-SVfM2vCCacgchXj0c0sPk3VR6DUI4R0ofFnxJSY4oDg=";
+  };
+
+  postPatch = ''
+    sed -i "s|/usr/local|$out|" Makefile
+  '';
+
+  buildInputs = [
+    libxcb
+    git
+    xcbutil
+    xcbutilwm
+  ];
+
+  meta = with lib; {
+    description = "Outputs X window titles";
+    homepage = "https://github.com/baskerville/xtitle";
+    maintainers = with maintainers; [ meisternu ];
+    license = lib.licenses.unlicense;
+    platforms = platforms.linux;
+    mainProgram = "xtitle";
+  };
+}

pkgs/by-name/xt/xtl/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  doctest,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xtl";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "xtensor-stack";
+    repo = "xtl";
+    tag = finalAttrs.version;
+    hash = "sha256-hhXM2fG3Yl4KeEJlOAcNPVLJjKy9vFlI63lhbmIAsT8=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  cmakeFlags = [ "-DBUILD_TESTS=ON" ];
+
+  doCheck = true;
+  nativeCheckInputs = [ doctest ];
+  checkTarget = "xtest";
+
+  meta = {
+    description = "Basic tools (containers, algorithms) used by other quantstack packages";
+    homepage = "https://github.com/xtensor-stack/xtl";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ cpcloud ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/xt/xtrace/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  autoreconfHook,
+  fetchFromGitLab,
+  libX11,
+  xauth,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xtrace";
+  version = "1.4.0";
+
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "debian";
+    repo = "xtrace";
+    rev = "xtrace-${version}";
+    sha256 = "1yff6x847nksciail9jly41mv70sl8sadh0m5d847ypbjmxcwjpq";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    makeWrapper
+  ];
+  buildInputs = [ libX11 ];
+
+  postInstall = ''
+    wrapProgram "$out/bin/xtrace" \
+        --prefix PATH ':' "${xauth}/bin"
+  '';
+
+  meta = with lib; {
+    homepage = "https://salsa.debian.org/debian/xtrace";
+    description = "Tool to trace X11 protocol connections";
+    license = licenses.gpl2Only;
+    maintainers = [ ];
+    platforms = with platforms; linux;
+    mainProgram = "xtrace";
+  };
+}

pkgs/by-name/xt/xtrans/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  writeScript,
+  testers,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xtrans";
+  version = "1.6.0";
+
+  src = fetchurl {
+    url = "mirror://xorg/individual/lib/xtrans-${finalAttrs.version}.tar.xz";
+    hash = "sha256-+q/qFmvyRRoXPZ1ZM1KUDsZAQUXF0dpcITQjzk01npI=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ pkg-config ];
+
+  passthru = {
+    updateScript = writeScript "update-${finalAttrs.pname}" ''
+      #!/usr/bin/env nix-shell
+      #!nix-shell -i bash -p common-updater-scripts
+      version="$(list-directory-versions --pname ${finalAttrs.pname} \
+        --url https://xorg.freedesktop.org/releases/individual/lib/ \
+        | sort -V | tail -n1)"
+      update-source-version ${finalAttrs.pname} "$version"
+    '';
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "X Window System Protocols Transport layer shared code";
+    homepage = "https://gitlab.freedesktop.org/xorg/lib/libxtrans";
+    license = with lib.licenses; [
+      mitOpenGroup
+      hpnd
+      mit
+      x11
+      hpndSellVariant
+    ];
+    maintainers = [ ];
+    pkgConfigModules = [ "xtrans" ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/xt/xtreemfs/package.nix

@@ -0,0 +1,129 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  fetchpatch,
+  makeWrapper,
+  stripJavaArchivesHook,
+  ant,
+  attr,
+  boost186,
+  cmake,
+  file,
+  fuse,
+  jdk8,
+  openssl,
+  python3,
+  valgrind,
+  which,
+}:
+
+let
+  boost = boost186;
+in
+
+stdenv.mkDerivation {
+  pname = "XtreemFS";
+  # using unstable release because stable (v1.5.1) has broken repl java plugin
+  version = "unstable-2015-06-17";
+
+  src = fetchFromGitHub {
+    rev = "7ddcb081aa125b0cfb008dc98addd260b8353ab3";
+    owner = "xtreemfs";
+    repo = "xtreemfs";
+    sha256 = "1hjmd32pla27zf98ghzz6r5ml8ry86m9dsryv1z01kxv5l95b3m0";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    python3
+    stripJavaArchivesHook
+    which
+  ];
+  buildInputs = [
+    attr
+  ];
+
+  patches = [
+    (fetchpatch {
+      name = "protobuf-add-arm64-atomicops.patch";
+      url = "https://github.com/protocolbuffers/protobuf/commit/2ca19bd8066821a56f193e7fca47139b25c617ad.patch";
+      stripLen = 1;
+      extraPrefix = "cpp/thirdparty/protobuf-2.5.0/";
+      sha256 = "sha256-hlL5ZiJhpO3fPpcSTV+yki4zahg/OhFdIZEGF1TNTe0=";
+    })
+    (fetchpatch {
+      name = "protobuf-add-aarch64-architecture-to-platform-macros.patch";
+      url = "https://github.com/protocolbuffers/protobuf/commit/f0b6a5cfeb5f6347c34975446bda08e0c20c9902.patch";
+      stripLen = 1;
+      extraPrefix = "cpp/thirdparty/protobuf-2.5.0/";
+      sha256 = "sha256-VRl303x9g5ES/LMODcAdhsPiEmQTq/qXhE/DfvLXF84=";
+    })
+    (fetchpatch {
+      name = "xtreemfs-fix-for-boost-version-1.66.patch";
+      url = "https://github.com/xtreemfs/xtreemfs/commit/aab843cb115ab0739edf7f58fd2d4553a05374a8.patch";
+      sha256 = "sha256-y/vXI/PT1TwSy8/73+RKIgKq4pZ9i22MBxr6jo/M5l8=";
+    })
+    (fetchpatch {
+      name = "xtreemfs-fix-for-openssl_1_1.patch";
+      url = "https://github.com/xtreemfs/xtreemfs/commit/ebfdc2fff56c09f310159d92026883941e42a953.patch";
+      sha256 = "075w00ad88qm6xpm5679m0gfzkrc53w17sk7ycybf4hzxjs29ygy";
+    })
+  ];
+
+  preConfigure = ''
+    export JAVA_HOME=${jdk8}
+    export ANT_HOME=${ant}
+
+    export BOOST_INCLUDEDIR=${boost.dev}/include
+    export BOOST_LIBRARYDIR=${boost.out}/lib
+    export CMAKE_INCLUDE_PATH=${openssl.dev}/include
+    export CMAKE_LIBRARY_PATH=${lib.getLib openssl}/lib
+
+    substituteInPlace cpp/cmake/FindValgrind.cmake \
+      --replace "/usr/local" "${valgrind}"
+
+    substituteInPlace cpp/CMakeLists.txt \
+      --replace '"/lib64" "/usr/lib64"' '"${attr.out}/lib" "${lib.getLib fuse}/lib"'
+
+    export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -I${lib.getDev fuse}/include"
+    export NIX_CFLAGS_LINK="$NIX_CFLAGS_LINK -L${lib.getLib fuse}/lib"
+
+    export DESTDIR=$out
+
+    substituteInPlace Makefile \
+      --replace "/usr/share/" "/share/" \
+      --replace 'BIN_DIR=$(DESTDIR)/usr/bin' "BIN_DIR=$out/bin"
+
+    substituteInPlace etc/init.d/generate_initd_scripts.sh \
+      --replace "/bin/bash" "${stdenv.shell}"
+
+    substituteInPlace cpp/thirdparty/gtest-1.7.0/configure \
+      --replace "/usr/bin/file" "${file}/bin/file"
+
+    substituteInPlace cpp/thirdparty/protobuf-2.5.0/configure \
+      --replace "/usr/bin/file" "${file}/bin/file"
+
+    substituteInPlace cpp/thirdparty/protobuf-2.5.0/gtest/configure \
+      --replace "/usr/bin/file" "${file}/bin/file"
+
+    # do not put cmake into buildInputs
+    export PATH="$PATH:${cmake}/bin"
+  '';
+
+  doCheck = false;
+
+  postInstall = ''
+    rm -r $out/sbin
+  '';
+
+  meta = {
+    description = "Distributed filesystem";
+    maintainers = with lib.maintainers; [
+      raskin
+      matejc
+    ];
+    platforms = lib.platforms.linux;
+    license = lib.licenses.bsd3;
+  };
+}

pkgs/by-name/xt/xtris/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  xorg,
+}:
+stdenv.mkDerivation rec {
+  pname = "xtris";
+  version = "1.15";
+
+  src = fetchzip {
+    url = "https://web.archive.org/web/20120315061213/http://www.iagora.com/~espel/xtris/xtris-${version}.tar.gz";
+    sha256 = "1vqva99lyv7r6f9c7yikk8ahcfh9aq3clvwm4pz964wlbr9mj1v6";
+  };
+
+  patchPhase = ''
+    sed -i '
+      s:/usr/local/bin:'$out'/bin:
+      s:/usr/local/man:'$out'/share/man:
+      s:mkdir:mkdir -p:g
+      s:^CFLAGS:#CFLAGS:
+    ' Makefile
+
+    sed -i '28i#include <time.h>' xtserv.c
+    sed -i '35i#include <time.h>' xtbot.c
+  '';
+  buildInputs = [ xorg.libX11 ];
+
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+
+  meta = with lib; {
+    description = "Multi-player version of the classical game of Tetris, for the X Window system";
+    homepage = "https://web.archive.org/web/20120315061213/http://www.iagora.com/~espel/xtris/xtris.html";
+    license = licenses.gpl2Only;
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/xt/xtruss/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  halibut,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xtruss";
+  version = "20211025.c25bf48";
+
+  src = fetchurl {
+    url = "https://www.chiark.greenend.org.uk/~sgtatham/xtruss/${pname}-${version}.tar.gz";
+    sha256 = "sha256-ikuKHtXEn2UVLE62l7qD9qc9ZUk6jiAqj5ru36vgdHk=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    halibut
+  ];
+
+  meta = with lib; {
+    description = "Easy-to-use X protocol tracing program";
+    homepage = "https://www.chiark.greenend.org.uk/~sgtatham/xtruss";
+    license = licenses.mit;
+    maintainers = with maintainers; [ dtzWill ];
+    mainProgram = "xtruss";
+  };
+}

pkgs/by-name/xt/xtuner/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  pkg-config,
+  cairo,
+  libX11,
+  libjack2,
+  liblo,
+  libsigcxx,
+  zita-resampler,
+  fftwFloat,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xtuner";
+  version = "1.0";
+
+  src = fetchFromGitHub {
+    owner = "brummer10";
+    repo = "XTuner";
+    tag = "v${version}";
+    sha256 = "1i5chfnf3hcivwzni9z6cn9pb68qmwsx8bf4z7d29a5vig8kbhrv";
+    fetchSubmodules = true;
+  };
+
+  patches = [
+    # Fix build against glibc-2.38.
+    (fetchpatch {
+      name = "glibc-2.38.patch";
+      url = "https://github.com/brummer10/libxputty/commit/7eb70bf3f7bce0af9e1919d6c875cdb8efca734e.patch";
+      hash = "sha256-VspR0KJjBt4WOrnlo7rHw1oAYM1d2RSz6JhuAEfsO3M=";
+      stripLen = 1;
+      extraPrefix = "libxputty/";
+    })
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    cairo
+    libX11
+    libjack2
+    liblo
+    libsigcxx
+    zita-resampler
+    fftwFloat
+  ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    homepage = "https://github.com/brummer10/XTuner";
+    description = "Tuner for Jack Audio Connection Kit";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ magnetophon ];
+    platforms = platforms.linux;
+    mainProgram = "xtuner";
+  };
+}