push sheeet

pkgs/desktops/mate/caja/default.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  pkg-config,
+  gettext,
+  gtk-layer-shell,
+  gtk3,
+  libnotify,
+  libxml2,
+  libexif,
+  exempi,
+  mate-desktop,
+  hicolor-icon-theme,
+  wayland,
+  wrapGAppsHook3,
+  mateUpdateScript,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "caja";
+  version = "1.28.0";
+
+  src = fetchurl {
+    url = "https://pub.mate-desktop.org/releases/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
+    sha256 = "HjAUzhRVgX7C73TQnv37aDXYo3LtmhbvtZGe97ghlXo=";
+  };
+
+  patches = [
+    # wayland: ensure windows can be moved if compositor is using CSD
+    # https://github.com/mate-desktop/caja/pull/1787
+    (fetchpatch {
+      url = "https://github.com/mate-desktop/caja/commit/b0fb727c62ef9f45865d5d7974df7b79bcf0d133.patch";
+      hash = "sha256-2QAXveJnrPPyFSBST6wQcXz9PRsJVdt4iSYy0gubDAs=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    gettext
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    gtk-layer-shell
+    gtk3
+    libnotify
+    libxml2
+    libexif
+    exempi
+    mate-desktop
+    hicolor-icon-theme
+    wayland
+  ];
+
+  configureFlags = [ "--disable-update-mimedb" ];
+
+  enableParallelBuilding = true;
+
+  passthru.updateScript = mateUpdateScript { inherit pname; };
+
+  meta = with lib; {
+    description = "File manager for the MATE desktop";
+    homepage = "https://mate-desktop.org";
+    license = with licenses; [
+      gpl2Plus
+      lgpl2Plus
+    ];
+    platforms = platforms.unix;
+    teams = [ teams.mate ];
+  };
+}

pkgs/desktops/mate/caja/with-extensions.nix

@@ -0,0 +1,67 @@
+{
+  stdenv,
+  lib,
+  glib,
+  wrapGAppsHook3,
+  xorg,
+  caja,
+  cajaExtensions,
+  extensions ? [ ],
+  useDefaultExtensions ? true,
+}:
+
+let
+  selectedExtensions = extensions ++ (lib.optionals useDefaultExtensions cajaExtensions);
+in
+stdenv.mkDerivation {
+  pname = "${caja.pname}-with-extensions";
+  version = caja.version;
+
+  src = null;
+
+  nativeBuildInputs = [
+    glib
+    wrapGAppsHook3
+  ];
+
+  buildInputs =
+    lib.forEach selectedExtensions (x: x.buildInputs)
+    ++ selectedExtensions
+    ++ [ caja ]
+    ++ caja.buildInputs;
+
+  dontUnpack = true;
+  dontConfigure = true;
+  dontBuild = true;
+
+  preferLocalBuild = true;
+  allowSubstitutes = false;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    ${xorg.lndir}/bin/lndir -silent ${caja} $out
+
+    dbus_service_path="share/dbus-1/services/org.mate.freedesktop.FileManager1.service"
+    rm -f $out/share/applications/* "$out/$dbus_service_path"
+    for file in ${caja}/share/applications/*; do
+      substitute "$file" "$out/share/applications/$(basename $file)" \
+        --replace-fail "${caja}" "$out"
+    done
+    substitute "${caja}/$dbus_service_path" "$out/$dbus_service_path" \
+      --replace-fail "${caja}" "$out"
+
+    runHook postInstall
+  '';
+
+  preFixup = lib.optionalString (selectedExtensions != [ ]) ''
+    gappsWrapperArgs+=(
+      --set CAJA_EXTENSION_DIRS ${
+        lib.concatMapStringsSep ":" (x: "${x.outPath}/lib/caja/extensions-2.0") selectedExtensions
+      }
+    )
+  '';
+
+  inherit (caja) meta;
+}