push sheeet

pkgs/desktops/gnome-2/default.nix

@@ -0,0 +1,83 @@
+{
+  config,
+  stdenv,
+  pkgs,
+  lib,
+}:
+
+lib.makeScope pkgs.newScope (
+  self: with self; {
+
+    #### PLATFORM
+
+    libIDL = callPackage ./platform/libIDL {
+      gettext = if stdenv.hostPlatform.isDarwin then pkgs.gettext else null;
+    };
+
+    ORBit2 = callPackage ./platform/ORBit2 { };
+
+    libart_lgpl = callPackage ./platform/libart_lgpl { };
+
+    libglade = callPackage ./platform/libglade { };
+
+    GConf = callPackage ./platform/GConf { };
+
+    libgnomecanvas = callPackage ./platform/libgnomecanvas { };
+
+    # for git-head builds
+    gnome-common = callPackage platform/gnome-common { };
+
+    gnome_mime_data = callPackage ./platform/gnome-mime-data { };
+
+    gtkglext = callPackage ./platform/gtkglext { };
+
+    #### DESKTOP
+
+    gtksourceview = callPackage ./desktop/gtksourceview { };
+
+  }
+)
+// lib.optionalAttrs config.allowAliases {
+  # added 2024-12-02
+  glib = throw "gnome2.glib has been removed, please use top-level glib";
+  glibmm = throw "gnome2.glibmm has been removed, please use top-level glibmm";
+  atk = throw "gnome2.atk has been removed, please use top-level atk";
+  atkmm = throw "gnome2.atkmm has been removed, please use top-level atkmm";
+  cairo = throw "gnome2.cairo has been removed, please use top-level cairo";
+  pango = throw "gnome2.pango has been removed, please use top-level pango";
+  pangomm = throw "gnome2.pangomm has been removed, please use top-level pangomm";
+  gtkmm2 = throw "gnome2.gtkmm2 has been removed, please use top-level gtkmm2";
+  libcanberra-gtk2 = throw "gnome2.libcanberra-gtk2 has been removed, please use top-level libcanberra-gtk2";
+  libsoup = throw "gnome2.libsoup has been removed, please use top-level libsoup_2_4";
+  libwnck2 = throw "gnome2.libwnck2 has been removed, please use top-level libwnck2";
+  gtk-doc = throw "gnome2.gtk-doc has been removed, please use top-level gtk-doc";
+  gnome-doc-utils = throw "gnome2.gnome-doc-utils has been removed, please use top-level gnome-doc-utils";
+  gvfs = throw "gnome2.gvfs has been removed, please use top-level gvfs";
+  gtk = throw "gnome2.gtk has been removed, please use top-level gtk2";
+  gtkmm = throw "gnome2.gtkmm has been removed, please use top-level gtkmm2";
+  gtkdoc = throw "gnome2.gtkdoc has been removed, please use top-level gtk-doc";
+  startup_notification = throw "gnome2.startup_notification has been removed, please use top-level libstartup_notification";
+  startupnotification = throw "gnome2.startupnotification has been removed, please use top-level libstartup_notification";
+  gnomedocutils = throw "gnome2.gnomedocutils has been removed, please use top-level gnome-doc-utils";
+  gnome-icon-theme = throw "gnome2.gnome-icon-theme has been removed, please use top-level gnome-icon-theme";
+  gnome_icon_theme = throw "gnome2.gnome_icon_theme has been removed, please use top-level gnome-icon-theme";
+  gnomeicontheme = throw "gnome2.gnomeicontheme has been removed, please use top-level gnome-icon-theme";
+  gnome_common = throw "gnome2.gnome_common has been removed, please use top-level gnome-common";
+
+  gnome_python = throw "gnome2.gnome_python has been removed"; # 2023-01-14
+  gnome_python_desktop = throw "gnome2.gnome_python_desktop has been removed"; # 2023-01-14
+  gnome_vfs = throw "gnome2.gnome_vfs has been removed"; # 2024-06-27
+  gtkhtml = throw "gnome2.gtkhtml has been removed"; # 2023-01-15
+  gtkhtml4 = throw "gnome2.gtkhtml4 has been removed"; # 2023-01-15
+  libbonobo = throw "gnome2.libbonobo has been removed"; # 2024-06-27
+  libbonoboui = throw "gnome2.libbonoboui has been removed"; # 2024-06-27
+  libglademm = throw "gnome2.libglademm has been removed"; # 2022-01-15
+  libgnomecanvasmm = "gnome2.libgnomecanvasmm has been removed"; # 2022-01-15
+  libgnomecups = throw "gnome2.libgnomecups has been removed"; # 2023-01-15
+  libgnomeprint = throw "gnome2.libgnomeprint has been removed"; # 2023-01-15
+  libgnomeprintui = throw "gnome2.libgnomeprintui has been removed"; # 2023-01-15
+  libgnome = throw "gnome2.libgnome has been removed"; # 2024-06-27
+  libgnomeui = throw "gnome2.libgnomeui has been removed"; # 2024-06-27
+  libgtkhtml = throw "gnome2.libgtkhtml has been removed"; # 2023-01-15
+  python_rsvg = throw "gnome2.python_rsvg has been removed"; # 2023-01-14
+}

