push sheeet

pkgs/data/themes/adwaita-qt/default.nix

@@ -0,0 +1,73 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  nix-update-script,
+  cmake,
+  ninja,
+  qtbase,
+  qtwayland,
+  qt5,
+  xorg,
+  useQt6 ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "adwaita-qt";
+  version = "1.4.2";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "FedoraQt";
+    repo = "adwaita-qt";
+    rev = version;
+    sha256 = "sha256-K/+SL52C+M2OC4NL+mhBnm/9BwH0KNNTGIDmPwuUwkM=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ];
+
+  buildInputs = [
+    qtbase
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    xorg.libxcb
+  ]
+  ++ lib.optionals (!useQt6) [
+    qt5.qtx11extras
+  ]
+  ++ lib.optionals useQt6 [
+    qtwayland
+  ];
+
+  # Qt setup hook complains about missing `wrapQtAppsHook` otherwise.
+  dontWrapQtApps = true;
+
+  cmakeFlags = lib.optionals useQt6 [
+    "-DUSE_QT6=true"
+  ];
+
+  postPatch = ''
+    # Fix plugin dir
+    substituteInPlace src/style/CMakeLists.txt \
+       --replace "DESTINATION \"\''${QT_PLUGINS_DIR}/styles" "DESTINATION \"$qtPluginPrefix/styles"
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = with lib; {
+    description = "Style to bend Qt applications to look like they belong into GNOME Shell";
+    homepage = "https://github.com/FedoraQt/adwaita-qt";
+    license = licenses.gpl2Plus;
+    maintainers = [ ];
+    platforms = platforms.all;
+  };
+}

pkgs/data/themes/andromeda-gtk-theme/default.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  gtk-engine-murrine,
+}:
+
+stdenvNoCC.mkDerivation {
+  pname = "andromeda-gtk-theme";
+  version = "0-unstable-2024-06-24";
+
+  srcs = [
+    (fetchFromGitHub {
+      owner = "EliverLara";
+      repo = "Andromeda-gtk";
+      rev = "1d86d5cab146a1841bfe2e5c4f0a109b315cfd98";
+      hash = "sha256-YzmNo7WZjF/BLKgT2wJXk0ms8bb5AydFcfPzFmRrhkU=";
+      name = "Andromeda";
+    })
+
+    (fetchFromGitHub {
+      owner = "EliverLara";
+      repo = "Andromeda-gtk";
+      rev = "7b0f5508269695054306eec10bd56ef5598ddf4a";
+      hash = "sha256-Bi5G3zs1bFYbOf74864eZHPUIJvBbByQNtDfqkNUSxo=";
+      name = "Andromeda-standard-buttons";
+    })
+  ];
+
+  sourceRoot = ".";
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/themes
+    cp -a Andromeda* $out/share/themes
+
+    # remove uneeded files, which are not distributed in https://www.gnome-look.org/p/2039961/
+    rm -rf $out/share/themes/*/.gitignore
+    rm -rf $out/share/themes/*/Art
+    rm -rf $out/share/themes/*/LICENSE
+    rm -rf $out/share/themes/*/README.md
+    rm -rf $out/share/themes/*/{package.json,package-lock.json,Gulpfile.js}
+    rm -rf $out/share/themes/*/src
+    rm -rf $out/share/themes/*/cinnamon/*.scss
+    rm -rf $out/share/themes/*/gnome-shell/{earlier-versions,extensions,*.scss}
+    rm -rf $out/share/themes/*/gtk-2.0/{assets.svg,assets.txt,links.fish,render-assets.sh}
+    rm -rf $out/share/themes/*/gtk-3.0/{apps,widgets,*.scss}
+    rm -rf $out/share/themes/*/gtk-4.0/{apps,widgets,*.scss}
+    rm -rf $out/share/themes/*/xfwm4/{assets,render_assets.fish}
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Elegant dark theme for gnome, mate, budgie, cinnamon, xfce";
+    homepage = "https://github.com/EliverLara/Andromeda-gtk";
+    license = licenses.gpl3Only;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      jakedevs
+      romildo
+    ];
+  };
+}

