push sheeet

pkgs/by-name/yu/yubico-pam/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  pkg-config,
+  asciidoc,
+  libxslt,
+  docbook_xsl,
+  pam,
+  yubikey-personalization,
+  libyubikey,
+  libykclient,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "yubico-pam";
+  version = "2.27";
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubico-pam";
+    rev = version;
+    sha256 = "0hb773zlf11xz4bwmsqv2mq5d4aq2g0crdr5cp9xwc4ivi5gd4kg";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    asciidoc
+    libxslt
+    docbook_xsl
+  ];
+  buildInputs = [
+    pam
+    yubikey-personalization
+    libyubikey
+    libykclient
+  ];
+
+  meta = with lib; {
+    description = "Yubico PAM module";
+    mainProgram = "ykpamcfg";
+    homepage = "https://developers.yubico.com/yubico-pam";
+    license = licenses.bsd2;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/yu/yubico-piv-tool/package.nix

@@ -0,0 +1,107 @@
+{
+  lib,
+  check,
+  cmake,
+  fetchFromGitHub,
+  gengetopt,
+  help2man,
+  nix-update-script,
+  openssl,
+  pcsclite,
+  pkg-config,
+  stdenv,
+  testers,
+  zlib,
+  withApplePCSC ? stdenv.hostPlatform.isDarwin,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yubico-piv-tool";
+  version = "2.7.2";
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubico-piv-tool";
+    tag = "yubico-piv-tool-${finalAttrs.version}";
+    hash = "sha256-1VLSlwwubxCYqdU1ueD2FXEqS5xKtHk4bsJAXOHCDKY=";
+  };
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt --replace-fail "-Werror" ""
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    gengetopt
+    help2man
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+    zlib
+  ]
+  ++ lib.optionals (!withApplePCSC) [ pcsclite ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "GENERATE_MAN_PAGES" true)
+    (lib.cmakeFeature "BACKEND" (if withApplePCSC then "macscard" else "pcsc"))
+    (lib.cmakeFeature "CMAKE_INSTALL_BINDIR" "bin")
+    (lib.cmakeFeature "CMAKE_INSTALL_INCLUDEDIR" "include")
+    (lib.cmakeFeature "CMAKE_INSTALL_LIBDIR" "lib")
+    (lib.cmakeFeature "CMAKE_INSTALL_MANDIR" "share/man")
+  ];
+
+  doCheck = true;
+
+  nativeCheckInputs = [ check ];
+
+  passthru = {
+    updateScript = nix-update-script {
+      extraArgs = [
+        "--version-regex"
+        "yubico-piv-tool-([0-9.]+)$"
+      ];
+    };
+    tests = {
+      pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+      version = testers.testVersion {
+        package = finalAttrs.finalPackage;
+        command = "yubico-piv-tool --version";
+      };
+    };
+  };
+
+  meta = {
+    homepage = "https://developers.yubico.com/yubico-piv-tool/";
+    changelog = "https://developers.yubico.com/yubico-piv-tool/Release_Notes.html";
+    description = ''
+      Used for interacting with the Privilege and Identification Card (PIV)
+      application on a YubiKey
+    '';
+    longDescription = ''
+      The Yubico PIV tool is used for interacting with the Privilege and
+      Identification Card (PIV) application on a YubiKey.
+      With it you may generate keys on the device, importing keys and
+      certificates, and create certificate requests, and other operations.
+      A shared library and a command-line tool is included.
+    '';
+    license = lib.licenses.bsd2;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      viraptor
+      anthonyroussel
+    ];
+    mainProgram = "yubico-piv-tool";
+    pkgConfigModules = [
+      "ykcs11"
+      "ykpiv"
+    ];
+  };
+})