pkgs/desktops/gnome-2/desktop/gtksourceview/default.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  stdenv,
+  fetchpatch,
+  fetchurl,
+  autoreconfHook,
+  gtk-doc,
+  pkg-config,
+  atk,
+  cairo,
+  glib,
+  gnome-common,
+  gtk2,
+  pango,
+  libxml2Python,
+  perl,
+  intltool,
+  gettext,
+  gtk-mac-integration-gtk2,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gtksourceview";
+  version = "2.10.5";
+
+  src =
+    let
+      inherit (finalAttrs) pname version;
+    in
+    fetchurl {
+      url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.bz2";
+      sha256 = "c585773743b1df8a04b1be7f7d90eecdf22681490d6810be54c81a7ae152191e";
+    };
+
+  patches = lib.optionals stdenv.hostPlatform.isDarwin [
+    (fetchpatch {
+      name = "change-igemacintegration-to-gtkosxapplication.patch";
+      url = "https://gitlab.gnome.org/GNOME/gtksourceview/commit/e88357c5f210a8796104505c090fb6a04c213902.patch";
+      sha256 = "0h5q79q9dqbg46zcyay71xn1pm4aji925gjd5j93v4wqn41wj5m7";
+    })
+    (fetchpatch {
+      name = "update-to-gtk-mac-integration-2.0-api.patch";
+      url = "https://gitlab.gnome.org/GNOME/gtksourceview/commit/ab46e552e1d0dae73f72adac8d578e40bdadaf95.patch";
+      sha256 = "0qzrbv4hpa0v8qbmpi2vp575n13lkrvp3cgllwrd2pslw1v9q3aj";
+    })
+  ];
+
+  # Fix build with gcc 14
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-pointer-types";
+
+  nativeBuildInputs = [
+    pkg-config
+    intltool
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    autoreconfHook
+    gtk-doc
+  ];
+
+  buildInputs = [
+    atk
+    cairo
+    glib
+    gtk2
+    pango
+    libxml2Python
+    perl
+    gettext
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    gnome-common
+    gtk-mac-integration-gtk2
+  ];
+
+  doCheck = false; # requires X11 daemon
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = {
+    pkgConfigModules = [ "gtksourceview-2.0" ];
+  };
+})