pkgs/data/themes/ant-theme/ant-bloody.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gtk-engine-murrine,
+}:
+
+let
+  themeName = "Ant-Bloody";
+in
+stdenv.mkDerivation rec {
+  pname = "ant-bloody-theme";
+  version = "1.3.0";
+
+  src = fetchurl {
+    url = "https://github.com/EliverLara/${themeName}/releases/download/v${version}/${themeName}.tar";
+    sha256 = "0rrz50kmzjmqj17hvrw67pbaclwxv85i5m08s7842iky6dnn5z8s";
+  };
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/themes/${themeName}
+    cp -a * $out/share/themes/${themeName}
+    rm -r $out/share/themes/${themeName}/{Art,LICENSE,README.md,gtk-2.0/render-assets.sh}
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Bloody variant of the Ant theme";
+    homepage = "https://github.com/EliverLara/${themeName}";
+    license = licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ alexarice ];
+  };
+}

pkgs/data/themes/ant-theme/ant-nebula.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gtk-engine-murrine,
+}:
+
+let
+  themeName = "Ant-Nebula";
+in
+stdenv.mkDerivation rec {
+  pname = "ant-nebula-theme";
+  version = "1.3.0";
+
+  src = fetchurl {
+    url = "https://github.com/EliverLara/${themeName}/releases/download/v${version}/${themeName}.tar";
+    sha256 = "1xpgw577nmgjk547mg2vvv0gdai60srgncykm5pb1w8dnlk69jbz";
+  };
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/themes/${themeName}
+    cp -a * $out/share/themes/${themeName}
+    rm -r $out/share/themes/${themeName}/{Art,LICENSE,README.md,gtk-2.0/render-assets.sh}
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Nebula variant of the Ant theme";
+    homepage = "https://github.com/EliverLara/${themeName}";
+    license = licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ alexarice ];
+  };
+}

pkgs/data/themes/ant-theme/ant.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gtk-engine-murrine,
+}:
+
+let
+  themeName = "Ant";
+in
+stdenv.mkDerivation rec {
+  pname = "ant-theme";
+  version = "1.3.0";
+
+  src = fetchurl {
+    url = "https://github.com/EliverLara/${themeName}/releases/download/v${version}/${themeName}.tar";
+    sha256 = "1r795v96ywzcb4dq08q2fdbmfia32g36cc512mhy41s8fb1a47dz";
+  };
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/themes/${themeName}
+    cp -a * $out/share/themes/${themeName}
+    rm -r $out/share/themes/${themeName}/{Art,LICENSE,README.md,gtk-2.0/render-assets.sh}
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Flat and light theme with a modern look";
+    homepage = "https://github.com/EliverLara/${themeName}";
+    license = licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ alexarice ];
+  };
+}

pkgs/data/themes/chili-sddm/default.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  qtgraphicaleffects,
+  themeConfig ? { },
+}:
+let
+  customToString = x: if builtins.isBool x then lib.boolToString x else toString x;
+  configLines = lib.mapAttrsToList (name: value: lib.nameValuePair name value) themeConfig;
+  configureTheme =
+    "cp theme.conf theme.conf.orig \n"
+    + (lib.concatMapStringsSep "\n" (
+      configLine:
+      "grep -q '^${configLine.name}=' theme.conf || echo '${configLine.name}=' >> \"$1\"\n"
+      + "sed -i -e 's/^${configLine.name}=.*$/${configLine.name}=${
+        lib.escape [ "/" "&" "\\" ] (customToString configLine.value)
+      }/' theme.conf"
+    ) configLines);
+in
+stdenv.mkDerivation {
+  pname = "sddm-chili-theme";
+  version = "0.1.5";
+
+  src = fetchFromGitHub {
+    owner = "MarianArlt";
+    repo = "sddm-chili";
+    rev = "6516d50176c3b34df29003726ef9708813d06271";
+    sha256 = "036fxsa7m8ymmp3p40z671z163y6fcsa9a641lrxdrw225ssq5f3";
+  };
+
+  propagatedBuildInputs = [
+    qtgraphicaleffects
+  ];
+
+  dontWrapQtApps = true;
+
+  preInstall = configureTheme;
+
+  postInstall = ''
+    mkdir -p $out/share/sddm/themes/chili
+
+    mv * $out/share/sddm/themes/chili/
+  '';
+
+  postFixup = ''
+    mkdir -p $out/nix-support
+
+    echo ${qtgraphicaleffects} >> $out/nix-support/propagated-user-env-packages
+  '';
+  meta = with lib; {
+    license = licenses.gpl3;
+    maintainers = with lib.maintainers; [ sents ];
+    homepage = "https://github.com/MarianArlt/sddm-chili";
+    description = "Chili login theme for SDDM";
+    longDescription = ''
+      Chili is hot, just like a real chili!
+      Spice up the login experience for your users, your family and yourself.
+      Chili reduces all the clutter and leaves you with a clean, easy to use, login interface with a modern yet classy touch.
+    '';
+  };
+}