pkgs/by-name/yu/yubihsm-connector/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  libusb1,
+  buildGoModule,
+  fetchFromGitHub,
+  pkg-config,
+}:
+
+buildGoModule rec {
+  pname = "yubihsm-connector";
+  version = "3.0.5";
+
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubihsm-connector";
+    rev = version;
+    hash = "sha256-hiCh/TG1epSmJtaptfVzcPklDTaBh0biKqfM01YoWo0=";
+  };
+
+  vendorHash = "sha256-XW7rEHY3S+M3b6QjmINgrCak+BqCEV3PJP90jz7J47A=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    libusb1
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  preBuild = ''
+    GOOS= GOARCH= go generate
+  '';
+
+  meta = with lib; {
+    description = "Performs the communication between the YubiHSM 2 and applications that use it";
+    homepage = "https://developers.yubico.com/yubihsm-connector/";
+    maintainers = with maintainers; [ matthewcroughan ];
+    license = licenses.asl20;
+    mainProgram = "yubihsm-connector";
+  };
+}

pkgs/by-name/yu/yubihsm-shell/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  openssl,
+  libusb1,
+  libedit,
+  curl,
+  gengetopt,
+  pkg-config,
+  pcsclite,
+  help2man,
+  libiconv,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "yubihsm-shell";
+  version = "2.7.0";
+
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubihsm-shell";
+    rev = version;
+    hash = "sha256-ymGS35kjhNlFee3FEXF8n6Jm7NVaynjv+lpix6F75BQ=";
+  };
+
+  postPatch = ''
+    # Can't find libyubihsm at runtime because of dlopen() in C code
+    substituteInPlace lib/yubihsm.c \
+      --replace "libyubihsm_usb.so" "$out/lib/libyubihsm_usb.so" \
+      --replace "libyubihsm_http.so" "$out/lib/libyubihsm_http.so"
+    # ld: unknown option: -z
+    substituteInPlace CMakeLists.txt cmake/SecurityFlags.cmake \
+      --replace "AppleClang" "Clang"
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+    help2man
+    gengetopt
+  ];
+
+  buildInputs = [
+    libusb1
+    libedit
+    curl
+    openssl
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    pcsclite.dev
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    libiconv
+  ];
+
+  preBuild = lib.optionalString stdenv.hostPlatform.isLinux ''
+    NIX_CFLAGS_COMPILE="$(pkg-config --cflags libpcsclite) $NIX_CFLAGS_COMPILE"
+  '';
+
+  # causes redefinition of _FORTIFY_SOURCE
+  hardeningDisable = [ "fortify3" ];
+
+  meta = with lib; {
+    description = "Thin wrapper around libyubihsm providing both an interactive and command-line interface to a YubiHSM";
+    homepage = "https://github.com/Yubico/yubihsm-shell";
+    maintainers = with maintainers; [ matthewcroughan ];
+    license = licenses.asl20;
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/yu/yubikey-agent/package.nix

@@ -0,0 +1,59 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+  libnotify,
+  pcsclite,
+  pkg-config,
+}:
+
+buildGoModule rec {
+  pname = "yubikey-agent";
+
+  version = "0.1.6";
+  src = fetchFromGitHub {
+    owner = "FiloSottile";
+    repo = "yubikey-agent";
+    rev = "v${version}";
+    sha256 = "sha256-Knk1ipBOzjmjrS2OFUMuxi1TkyDcSYlVKezDWT//ERY=";
+  };
+
+  buildInputs = lib.optional stdenv.hostPlatform.isLinux (lib.getDev pcsclite);
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [ pkg-config ];
+
+  postPatch = lib.optionalString stdenv.hostPlatform.isLinux ''
+    substituteInPlace main.go --replace 'notify-send' ${libnotify}/bin/notify-send
+  '';
+
+  vendorHash = "sha256-+IRPs3wm3EvIgfQRpzcVpo2JBaFQlyY/RI1G7XfVS84=";
+
+  doCheck = false;
+
+  subPackages = [ "." ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.Version=${version}"
+  ];
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
+    mkdir -p $out/lib/systemd/user
+    substitute contrib/systemd/user/yubikey-agent.service $out/lib/systemd/user/yubikey-agent.service \
+      --replace 'ExecStart=yubikey-agent' "ExecStart=$out/bin/yubikey-agent"
+  '';
+
+  meta = with lib; {
+    description = "Seamless ssh-agent for YubiKeys";
+    mainProgram = "yubikey-agent";
+    license = licenses.bsd3;
+    homepage = "https://filippo.io/yubikey-agent";
+    maintainers = with lib.maintainers; [
+      philandstuff
+      rawkode
+    ];
+    platforms = platforms.darwin ++ platforms.linux;
+  };
+}