pkgs/desktops/gnome-2/platform/GConf/default.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  dbus-glib,
+  glib,
+  ORBit2,
+  libxml2,
+  polkit,
+  python312,
+  intltool,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gconf";
+  version = "3.2.6";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/GConf/${lib.versions.majorMinor version}/GConf-${version}.tar.xz";
+    sha256 = "0k3q9nh53yhc9qxf1zaicz4sk8p3kzq4ndjdsgpaa2db0ccbj4hr";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+  ];
+
+  strictDeps = true;
+
+  buildInputs = [
+    ORBit2
+    libxml2
+  ]
+  # polkit requires pam, which requires shadow.h, which is not available on
+  # darwin
+  ++ lib.optional (!stdenv.hostPlatform.isDarwin) polkit;
+
+  propagatedBuildInputs = [
+    glib
+    dbus-glib
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    intltool
+    python312
+    glib
+  ];
+
+  configureFlags =
+    # fixes the "libgconfbackend-oldxml.so is not portable" error on darwin
+    lib.optionals stdenv.hostPlatform.isDarwin [ "--enable-static" ];
+
+  postPatch = ''
+    2to3 --write --nobackup gsettings/gsettings-schema-convert
+  '';
+
+  meta = with lib; {
+    homepage = "https://projects.gnome.org/gconf/";
+    description = "Deprecated system for storing application preferences";
+    platforms = platforms.unix;
+  };
+}

pkgs/desktops/gnome-2/platform/ORBit2/default.nix

@@ -0,0 +1,101 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  glib,
+  libIDL,
+  libintl,
+  buildPackages,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ORBit2";
+  version = "2.14.19";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/ORBit2/${lib.versions.majorMinor version}/ORBit2-${version}.tar.bz2";
+    sha256 = "0l3mhpyym9m5iz09fz0rgiqxl2ym6kpkwpsp1xrr4aa80nlh1jam";
+  };
+
+  strictDeps = true;
+
+  # Processing file orbit-interface.idl
+  # sh: gcc: not found
+  # output does not contain binaries for build
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+  nativeBuildInputs = [
+    pkg-config
+    libintl
+  ];
+  propagatedBuildInputs = [
+    glib
+    libIDL
+  ];
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals (stdenv.cc.isGNU && (lib.versionAtLeast (lib.getVersion stdenv.cc.cc) "14")) [
+      # the ./configure script is not compatible with gcc-14, not easy to
+      # regenerate without porting: https://github.com/NixOS/nixpkgs/issues/367694
+      "-Wno-error=implicit-int"
+      "-Wno-error=incompatible-pointer-types"
+    ]
+  );
+
+  configureFlags = lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
+    "--with-idl-compiler=${lib.getExe' buildPackages.gnome2.ORBit2 "orbit-idl-2"}"
+    # https://github.com/void-linux/void-packages/blob/e5856e02aa6ef7e4f2725afbff2915f89d39024b/srcpkgs/ORBit2/template#L17-L35
+    "ac_cv_alignof_CORBA_boolean=1"
+    "ac_cv_alignof_CORBA_char=1"
+    "ac_cv_alignof_CORBA_double=8"
+    "ac_cv_alignof_CORBA_float=4"
+    "ac_cv_alignof_CORBA_long=4"
+    "ac_cv_alignof_CORBA_long_double=8"
+    "ac_cv_alignof_CORBA_long_long=8"
+    "ac_cv_alignof_CORBA_octet=1"
+    "ac_cv_alignof_CORBA_short=2"
+    "ac_cv_alignof_CORBA_struct=1"
+    "ac_cv_alignof_CORBA_wchar=2"
+    "ac_cv_alignof_CORBA_pointer=${if stdenv.hostPlatform.is64bit then "8" else "4"}"
+  ];
+
+  preBuild = ''
+    sed 's/-DG_DISABLE_DEPRECATED//' -i linc2/src/Makefile
+  '';
+
+  preFixup = ''
+    moveToOutput "bin/orbit2-config" "$dev"
+  '';
+
+  # Parallel build fails due to missing internal library dependency:
+  #    libtool --tag=CC   --mode=link gcc ... -o orbit-name-server-2 ...
+  #    ld: cannot find libname-server-2.a: No such file or directory
+  # It happens because orbit-name-server-2 should have libname-server-2.a
+  # in _DEPENDENCIES but does not. Instead of fixing it and regenerating
+  # Makefile.in let's just disable parallel build.
+  enableParallelBuilding = false;
+
+  meta = with lib; {
+    homepage = "https://developer-old.gnome.org/ORBit2/";
+    description = "CORBA 2.4-compliant Object Request Broker";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ lovek323 ];
+
+    longDescription = ''
+      ORBit2 is a CORBA 2.4-compliant Object Request Broker (ORB) featuring
+      mature C, C++ and Python bindings. Bindings (in various degrees of
+      completeness) are also available for Perl, Lisp, Pascal, Ruby, and TCL;
+      others are in-progress. It supports POA, DII, DSI, TypeCode, Any, IR and
+      IIOP. Optional features including INS and threading are available. ORBit2
+      is engineered for the desktop workstation environment, with a focus on
+      performance, low resource usage, and security. The core ORB is written in
+      C, and runs under Linux, UNIX (BSD, Solaris, HP-UX, ...), and Windows.
+      ORBit2 is developed and released as open source software under GPL/LGPL.
+    '';
+  };
+}