pkgs/data/themes/elegant-sddm/default.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  formats,
+  stdenvNoCC,
+  fetchFromGitHub,
+  qtgraphicaleffects,
+  /*
+    An example of how you can override the background with a NixOS wallpaper
+    *
+    *  environment.systemPackages = [
+    *    (pkgs.elegant-sddm.override {
+    *      themeConfig.General = {
+             background = "${pkgs.nixos-artwork.wallpapers.simple-dark-gray-bottom.gnomeFilePath}";
+    *      };
+    *    })
+    *  ];
+  */
+  themeConfig ? null,
+}:
+
+let
+  user-cfg = (formats.ini { }).generate "theme.conf.user" themeConfig;
+in
+
+stdenvNoCC.mkDerivation {
+  pname = "elegant-sddm";
+  version = "unstable-2024-02-08";
+
+  src = fetchFromGitHub {
+    owner = "surajmandalcell";
+    repo = "Elegant-sddm";
+    rev = "3102e880f46a1b72c929d13cd0a3fb64f973952a";
+    hash = "sha256-yn0fTYsdZZSOcaYlPCn8BUIWeFIKcTI1oioTWqjYunQ=";
+  };
+
+  propagatedBuildInputs = [
+    qtgraphicaleffects
+  ];
+
+  dontWrapQtApps = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/share/sddm/themes"
+    cp -r Elegant/ "$out/share/sddm/themes/Elegant"
+  ''
+  + (lib.optionalString (lib.isAttrs themeConfig) ''
+    ln -sf ${user-cfg} $out/share/sddm/themes/Elegant/theme.conf.user
+  '')
+  + ''
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    mkdir -p $out/nix-support
+
+    echo ${qtgraphicaleffects} >> $out/nix-support/propagated-user-env-packages
+  '';
+
+  meta = with lib; {
+    description = "Sleek and stylish SDDM theme crafted in QML";
+    homepage = "https://github.com/surajmandalcell/Elegant-sddm";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ GaetanLepage ];
+  };
+}

pkgs/data/themes/gtk-theme-framework/default.nix

@@ -0,0 +1,41 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  theme,
+  lib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gtk-theme-framework";
+  version = "0.2.3";
+
+  src = fetchFromGitHub {
+    owner = "jaxwilko";
+    repo = "gtk-theme-framework";
+    rev = "v${version}";
+    sha256 = "1z5s5rsgiypanf2z0avaisbflnvwrc8aiy5qskrsvbbaja63jy3s";
+  };
+
+  postPatch = ''
+    substituteInPlace main.sh \
+      --replace "#!/usr/bin/env bash" "#!/bin/sh"
+
+    substituteInPlace scripts/install.sh \
+      --replace "#!/usr/bin/env bash" "#!/bin/sh"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/themes
+    ./main.sh -i -t ${theme} -d $out/share/themes
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/jaxwilko/gtk-theme-framework";
+    license = licenses.gpl3Only;
+    maintainers = [ ];
+  };
+}

pkgs/data/themes/kwin-decorations/kde-rounded-corners/default.nix

@@ -0,0 +1,45 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  extra-cmake-modules,
+  wrapQtAppsHook,
+  qtbase,
+  kwin,
+  kcmutils,
+  libepoxy,
+  libxcb,
+  lib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kde-rounded-corners";
+  version = "0.8.5";
+
+  src = fetchFromGitHub {
+    owner = "matinlotfali";
+    repo = "KDE-Rounded-Corners";
+    rev = "v${version}";
+    hash = "sha256-ef63PVG0JOHY4zyq5M5oAAcxtfhm1XOvpsxgSeXvgDo=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    wrapQtAppsHook
+  ];
+  buildInputs = [
+    kcmutils
+    kwin
+    libepoxy
+    libxcb
+    qtbase
+  ];
+
+  meta = with lib; {
+    description = "Rounds the corners of your windows";
+    homepage = "https://github.com/matinlotfali/KDE-Rounded-Corners";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ devusb ];
+  };
+}

pkgs/data/themes/kwin-decorations/sierra-breeze-enhanced/default.nix