pkgs/by-name/yu/yubikey-manager/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  python3Packages,
+  installShellFiles,
+  procps,
+}:
+
+python3Packages.buildPythonPackage rec {
+  pname = "yubikey-manager";
+  version = "5.8.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubikey-manager";
+    tag = version;
+    hash = "sha256-Z3krdKP6hhhIxN7nl/k5r30jFVC0kZK9Z6Aqllp/KrA=";
+  };
+
+  postPatch = ''
+    substituteInPlace "ykman/pcsc/__init__.py" \
+      --replace-fail 'pkill' '${if stdenv.hostPlatform.isLinux then procps else "/usr"}/bin/pkill'
+  '';
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  build-system = with python3Packages; [
+    poetry-core
+  ];
+
+  dependencies = with python3Packages; [
+    cryptography
+    pyscard
+    fido2
+    click
+    keyring
+  ];
+
+  postInstall = ''
+    installManPage man/ykman.1
+
+    installShellCompletion --cmd ykman \
+      --bash <(_YKMAN_COMPLETE=bash_source "$out/bin/ykman") \
+      --zsh  <(_YKMAN_COMPLETE=zsh_source  "$out/bin/ykman") \
+      --fish <(_YKMAN_COMPLETE=fish_source "$out/bin/ykman") \
+  '';
+
+  nativeCheckInputs = with python3Packages; [
+    pytestCheckHook
+    makefun
+  ];
+
+  meta = {
+    homepage = "https://developers.yubico.com/yubikey-manager";
+    changelog = "https://github.com/Yubico/yubikey-manager/releases/tag/${src.tag}";
+    description = "Command line tool for configuring any YubiKey over all USB transports";
+
+    license = lib.licenses.bsd2;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      benley
+      lassulus
+      pinpox
+      nickcao
+    ];
+    mainProgram = "ykman";
+  };
+}

