push sheeet

pkgs/by-name/zu/zuban/package.nix

@@ -0,0 +1,47 @@
+{
+  fetchFromGitHub,
+  lib,
+  rustPlatform,
+  versionCheckHook,
+  nix-update-script,
+}:
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "zuban";
+
+  version = "0.0.23";
+
+  src = fetchFromGitHub {
+    owner = "zubanls";
+    repo = "zuban";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-EPF1HW/oqUKHLTorkO3C+X+ziq6i1lCxGY5y1ioKg6A=";
+  };
+
+  buildAndTestSubdir = "crates/zuban";
+
+  cargoHash = "sha256-TAFdS4NmXchmhqVRcsckz6GhZG35IE2fukDlZiRF8Ms=";
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Mypy-compatible Python Language Server built in Rust";
+    homepage = "https://zubanls.com";
+    # There's no changelog file yet, but they post updates on their blog.
+    changelog = "https://zubanls.com/blog/";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [
+      mcjocobe
+    ];
+    platforms = lib.platforms.all;
+    mainProgram = "zuban";
+  };
+})

pkgs/by-name/zu/zug/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  cmake,
+  boost,
+  catch2,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "zug";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "arximboldi";
+    repo = "zug";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Ti0EurhGQgWSXzSOlH9/Zsp6kQ/+qGjWbfHGTPpfehs=";
+  };
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/arximboldi/zug/commit/c8c74ada30d931e40636c13763b892f20d3ce1ae.patch";
+      hash = "sha256-0x+ScRnziBeyHWYJowcVb2zahkcK2qKrMVVk2twhtHA=";
+    })
+  ];
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    boost
+    catch2
+  ];
+
+  cmakeFlags = [ "-Dzug_BUILD_EXAMPLES=OFF" ];
+
+  preConfigure = ''
+    rm BUILD
+  '';
+
+  meta = {
+    homepage = "https://github.com/arximboldi/zug";
+    description = "Library for functional interactive c++ programs";
+    maintainers = with lib.maintainers; [ nek0 ];
+    license = lib.licenses.boost;
+  };
+})

pkgs/by-name/zu/zuki-themes/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  sassc,
+  gdk-pixbuf,
+  librsvg,
+  gtk_engines,
+  gtk-engine-murrine,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zuki-themes";
+  version = "4.0";
+
+  src = fetchFromGitHub {
+    owner = "lassekongo83";
+    repo = "zuki-themes";
+    rev = "v${version}";
+    sha256 = "1q026wa8xgyb6f5k7pqpm5zav30dbnm3b8w59as3sh8rhfgpbf80";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    sassc
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    librsvg
+    gtk_engines
+  ];
+
+  propagatedUserEnvPkgs = [ gtk-engine-murrine ];
+
+  meta = with lib; {
+    description = "Themes for GTK, gnome-shell and Xfce";
+    homepage = "https://github.com/lassekongo83/zuki-themes";
+    license = licenses.gpl3Only;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}

pkgs/by-name/zu/zulip-term/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  glibcLocales,
+  libnotify,
+}:
+
+let
+  py = python3.override {
+    self = py;
+    packageOverrides = self: super: {
+
+      # Requires "urwid~=2.1.2", otherwise some tests are failing
+      urwid = super.urwid.overridePythonAttrs (oldAttrs: rec {
+        version = "2.1.2";
+        src = fetchFromGitHub {
+          owner = "urwid";
+          repo = "urwid";
+          rev = "refs/tags/${version}";
+          hash = "sha256-oPb2h/+gaqkZTXIiESjExMfBNnOzDvoMkXvkZ/+KVwo=";
+        };
+        doCheck = false;
+      });
+    };
+  };
+in
+with py.pkgs;
+
+buildPythonApplication rec {
+  pname = "zulip-term";
+  version = "0.7.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "zulip";
+    repo = "zulip-terminal";
+    rev = "refs/tags/${version}";
+    hash = "sha256-ZouUU4p1FSGMxPuzDo5P971R+rDXpBdJn2MqvkJO+Fw=";
+  };
+
+  patches = [
+    ./pytest-executable-name.patch
+  ];
+
+  nativeBuildInputs = with py.pkgs; [
+    setuptools
+  ];
+
+  propagatedBuildInputs = with py.pkgs; [
+    beautifulsoup4
+    lxml
+    pygments
+    pyperclip
+    python-dateutil
+    pytz
+    typing-extensions
+    tzlocal
+    urwid
+    urwid-readline
+    zulip
+  ];
+
+  nativeCheckInputs = [
+    glibcLocales
+  ]
+  ++ (with python3.pkgs; [
+    pytestCheckHook
+    pytest-cov-stub
+    pytest-mock
+  ]);
+
+  makeWrapperArgs = [
+    "--prefix"
+    "PATH"
+    ":"
+    (lib.makeBinPath [ libnotify ])
+  ];
+
+  meta = {
+    description = "Zulip's official terminal client";
+    homepage = "https://github.com/zulip/zulip-terminal";
+    changelog = "https://github.com/zulip/zulip-terminal/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ dotlambda ];
+  };
+}