@@ -0,0 +1,41 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  extra-cmake-modules,
+  wrapQtAppsHook,
+  kwin,
+  lib,
+}:
+stdenv.mkDerivation rec {
+  pname = "sierra-breeze-enhanced";
+  version = "2.1.1";
+
+  src = fetchFromGitHub {
+    owner = "kupiqu";
+    repo = "SierraBreezeEnhanced";
+    rev = if version == "2.1.1" then "V.2.1.1" else "V${version}";
+    hash = "sha256-7mQnJCQr/zm9zEdg2JPr7jQn8uajyCXvyYRQZWxG+Q8=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    wrapQtAppsHook
+  ];
+  buildInputs = [ kwin ];
+
+  cmakeFlags = [
+    "-DCMAKE_INSTALL_PREFIX=$out"
+    "-DBUILD_TESTING=OFF"
+    "-DKDE_INSTALL_USE_QT_SYS_PATHS=ON"
+  ];
+
+  meta = with lib; {
+    description = "OSX-like window decoration for KDE Plasma written in C++";
+    homepage = "https://github.com/kupiqu/SierraBreezeEnhanced";
+    changelog = "https://github.com/kupiqu/SierraBreezeEnhanced/releases/tag/V${version}";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ A1ca7raz ];
+  };
+}

pkgs/data/themes/plata/default.nix

@@ -0,0 +1,109 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  autoreconfHook,
+  pkg-config,
+  parallel,
+  sassc,
+  inkscape,
+  libxml2,
+  glib,
+  gtk_engines,
+  gtk-engine-murrine,
+  cinnamonSupport ? true,
+  gnomeFlashbackSupport ? true,
+  gnomeShellSupport ? true,
+  openboxSupport ? true,
+  xfceSupport ? true,
+  mateSupport ? true,
+  gtk3,
+  marco,
+  gtkNextSupport ? false,
+  plankSupport ? false,
+  steamSupport ? false,
+  telegramSupport ? false,
+  zip,
+  tweetdeckSupport ? false,
+  selectionColor ? null, # Primary color for 'selected-items' (Default: #3F51B5 = Indigo500)
+  accentColor ? null, # Secondary color for notifications and OSDs (Default: #7986CB = Indigo300)
+  suggestionColor ? null, # Secondary color for 'suggested' buttons (Default: #673AB7 = DPurple500)
+  destructionColor ? null, # Tertiary color for 'destructive' buttons (Default: #F44336 = Red500)
+}:
+
+stdenv.mkDerivation rec {
+  pname = "plata-theme";
+  version = "0.9.9";
+
+  src = fetchFromGitLab {
+    owner = "tista500";
+    repo = "plata-theme";
+    rev = version;
+    sha256 = "1iwvlv9qcrjyfbzab00vjqafmp3vdybz1hi02r6lwbgvwyfyrifk";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    parallel
+    sassc
+    inkscape
+    libxml2
+    glib
+  ]
+  ++ lib.optionals mateSupport [
+    gtk3
+    marco
+  ]
+  ++ lib.optional telegramSupport zip;
+
+  buildInputs = [ gtk_engines ];
+
+  propagatedUserEnvPkgs = [
+    gtk-engine-murrine
+  ];
+
+  postPatch = "patchShebangs .";
+
+  configureFlags =
+    let
+      inherit (lib) enableFeature optional;
+      withOptional = value: feat: optional (value != null) "--with-${feat}=${value}";
+    in
+    [
+      "--enable-parallel"
+      (enableFeature cinnamonSupport "cinnamon")
+      (enableFeature gnomeFlashbackSupport "flashback")
+      (enableFeature gnomeShellSupport "gnome")
+      (enableFeature openboxSupport "openbox")
+      (enableFeature xfceSupport "xfce")
+      (enableFeature mateSupport "mate")
+      (enableFeature gtkNextSupport "gtk_next")
+      (enableFeature plankSupport "plank")
+      (enableFeature steamSupport "airforsteam")
+      (enableFeature telegramSupport "telegram")
+      (enableFeature tweetdeckSupport "tweetdeck")
+    ]
+    ++ (withOptional selectionColor "selection_color")
+    ++ (withOptional accentColor "accent_color")
+    ++ (withOptional suggestionColor "suggestion_color")
+    ++ (withOptional destructionColor "destruction_color");
+
+  postInstall = ''
+    for dest in $out/share/gtksourceview-{3.0,4}/styles; do
+      mkdir -p $dest
+      cp $out/share/themes/Plata-{Noir,Lumine}/gtksourceview/*.xml $dest
+    done
+  '';
+
+  meta = with lib; {
+    description = "GTK theme based on Material Design Refresh";
+    homepage = "https://gitlab.com/tista500/plata-theme";
+    license = with licenses; [
+      gpl2
+      cc-by-sa-40
+    ];
+    platforms = platforms.linux;
+    maintainers = [ maintainers.tadfisher ];
+  };
+}

pkgs/data/themes/qogir-kde/default.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  unstableGitUpdater,
+}:
+
+# NOTE:
+#
+# In order to use the qogir sddm theme, the packages
+# kdePackages.plasma-desktop and kdePackages.qtsvg should be added to
+# the option services.displayManager.sddm.extraPackages of the sddm
+# module:
+#
+# environment.systemPackages = with pkgs; [
+#   qogir-kde
+# ];
+#
+# services.displayManager.sddm = {
+#     enable = true;
+#     package = pkgs.kdePackages.sddm;
+#     theme = "Qogir";
+#     extraPackages = with pkgs; [
+#       kdePackages.plasma-desktop
+#       kdePackages.qtsvg
+#     ];
+# };
+
+stdenvNoCC.mkDerivation {
+  pname = "qogir-kde";
+  version = "0-unstable-2024-12-21";
+
+  src = fetchFromGitHub {
+    owner = "vinceliuice";
+    repo = "qogir-kde";
+    rev = "31e7bbf94e905ef40d262d2bc6063156df252470";
+    hash = "sha256-zgXwYmpD31vs2Gyg21m0MdOkwqzSn6V21Kva+nvNeVI=";
+  };
+
+  postPatch = ''
+    patchShebangs install.sh
+
+    substituteInPlace install.sh \
+      --replace '$HOME/.local' $out \
+      --replace '$HOME/.config' $out/share
+
+    substituteInPlace sddm/*/Main.qml \
+      --replace /usr $out
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/plasma/plasmoids
+
+    name= HOME="$TMPDIR" ./install.sh --dest $out/share/themes
+
+    mkdir -p $out/share/sddm/themes
+    cp -a sddm/Qogir $out/share/sddm/themes/
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    description = "Flat Design theme for KDE Plasma desktop";
+    homepage = "https://github.com/vinceliuice/Qogir-kde";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.all;
+    maintainers = [ lib.maintainers.romildo ];
+  };
+}