pkgs/desktops/gnome-2/platform/gnome-common/default.nix

@@ -0,0 +1,26 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  which,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gnome-common";
+  version = "2.34.0";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/gnome-common/${lib.versions.majorMinor version}/gnome-common-${version}.tar.bz2";
+    sha256 = "1pz13mpp09q5s3bikm8ml92s1g0scihsm4iipqv1ql3mp6d4z73s";
+  };
+
+  propagatedBuildInputs = [ which ]; # autogen.sh which is using gnome-common tends to require which
+
+  patches = [
+    (fetchurl {
+      name = "gnome-common-patch";
+      url = "https://bug697543.bugzilla-attachments.gnome.org/attachment.cgi?id=240935";
+      sha256 = "17abp7czfzirjm7qsn2czd03hdv9kbyhk3lkjxg2xsf5fky7z7jl";
+    })
+  ];
+}

pkgs/desktops/gnome-2/platform/gnome-mime-data/default.nix

@@ -0,0 +1,16 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  intltool,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gnome-mime-data";
+  version = "2.18.0";
+  src = fetchurl {
+    url = "mirror://gnome/sources/gnome-mime-data/${lib.versions.majorMinor version}/gnome-mime-data-${version}.tar.bz2";
+    sha256 = "1mvg8glb2a40yilmyabmb7fkbzlqd3i3d31kbkabqnq86xdnn69p";
+  };
+  nativeBuildInputs = [ intltool ];
+}

pkgs/desktops/gnome-2/platform/gtkglext/default.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  pkg-config,
+  gtk-doc,
+  autoconf,
+  automake,
+  which,
+  libtool,
+  gobject-introspection,
+  glib,
+  gtk2,
+  libGLU,
+  libGL,
+  pango,
+  xorg,
+}:
+
+stdenv.mkDerivation {
+  pname = "gtkglext";
+  version = "unstable-2019-12-19";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.gnome.org";
+    owner = "Archive";
+    repo = "gtkglext";
+    # build fixes
+    # https://gitlab.gnome.org/Archive/gtkglext/merge_requests/1
+    rev = "ad95fbab68398f81d7a5c895276903b0695887e2";
+    sha256 = "1d1bp4635nla7d07ci40c7w4drkagdqk8wg93hywvdipmjfb4yqb";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    gtk-doc
+    autoconf
+    automake
+    which
+    libtool
+    gobject-introspection
+  ];
+
+  buildInputs = [
+    glib
+    gtk2
+    libGLU
+    libGL
+    pango
+    xorg.libX11
+    xorg.libXmu
+  ];
+
+  preConfigure = ''
+    NOCONFIGURE=1 ./autogen.sh
+  '';
+
+  meta = with lib; {
+    homepage = "https://projects.gnome.org/gtkglext/";
+    description = "GtkGLExt, an OpenGL extension to GTK";
+    longDescription = ''
+      GtkGLExt is an OpenGL extension to GTK. It provides additional GDK
+      objects which support OpenGL rendering in GTK and GtkWidget API
+      add-ons to make GTK widgets OpenGL-capable.  In contrast to Janne
+      Löf's GtkGLArea, GtkGLExt provides a GtkWidget API that enables
+      OpenGL drawing for standard and custom GTK widgets.
+    '';
+    license = licenses.lgpl2Plus;
+    platforms = platforms.linux;
+  };
+}