pkgs/by-name/zu/zulip-term/pytest-executable-name.patch

@@ -0,0 +1,22 @@
+diff --git a/tests/cli/test_run.py b/tests/cli/test_run.py
+index 1452cfd..0a21c09 100644
+--- a/tests/cli/test_run.py
++++ b/tests/cli/test_run.py
+@@ -240,7 +240,7 @@ def test_main_multiple_autohide_options(
+ 
+     captured = capsys.readouterr()
+     lines = captured.err.strip("\n")
+-    lines = lines.split("pytest: ", 1)[1]
++    lines = lines.split("__main__.py: ", 1)[1]
+     expected = f"error: argument {options[1]}: not allowed with argument {options[0]}"
+     assert lines == expected
+ 
+@@ -277,7 +277,7 @@ def test_main_multiple_notify_options(
+ 
+     captured = capsys.readouterr()
+     lines = captured.err.strip("\n")
+-    lines = lines.split("pytest: ", 1)[1]
++    lines = lines.split("__main__.py: ", 1)[1]
+     expected = f"error: argument {options[1]}: not allowed with argument {options[0]}"
+     assert lines == expected
+ 

pkgs/by-name/zu/zulip/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+  python3,
+  electron_37,
+  makeDesktopItem,
+  makeShellWrapper,
+  copyDesktopItems,
+}:
+
+buildNpmPackage rec {
+  pname = "zulip";
+  version = "5.12.2";
+
+  src = fetchFromGitHub {
+    owner = "zulip";
+    repo = "zulip-desktop";
+    tag = "v${version}";
+    hash = "sha256-+OS3Fw4Z1ZOzXou1sK39AUFLI78nUl4UBVYA3SNH7I0=";
+  };
+
+  npmDepsHash = "sha256-5qjBZfl9kse97y5Mru4RF4RLTbojoXeUp84I/bOHEcw=";
+  makeCacheWritable = true;
+
+  env = {
+    ELECTRON_SKIP_BINARY_DOWNLOAD = 1;
+  };
+
+  nativeBuildInputs = [
+    makeShellWrapper
+    copyDesktopItems
+    (python3.withPackages (ps: with ps; [ distutils ]))
+  ];
+
+  dontNpmBuild = true;
+  buildPhase = ''
+    runHook preBuild
+
+    npm run pack -- \
+      -c.electronDist=${electron_37}/libexec/electron \
+      -c.electronVersion=${electron_37.version}
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/share/lib/zulip"
+    cp -r dist/*-unpacked/resources/app.asar* "$out/share/lib/zulip/"
+
+    install -m 444 -D app/resources/zulip.png $out/share/icons/hicolor/512x512/apps/zulip.png
+
+    makeShellWrapper '${lib.getExe electron_37}' "$out/bin/zulip" \
+      --add-flags "$out/share/lib/zulip/app.asar" \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-wayland-ime=true}}" \
+      --inherit-argv0
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "zulip";
+      exec = "zulip %U";
+      icon = "zulip";
+      desktopName = "Zulip";
+      comment = "Zulip Desktop Client for Linux";
+      categories = [
+        "Chat"
+        "Network"
+        "InstantMessaging"
+      ];
+      startupWMClass = "Zulip";
+      terminal = false;
+    })
+  ];
+
+  meta = with lib; {
+    description = "Desktop client for Zulip Chat";
+    homepage = "https://zulip.com";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ andersk ];
+    platforms = lib.platforms.linux;
+    mainProgram = "zulip";
+  };
+}

pkgs/by-name/zu/zunit/package.nix

@@ -0,0 +1,96 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  zsh,
+  revolver,
+  installShellFiles,
+  testers,
+  nix-update-script,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "zunit";
+  version = "0.8.2";
+
+  src = fetchFromGitHub {
+    owner = "zunit-zsh";
+    repo = "zunit";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-GkBewb795piCaniZJZpGEZFhKaNs8p8swV5z34OegPY=";
+    deepClone = true; # Needed in order to get "tests" folder
+  };
+
+  strictDeps = true;
+  doCheck = true;
+  doInstallCheck = true;
+
+  nativeBuildInputs = [
+    zsh
+    installShellFiles
+  ];
+  nativeCheckInputs = [ revolver ];
+  buildInputs = [
+    zsh
+    revolver
+  ];
+
+  postPatch = ''
+    for i in $(find src/ -type f -print); do
+      substituteInPlace $i \
+        --replace-warn " revolver " " ${lib.getExe revolver} "
+    done
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    zsh build.zsh
+
+    runHook postBuild
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+
+    HOME="$TEMPDIR" zsh zunit
+
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 zunit $out/bin/zunit
+
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    installShellCompletion --cmd zunit --zsh zunit.zsh-completion
+  '';
+
+  installCheckPhase = ''
+    runHook preInstallCheck
+
+    PATH=$PATH:$out/bin zunit --help
+
+    runHook postInstallCheck
+  '';
+
+  passthru = {
+    tests.version = testers.testVersion { package = finalAttrs.finalPackage; };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Powerful testing framework for ZSH projects";
+    homepage = "https://zunit.xyz/";
+    downloadPage = "https://github.com/zunit-zsh/zunit/releases";
+    changelog = "https://github.com/zunit-zsh/zunit/releases/tag/${finalAttrs.src.rev}";
+    license = lib.licenses.mit;
+    mainProgram = "zunit";
+    inherit (zsh.meta) platforms;
+    maintainers = with lib.maintainers; [ d-brasher ];
+  };
+})

pkgs/by-name/zu/zuo/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  buildPackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "zuo";
+  version = "1.12";
+
+  src = fetchFromGitHub {
+    owner = "racket";
+    repo = "zuo";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-BUJtAKB2tz04LhkCsDWBjgTTymU4U3Zcdm+RDYawfxQ=";
+  };
+
+  strictDeps = true;
+  enableParallelBuilding = true;
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+  nativeBuildInputs = [ autoreconfHook ];
+
+  configureFlags = [
+    "CC_FOR_BUILD=cc"
+  ];
+
+  doCheck = true;
+  enableParallelChecking = true;
+
+  meta = {
+    description = "Tiny Racket for Scripting";
+    mainProgram = "zuo";
+    homepage = "https://github.com/racket/zuo";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.all;
+    maintainers = [ lib.maintainers.RossSmyth ];
+  };
+})

pkgs/by-name/zu/zuse/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "zuse";
+  version = "1.0";
+
+  src = fetchFromGitHub {
+    owner = "babycommando";
+    repo = "zuse";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-zKAAHvbaR1HnRe6CmAEi/6iAOHCcbGVS1/jSrQwksRk=";
+  };
+
+  vendorHash = "sha256-P7T244d1OpFDqwRu3gdEI1OAqq9EbpL1YO2mlTw0Jew=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "IRC client for the terminal made in Go with Bubbletea";
+    homepage = "https://github.com/babycommando/zuse";
+    changelog = "https://github.com/babycommando/zuse/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ yiyu ];
+    mainProgram = "zuse";
+  };
+})

pkgs/by-name/zu/zutty/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  pkg-config,
+  freetype,
+  wafHook,
+  python3,
+  libXmu,
+  glew,
+  ucs-fonts,
+  nixosTests,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "zutty";
+  version = "0.16-unstable-2024-08-18";
+
+  src = fetchgit {
+    url = "https://git.hq.sig7.se/zutty.git";
+    rev = "04b2ca3b3aaa070c41583247f8112c31b6003886"; # 20240818
+    hash = "sha256-izUbn2B3RqIIOW9tuL7DFLqJdektCftxnpQssJMYxC8=";
+  };
+
+  postPatch =
+    let
+      fontpaths = [
+        "/run/current-system/sw/share/X11/fonts" # available if fonts.fontDir.enable = true
+        "${ucs-fonts}/share/fonts"
+      ];
+    in
+    ''
+      substituteInPlace src/options.h \
+        --replace-fail /usr/share/fonts ${builtins.concatStringsSep ":" fontpaths}
+    '';
+
+  nativeBuildInputs = [
+    pkg-config
+    wafHook
+    python3
+  ];
+
+  buildInputs = [
+    freetype
+    libXmu
+    glew
+  ];
+
+  passthru = {
+    tests = lib.optionalAttrs stdenv.hostPlatform.isLinux {
+      default = nixosTests.terminal-emulators.zutty;
+    };
+  };
+
+  meta = {
+    homepage = "https://tomscii.sig7.se/zutty/";
+    description = "X terminal emulator rendering through OpenGL ES Compute Shaders";
+    license = lib.licenses.gpl3Plus;
+    maintainers = [ lib.maintainers.rolfschr ];
+    platforms = lib.platforms.linux;
+  };
+})