pkgs/data/themes/qtcurve/default.nix

@@ -0,0 +1,107 @@
+{
+  lib,
+  fetchFromGitHub,
+  cmake,
+  extra-cmake-modules,
+  pkg-config,
+  mkDerivation,
+  gtk2Support ? true,
+  gtk2,
+  qtbase,
+  qtsvg,
+  qtx11extras, # Toolkit dependencies
+  karchive,
+  kconfig,
+  kconfigwidgets,
+  kio,
+  frameworkintegration,
+  kguiaddons,
+  ki18n,
+  kwindowsystem,
+  kdelibs4support,
+  kiconthemes,
+  libpthreadstubs,
+  pcre,
+  libXdmcp,
+  libX11,
+  libXau, # X11 dependencies
+  fetchpatch,
+}:
+
+mkDerivation rec {
+  pname = "qtcurve";
+  version = "1.9.1";
+  src = fetchFromGitHub {
+    owner = "KDE";
+    repo = "qtcurve";
+    rev = version;
+    sha256 = "XP9VTeiVIiMm5mkXapCKWxfcvaYCkhY3S5RXZNR3oWo=";
+  };
+
+  patches = [
+    # Remove unnecessary constexpr, this is not allowed in C++14
+    (fetchpatch {
+      url = "https://github.com/KDE/qtcurve/commit/ee2228ea2f18ac5da9b434ee6089381df815aa94.patch";
+      sha256 = "1vz5frsrsps93awn84gk8d7injrqfcyhc1rji6s0gsgsp5z9sl34";
+    })
+    # Fix build with Qt5.15
+    (fetchpatch {
+      url = "https://github.com/KDE/qtcurve/commit/44e2a35ebb164dcab0bad1a9158b1219a3ff6504.patch";
+      sha256 = "5I2fTxKRJX0cJcyUvYHWZx369FKk6ti9Se7AfYmB9ek=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    pkg-config
+  ];
+
+  buildInputs = [
+    qtbase
+    qtsvg
+    qtx11extras
+    karchive
+    kconfig
+    kconfigwidgets
+    kio
+    kiconthemes
+    kguiaddons
+    ki18n
+    kwindowsystem
+    kdelibs4support
+    frameworkintegration
+    libpthreadstubs
+    pcre
+    libXdmcp
+    libX11
+    libXau
+  ]
+  ++ lib.optional gtk2Support gtk2;
+
+  preConfigure = ''
+    for i in qt5/CMakeLists.txt qt5/config/CMakeLists.txt
+    do
+      substituteInPlace $i \
+        --replace "{_Qt5_PLUGIN_INSTALL_DIR}" "{KDE_INSTALL_QTPLUGINDIR}"
+    done
+    substituteInPlace CMakeLists.txt \
+      --replace \$\{GTK2_PREFIX\} $out
+    substituteInPlace gtk2/style/CMakeLists.txt \
+      --replace \$\{GTK2_LIBDIR\} $out/lib
+    patchShebangs tools/gen-version.sh
+  '';
+
+  configureFlags = [
+    "-DENABLE_GTK2=${if gtk2Support then "ON" else "OFF"}"
+    "-DENABLE_QT4=OFF"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/QtCurve/qtcurve";
+    description = "Widget styles for Qt5/Plasma 5 and gtk2";
+    platforms = platforms.linux;
+    license = licenses.lgpl21Plus;
+    maintainers = [ ];
+  };
+}

pkgs/data/themes/sddm-astronaut/default.nix

@@ -0,0 +1,61 @@
+{
+  pkgs,
+  lib,
+  stdenvNoCC,
+  themeConfig ? null,
+  embeddedTheme ? "astronaut",
+}:
+stdenvNoCC.mkDerivation rec {
+  pname = "sddm-astronaut";
+  version = "1.0-unstable-2025-01-05";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "Keyitdev";
+    repo = "sddm-astronaut-theme";
+    rev = "11c0bf6147bbea466ce2e2b0559e9a9abdbcc7c3";
+    hash = "sha256-gBSz+k/qgEaIWh1Txdgwlou/Lfrfv3ABzyxYwlrLjDk=";
+  };
+
+  dontWrapQtApps = true;
+
+  propagatedBuildInputs = with pkgs.kdePackages; [
+    qtsvg
+    qtmultimedia
+    qtvirtualkeyboard
+  ];
+
+  installPhase =
+    let
+      iniFormat = pkgs.formats.ini { };
+      configFile = iniFormat.generate "" { General = themeConfig; };
+
+      basePath = "$out/share/sddm/themes/sddm-astronaut-theme";
+      sedString = "ConfigFile=Themes/";
+    in
+    ''
+      mkdir -p ${basePath}
+      cp -r $src/* ${basePath}
+    ''
+    + lib.optionalString (embeddedTheme != "astronaut") ''
+
+      # Replaces astronaut.conf with embedded theme in metadata.desktop on line 9.
+      # ConfigFile=Themes/astronaut.conf.
+      sed -i "s|^${sedString}.*\\.conf$|${sedString}${embeddedTheme}.conf|" ${basePath}/metadata.desktop
+    ''
+    + lib.optionalString (themeConfig != null) ''
+      chmod u+w ${basePath}/Themes/
+      ln -sf ${configFile} ${basePath}/Themes/${embeddedTheme}.conf.user
+    '';
+
+  meta = {
+    description = "Modern looking qt6 sddm theme";
+    homepage = "https://github.com/${src.owner}/${src.repo}";
+    license = lib.licenses.gpl3;
+
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      danid3v
+      uxodb
+    ];
+  };
+}

pkgs/data/themes/sddm-sugar-dark/default.nix

@@ -0,0 +1,46 @@
+{
+  pkgs,
+  lib,
+  stdenvNoCC,
+  themeConfig ? null,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "sddm-sugar-dark";
+  version = "1.2";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "MarianArlt";
+    repo = "sddm-sugar-dark";
+    rev = "v${version}";
+    hash = "sha256-C3qB9hFUeuT5+Dos2zFj5SyQegnghpoFV9wHvE9VoD8=";
+  };
+
+  dontWrapQtApps = true;
+
+  buildInputs = with pkgs.libsForQt5.qt5; [ qtgraphicaleffects ];
+
+  installPhase =
+    let
+      iniFormat = pkgs.formats.ini { };
+      configFile = iniFormat.generate "" { General = themeConfig; };
+
+      basePath = "$out/share/sddm/themes/sugar-dark";
+    in
+    ''
+      mkdir -p ${basePath}
+      cp -r $src/* ${basePath}
+    ''
+    + lib.optionalString (themeConfig != null) ''
+      ln -sf ${configFile} ${basePath}/theme.conf.user
+    '';
+
+  meta = {
+    description = "Dark SDDM theme from the sugar family";
+    homepage = "https://github.com/${src.owner}/${pname}";
+    license = lib.licenses.gpl3;
+
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ danid3v ];
+  };
+}