push sheeet

pkgs/by-name/zd/zd1211fw/package.nix

@@ -0,0 +1,31 @@
+{
+  stdenvNoCC,
+  lib,
+  fetchurl,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "zd1211-firmware";
+  version = "1.5";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/zd1211/${pname}-${version}.tar.bz2";
+    hash = "sha256-8R04ENf3KDOZf2NFhKWG3M7XGjU/llq/gQYuxDHQKxI=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib/firmware/zd1211
+    cp zd1211* $out/lib/firmware/zd1211
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Firmware for the ZyDAS ZD1211(b) 802.11a/b/g USB WLAN chip";
+    homepage = "https://sourceforge.net/projects/zd1211/";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/zd/zdbsp/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  cmake,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zdbsp";
+  version = "1.19";
+
+  src = fetchzip {
+    url = "https://zdoom.org/files/utils/zdbsp/zdbsp-${version}-src.zip";
+    sha256 = "sha256-DTj0jMNurvwRwMbo0L4+IeNlbfIwUbqcG1LKd68C08g=";
+    stripRoot = false;
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    zlib
+  ];
+
+  installPhase = ''
+    install -Dm755 zdbsp $out/bin/zdbsp
+  '';
+
+  meta = with lib; {
+    homepage = "https://zdoom.org/wiki/ZDBSP";
+    description = "ZDoom's internal node builder for DOOM maps";
+    mainProgram = "zdbsp";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      lassulus
+      siraben
+    ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/zd/zdelta/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation {
+  pname = "zdelta";
+  version = "2.1";
+
+  src = fetchurl {
+    url = "https://web.archive.org/web/20160316212948/http://cis.poly.edu/zdelta/downloads/zdelta-2.1.tar.gz";
+    sha256 = "sha256-WiQKWxJkINIwRBcdiuVLMDiupQ8gOsiXOEZvHDa5iFg=";
+  };
+
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -p zdc zdu $out/bin
+  '';
+
+  meta = with lib; {
+    homepage = "https://web.archive.org/web/20160316212948/http://cis.poly.edu/zdelta/";
+    platforms = platforms.all;
+    license = licenses.zlib;
+  };
+}

pkgs/by-name/zd/zdns/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "zdns";
+  version = "2.0.5";
+
+  src = fetchFromGitHub {
+    owner = "zmap";
+    repo = "zdns";
+    tag = "v${version}";
+    hash = "sha256-e01+TjJETpWNrdtG+lHHGmS9ZS9RijOo5wRnEv6w5jk=";
+  };
+
+  vendorHash = "sha256-YlSm4uMDw5I/R4VRpoo5+t/zTwY7J62faodwKlrfbTs=";
+
+  preCheck = ''
+    # Tests require network access
+    substituteInPlace src/cli/worker_manager_test.go \
+      --replace-fail "TestConvertNameServerStringToNameServer" "SkipTestConvertNameServerStringToNameServer"
+  '';
+
+  meta = {
+    description = "CLI DNS lookup tool";
+    mainProgram = "zdns";
+    homepage = "https://github.com/zmap/zdns";
+    license = with lib.licenses; [ asl20 ];
+    maintainers = with lib.maintainers; [ fab ];
+  };
+}

pkgs/by-name/zd/zdoom/package.nix

@@ -0,0 +1,82 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  p7zip,
+  cmake,
+  SDL2,
+  openal,
+  fluidsynth,
+  soundfont-fluid,
+  bzip2,
+  zlib,
+  libjpeg,
+  game-music-emu,
+  libsndfile,
+  mpg123,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zdoom";
+  majorVersion = "2.8";
+  version = "${majorVersion}.1";
+
+  src = fetchurl {
+    url = "https://zdoom.org/files/zdoom/${majorVersion}/zdoom-${version}-src.7z";
+    sha256 = "0453fqrh9l00xwphfxni5qkf9y134n3s1mr1dvi5cbkxcva7j8bq";
+  };
+
+  nativeBuildInputs = [
+    p7zip
+    cmake
+  ];
+  buildInputs = [
+    SDL2
+    openal
+    fluidsynth
+    bzip2
+    zlib
+    libjpeg
+    game-music-emu
+    libsndfile
+    mpg123
+  ];
+
+  cmakeFlags = [
+    "-DFORCE_INTERNAL_GME=OFF"
+    "-DGME_INCLUDE_DIR=${game-music-emu}/include"
+    "-DGME_LIBRARIES=${game-music-emu}/lib/libgme.so"
+  ];
+
+  sourceRoot = ".";
+
+  NIX_CFLAGS_LINK = [
+    "-lopenal"
+    "-lfluidsynth"
+  ];
+
+  preConfigure = ''
+    sed -i \
+      -e "s@/usr/share/sounds/sf2/@${soundfont-fluid}/share/soundfonts/@g" \
+      -e "s@FluidR3_GM.sf2@FluidR3_GM2-2.sf2@g" \
+      src/sound/music_fluidsynth_mididevice.cpp
+  '';
+
+  installPhase = ''
+    install -Dm755 zdoom "$out/lib/zdoom/zdoom"
+    for i in *.pk3; do
+      install -Dm644 "$i" "$out/lib/zdoom/$i"
+    done
+    mkdir -p $out/bin
+    ln -s $out/lib/zdoom/zdoom $out/bin/zdoom
+  '';
+
+  meta = with lib; {
+    homepage = "http://zdoom.org/";
+    description = "Enhanced port of the official DOOM source code";
+    # Doom source license, MAME license
+    license = licenses.unfreeRedistributable;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ lassulus ];
+  };
+}