pkgs/desktops/gnome-2/platform/libIDL/default.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  flex,
+  bison,
+  pkg-config,
+  glib,
+  gettext,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libIDL";
+  version = "0.8.14";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/libIDL/${lib.versions.majorMinor version}/libIDL-${version}.tar.bz2";
+    sha256 = "08129my8s9fbrk0vqvnmx6ph4nid744g5vbwphzkaik51664vln5";
+  };
+
+  strictDeps = true;
+
+  buildInputs = [
+    glib
+    gettext
+  ];
+
+  nativeBuildInputs = [
+    flex
+    bison
+    pkg-config
+  ];
+
+  configureFlags = lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
+    # before openembedded removed libIDL
+    # the result was always ll https://lists.openembedded.org/g/openembedded-core/topic/85775262?p=%2C%2C%2C20%2C0%2C0%2C0%3A%3A%2C%2C%2C0%2C0%2C0%2C85775262
+    "libIDL_cv_long_long_format=ll"
+  ];
+  meta.mainProgram = "libIDL-config-2";
+}

pkgs/desktops/gnome-2/platform/libart_lgpl/default.nix

@@ -0,0 +1,15 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libart_lgpl";
+  version = "2.3.21";
+  src = fetchurl {
+    url = "mirror://gnome/sources/libart_lgpl/${lib.versions.majorMinor version}/libart_lgpl-${version}.tar.bz2";
+    sha256 = "1yknfkyzgz9s616is0l9gp5aray0f2ry4dw533jgzj8gq5s1xhgx";
+  };
+  meta.mainProgram = "libart2-config";
+}

pkgs/desktops/gnome-2/platform/libglade/default.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  gtk2,
+  libxml2,
+  gettext,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libglade";
+  version = "2.6.4";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/libglade/${lib.versions.majorMinor version}/libglade-${version}.tar.bz2";
+    sha256 = "1v2x2s04jry4gpabws92i0wq2ghd47yr5n9nhgnkd7c38xv1wdk4";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+    gettext
+  ];
+  buildInputs = [ gtk2 ];
+  propagatedBuildInputs = [ libxml2 ];
+
+  postPatch = ''
+    # uses pkg-config in some places and uses the correct $PKG_CONFIG in some
+    # it's an ancient library so it has very old configure scripts and m4
+    substituteInPlace ./configure \
+      --replace "pkg-config" "$PKG_CONFIG"
+  '';
+
+  NIX_LDFLAGS = "-lgmodule-2.0";
+}

pkgs/desktops/gnome-2/platform/libgnomecanvas/default.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  gtk2,
+  intltool,
+  libart_lgpl,
+  libglade,
+  glib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libgnomecanvas";
+  version = "2.30.3";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/libgnomecanvas/${lib.versions.majorMinor version}/libgnomecanvas-${version}.tar.bz2";
+    sha256 = "0h6xvswbqspdifnyh5pm2pqq55yp3kn6yrswq7ay9z49hkh7i6w5";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  strictDeps = true;
+
+  buildInputs = [ libglade ];
+  nativeBuildInputs = [
+    pkg-config
+    intltool
+    glib
+  ];
+  propagatedBuildInputs = [
+    libart_lgpl
+    gtk2
+  ];
+}