push sheeet

pkgs/by-name/yn/ynetd/hardened.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  openssl,
+  stdenv,
+  fetchurl,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ctf-ynetd";
+  version = "2024.12.31";
+
+  src = fetchurl {
+    url = "https://hxp.io/assets/data/code/ctf-ynetd-2024.12.31.tar.xz";
+    hash = "sha256-hUEZZEulmaV3KfKOqE1wl7y4SRUn2/HoOjVDabk5+YA=";
+  };
+
+  buildInputs = [ openssl ];
+
+  makeFlags = [
+    "ynetd"
+    "pow-solver"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 ynetd $out/bin/ynetd
+    install -Dm755 pow-solver $out/bin/pow-solver
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Fork of ynetd hardened for CTFs with isolation using PID namespaces, minimal overhead proof-of-work checking, and strict resource limits via cgroups";
+    homepage = "https://hxp.io/code/";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.haylin ];
+    mainProgram = "ynetd";
+  };
+})

pkgs/by-name/yn/ynetd/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  callPackage,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ynetd";
+  version = "2024.02.17";
+
+  src = fetchurl {
+    url = "https://yx7.cc/code/ynetd/ynetd-2024.02.17.tar.xz";
+    hash = "sha256-7gioQ0r0LlUftIWKRwTqeZQl0GtskcRKaEE5z6A0S24=";
+  };
+
+  postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    substituteInPlace Makefile --replace-fail "-Wl,-z,relro,-z,now" ""
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 ynetd $out/bin/ynetd
+    runHook postInstall
+  '';
+
+  # ctf-ynetd releases are based on the last stable ynetd version
+  # these should be kept in sync when possible
+  passthru.hardened = callPackage ./hardened.nix { };
+
+  meta = {
+    description = "Small server for binding programs to TCP ports";
+    homepage = "https://yx7.cc/code/";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.haylin ];
+    mainProgram = "ynetd";
+  };
+})