pkgs/by-name/yu/yubikey-personalization/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  pkg-config,
+  libusb1,
+  libyubikey,
+  json_c,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "yubikey-personalization";
+  version = "1.20.0";
+
+  src = fetchurl {
+    url = "https://developers.yubico.com/yubikey-personalization/Releases/ykpers-${version}.tar.gz";
+    sha256 = "14wvlwqnwj0gllkpvfqiy8ns938bwvjsz8x1hmymmx32m074vj0f";
+  };
+
+  patches = [
+    # remove after updating to next release
+    (fetchpatch {
+      name = "json-c-0.14-support.patch";
+      url = "https://github.com/Yubico/yubikey-personalization/commit/0aa2e2cae2e1777863993a10c809bb50f4cde7f8.patch";
+      sha256 = "1wnigf3hbq59i15kgxpq3pwrl1drpbj134x81mmv9xm1r44cjva8";
+    })
+
+    # Pull upstream fix for -fno-common toolchain support:
+    #  https://github.com/Yubico/yubikey-personalization/issues/155
+    (fetchpatch {
+      name = "fno-common.patch";
+      url = "https://github.com/Yubico/yubikey-personalization/commit/09ea16d9e2030e4da6ad00c1e5147e962aa7ff84.patch";
+      sha256 = "0n3ka8n7f3ndbxv3k0bi77d850kr2ypglkw81gqycpqyaciidqwa";
+    })
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    libusb1
+    libyubikey
+    json_c
+  ];
+
+  configureFlags = [
+    "--with-backend=libusb-1.0"
+  ];
+
+  doCheck = true;
+
+  doInstallCheck = true;
+
+  postInstall = ''
+    # Don't use 70-yubikey.rules because it depends on ConsoleKit
+    install -D -t $out/lib/udev/rules.d 69-yubikey.rules
+  '';
+
+  meta = with lib; {
+    homepage = "https://developers.yubico.com/yubikey-personalization";
+    description = "Library and command line tool to personalize YubiKeys";
+    license = licenses.bsd2;
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/yu/yubikey-touch-detector/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  libnotify,
+  gpgme,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  scdoc,
+}:
+
+buildGoModule rec {
+  pname = "yubikey-touch-detector";
+  version = "1.13.0";
+
+  src = fetchFromGitHub {
+    owner = "maximbaz";
+    repo = "yubikey-touch-detector";
+    tag = version;
+    hash = "sha256-aHR/y8rAKS+dMvRdB3oAmOiI7hTA6qlF4Z05OjwYOO4=";
+  };
+  vendorHash = "sha256-oHEcpu3QvcVC/YCtGtP7nNT9++BSU8BPT5pf8NdLrOo=";
+
+  nativeBuildInputs = [
+    pkg-config
+    scdoc
+    installShellFiles
+  ];
+
+  buildInputs = [
+    libnotify
+    gpgme
+  ];
+
+  postInstall = ''
+    install -Dm444 -t $out/share/doc/yubikey-touch-detector *.{md,example}
+
+    install -Dm444 -t $out/share/licenses/yubikey-touch-detector LICENSE
+
+    install -Dm444 -t $out/share/icons/hicolor/128x128/apps yubikey-touch-detector.png
+
+    install -Dm444 -t $out/lib/systemd/user *.{service,socket}
+
+    substituteInPlace $out/lib/systemd/user/*.service \
+      --replace /usr/bin/yubikey-touch-detector "$out/bin/yubikey-touch-detector"
+
+    scdoc < yubikey-touch-detector.1.scd > yubikey-touch-detector.1
+    installManPage yubikey-touch-detector.1
+  '';
+
+  meta = {
+    description = "Tool to detect when your YubiKey is waiting for a touch";
+    homepage = "https://github.com/maximbaz/yubikey-touch-detector";
+    maintainers = with lib.maintainers; [ sumnerevans ];
+    license = lib.licenses.isc;
+    platforms = lib.platforms.linux;
+    mainProgram = "yubikey-touch-detector";
+  };
+}

pkgs/by-name/yu/yubioath-flutter/helper.nix

@@ -0,0 +1,46 @@
+{
+  buildPythonApplication,
+  yubikey-manager,
+  mss,
+  zxing-cpp,
+  pillow,
+  poetry-core,
+
+  src,
+  version,
+  meta,
+}:
+
+buildPythonApplication {
+  pname = "yubioath-flutter-helper";
+  inherit src version meta;
+
+  pyproject = true;
+
+  sourceRoot = "${src.name}/helper";
+
+  nativeBuildInputs = [
+    poetry-core
+  ];
+
+  pythonRelaxDeps = true;
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace "authenticator-helper" "yubioath-flutter-helper" \
+      --replace "0.1.0" "${version}"
+  '';
+
+  postInstall = ''
+    install -Dm 0755 authenticator-helper.py $out/bin/authenticator-helper
+    install -d $out/libexec/helper
+    ln -fs $out/bin/authenticator-helper $out/libexec/helper/authenticator-helper
+  '';
+
+  propagatedBuildInputs = [
+    yubikey-manager
+    mss
+    zxing-cpp
+    pillow
+  ];
+}

pkgs/by-name/yu/yubioath-flutter/package.nix

@@ -0,0 +1,116 @@
+{
+  lib,
+  flutter335,
+  python3,
+  fetchFromGitHub,
+  pcre2,
+  libnotify,
+  libappindicator,
+  pkg-config,
+  gnome-screenshot,
+  makeWrapper,
+  removeReferencesTo,
+  runCommand,
+  yq,
+  yubioath-flutter,
+  _experimental-update-script-combinators,
+  gitUpdater,
+}:
+
+flutter335.buildFlutterApplication rec {
+  pname = "yubioath-flutter";
+  version = "7.3.0";
+
+  src = fetchFromGitHub {
+    owner = "Yubico";
+    repo = "yubioath-flutter";
+    tag = version;
+    hash = "sha256-1Hr8ZDHXiLiYfQg4PEpmIuIJR/USbsGCgI4YZSex2Eg=";
+  };
+
+  pubspecLock = lib.importJSON ./pubspec.lock.json;
+
+  gitHashes.window_manager = "sha256-WKcNwEOthXj1S2lKlpdhy+r8JZslVqhwY2ywXeTSBEs=";
+
+  postPatch = ''
+    rm -f pubspec.lock
+
+    substituteInPlace linux/CMakeLists.txt \
+      --replace-fail "../build/linux/helper" "${passthru.helper}/libexec/helper"
+  '';
+
+  nativeBuildInputs = [
+    makeWrapper
+    removeReferencesTo
+    pkg-config
+  ];
+
+  buildInputs = [
+    pcre2
+    libnotify
+    libappindicator
+  ];
+
+  preInstall = ''
+    # Make sure we have permission to delete things CMake has copied in to our build directory from elsewhere.
+    chmod -R +w build
+  '';
+
+  postInstall = ''
+    # Swap the authenticator-helper symlink with the correct symlink.
+    ln -fs "${passthru.helper}/bin/authenticator-helper" "$out/app/$pname/helper/authenticator-helper"
+
+    # Move the icon.
+    mkdir $out/share/pixmaps
+    mv $out/app/$pname/linux_support/com.yubico.yubioath.png $out/share/pixmaps
+
+    # Cleanup.
+    rm -rf \
+      "$out/app/$pname/README.adoc" \
+      "$out/app/$pname/desktop_integration.sh" \
+      "$out/app/$pname/linux_support" \
+      $out/bin/* # We will repopulate this directory later.
+
+    # Symlink binary.
+    ln -sf "$out/app/$pname/authenticator" "$out/bin/yubioath-flutter"
+
+    # Set the correct path to the binary in desktop file.
+    substituteInPlace "$out/share/applications/com.yubico.yubioath.desktop" \
+      --replace-fail '"@EXEC_PATH/authenticator"' "yubioath-flutter" \
+      --replace-fail "@EXEC_PATH/linux_support/com.yubico.yubioath.png" "com.yubico.yubioath"
+  '';
+
+  # Needed for QR scanning to work
+  extraWrapProgramArgs = ''
+    --prefix PATH : ${lib.makeBinPath [ gnome-screenshot ]}
+  '';
+
+  passthru = {
+    helper = python3.pkgs.callPackage ./helper.nix { inherit src version meta; };
+    pubspecSource =
+      runCommand "pubspec.lock.json"
+        {
+          nativeBuildInputs = [ yq ];
+          inherit (yubioath-flutter) src;
+        }
+        ''
+          cat $src/pubspec.lock | yq > $out
+        '';
+    updateScript = _experimental-update-script-combinators.sequence [
+      (gitUpdater { })
+      (_experimental-update-script-combinators.copyAttrOutputToFile "yubioath-flutter.pubspecSource" ./pubspec.lock.json)
+    ];
+  };
+
+  meta = {
+    description = "Yubico Authenticator for Desktop";
+    mainProgram = "yubioath-flutter";
+    homepage = "https://github.com/Yubico/yubioath-flutter";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ lukegb ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+    ];
+  };
+}

pkgs/by-name/yu/yudit/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  xorg,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yudit";
+  version = "3.1.0";
+
+  src = fetchurl {
+    url = "https://www.yudit.org/download/yudit-${finalAttrs.version}.tar.gz";
+    hash = "sha256-oYgjTWEnNXaE9Sw9bGpLnY9avQ99tnJWa/RE73p85Vc=";
+  };
+
+  buildInputs = [
+    xorg.libX11
+  ];
+
+  meta = {
+    description = "Free Unicode plain-text editor for Unix-like systems";
+    homepage = "https://www.yudit.org/";
+    changelog = "https://www.yudit.org/download/CHANGELOG.TXT";
+    mainProgram = "yudit";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ doronbehar ];
+    # Might work on Darwin but currently fails, and upstream doesn't officially
+    # supports it.
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/yu/yuhaiin/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  versionCheckHook,
+}:
+
+buildGoModule rec {
+  pname = "yuhaiin";
+  version = "0.3.8";
+
+  src = fetchFromGitHub {
+    owner = "yuhaiin";
+    repo = "yuhaiin";
+    tag = "v${version}";
+    hash = "sha256-9vrq2qKbBLObANzVWrP73BuhQdY0JSEdPci420lj3Fg=";
+  };
+
+  vendorHash = "sha256-FSm/oG0XkTqx93DrtVKoJAmIlkHNXEG20IanXuMxBgw=";
+
+  subPackages = [ "cmd/yuhaiin" ];
+
+  ldflags =
+    let
+      # https://github.com/yuhaiin/yuhaiin/blob/dbbcd93c3dce141a3323e03043d5d0eabe7252d1/makefile#L1
+      module = "github.com/Asutorufa/yuhaiin/internal";
+    in
+    [
+      "-s"
+      "-w"
+      "-X ${module}/version.Version=v${version}"
+      "-X ${module}/version.GitCommit=${src.rev}"
+      "-X ${module}/version.BuildDate=unknown"
+    ];
+
+  nativeCheckInputs = [
+    versionCheckHook
+  ];
+
+  versionCheckProgramArg = [ "--version" ];
+
+  meta = {
+    description = "Proxy kit for Linux/Windows/MacOS";
+    homepage = "https://github.com/yuhaiin/yuhaiin";
+    changelog = "https://github.com/yuhaiin/yuhaiin/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ oluceps ];
+    mainProgram = "yuhaiin";
+  };
+}

pkgs/by-name/yu/yuicompressor/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  jre,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yuicompressor";
+  version = "2.4.8";
+
+  src = fetchurl {
+    url = "https://github.com/yui/yuicompressor/releases/download/v${finalAttrs.version}/yuicompressor-${finalAttrs.version}.jar";
+    sha256 = "1qjxlak9hbl9zd3dl5ks0w4zx5z64wjsbk7ic73r1r45fasisdrh";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ jre ];
+
+  buildCommand = ''
+    mkdir -p $out/{bin,lib}
+    ln -s $src $out/lib/yuicompressor.jar
+    makeWrapper ${jre}/bin/java $out/bin/yuicompressor --add-flags \
+     "-cp $out/lib/yuicompressor.jar com.yahoo.platform.yui.compressor.YUICompressor"
+  '';
+
+  meta = {
+    description = "JavaScript and CSS minifier";
+    mainProgram = "yuicompressor";
+    homepage = "http://yui.github.io/yuicompressor/";
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ jwiegley ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/yu/yunfaavatar/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  imagemagick,
+  makeWrapper,
+}:
+stdenvNoCC.mkDerivation rec {
+  pname = "yunfaavatar";
+  version = "0.2.0";
+
+  src = fetchFromGitHub {
+    owner = "yunfachi";
+    repo = "yunfaAvatar";
+    rev = version;
+    hash = "sha256-hCpbe+gW9hkiVOKq7a55n5s3bMpyCNGWiY3D2b4VYxg=";
+  };
+
+  strictDeps = true;
+  nativeBuildInputs = [ makeWrapper ];
+
+  makeFlags = [
+    "PREFIX=${placeholder "out"}"
+  ];
+
+  postInstall = ''
+    wrapProgram "$out/bin/yunfaavatar" \
+      --prefix PATH : "${lib.makeBinPath [ imagemagick ]}"
+  '';
+
+  meta = with lib; {
+    description = "Utility for automatic centralized changing of avatar in Github, Discord, Steam, Shikimori, and many more";
+    homepage = "https://github.com/yunfachi/yunfaAvatar";
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ yunfachi ];
+    mainProgram = "yunfaavatar";
+  };
+}

pkgs/by-name/yu/yutto/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  ffmpeg,
+  nix-update-script,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "yutto";
+  version = "2.0.3";
+  pyproject = true;
+
+  pythonRelaxDeps = true;
+
+  src = fetchFromGitHub {
+    owner = "yutto-dev";
+    repo = "yutto";
+    tag = "v${version}";
+    hash = "sha256-giwCLA9M1XR0neLJVfO017Q1wK34yVQpOxUzgShDJL0=";
+  };
+
+  build-system = with python3Packages; [ hatchling ];
+
+  dependencies =
+    with python3Packages;
+    [
+      httpx
+      aiofiles
+      biliass
+      dict2xml
+      colorama
+      typing-extensions
+      pydantic
+    ]
+    ++ (with httpx.optional-dependencies; http2 ++ socks);
+
+  preFixup = ''
+    makeWrapperArgs+=(--prefix PATH : ${lib.makeBinPath [ ffmpeg ]})
+  '';
+
+  pythonImportsCheck = [ "yutto" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Bilibili downloader";
+    homepage = "https://github.com/yutto-dev/yutto";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ linsui ];
+    mainProgram = "yutto";
+  };
+}

pkgs/by-name/yu/yuview/disable_version_check.patch

@@ -0,0 +1,15 @@
+diff --git a/YUViewLib/src/common/Typedef.h b/YUViewLib/src/common/Typedef.h
+--- a/YUViewLib/src/common/Typedef.h
++++ b/YUViewLib/src/common/Typedef.h
+@@ -212,12 +212,7 @@ private:
+ #define YUVIEW_VERSION "Unknown"
+ #endif
+ 
+-#ifndef YUVIEW_HASH
+ #define VERSION_CHECK 0
+-#define YUVIEW_HASH 0
+-#else
+-#define VERSION_CHECK 1
+-#endif
+ 
+ #define MAX_RECENT_FILES 10

pkgs/by-name/yu/yuview/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libsForQt5,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yuview";
+  version = "2.14";
+
+  src = fetchFromGitHub {
+    owner = "IENT";
+    repo = "YUView";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-YuKPRYBr1CKrwickk1T89ZCYFt99jP86tdanp+JZMO4=";
+  };
+
+  nativeBuildInputs = [
+    libsForQt5.qmake
+    libsForQt5.wrapQtAppsHook
+  ];
+
+  patches = [ ./disable_version_check.patch ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    changelog = "https://github.com/IENT/YUView/releases/tag/${finalAttrs.src.tag}";
+    homepage = "https://ient.github.io/YUView";
+    description = "YUV Viewer and Analysis Tool";
+    longDescription = ''
+      YUView is a Qt based YUV player with an advanced analytic toolset for
+      Linux, Windows and Mac. At its core, YUView is a powerful YUV player that
+      can open and show almost any YUV format. With its simple interface it is
+      easy to navigate through sequences and inspect details and a side by side
+      and comparison view can help to spot differences between two sequences. A
+      sophisticated statistics renderer can overlay the video with supplemental
+      information. More features include playlists, support for visual tests and
+      presentations, support of compressed formats (through libde265 and
+      FFmpeg), support for raw RGB files as well as image files and image
+      sequences, and many more. Further information can be found in the YUV help
+      in the application itself or in our wiki.
+    '';
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ leixb ];
+    platforms = lib.platforms.unix;
+    mainProgram = "YUView";
+  };
+})