push sheeet

pkgs/development/compilers/kotlin/default.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  jre,
+  unzip,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kotlin";
+  version = "2.2.20";
+
+  src = fetchurl {
+    url = "https://github.com/JetBrains/kotlin/releases/download/v${finalAttrs.version}/kotlin-compiler-${finalAttrs.version}.zip";
+    sha256 = "sha256-gfAmTJBztcu9s/+EGM8sXawHaHn8FW+hpkYvWlrMRCA=";
+  };
+
+  propagatedBuildInputs = [ jre ];
+  nativeBuildInputs = [
+    makeWrapper
+    unzip
+  ];
+
+  installPhase = ''
+    mkdir -p $out
+    rm "bin/"*.bat
+    mv * $out
+
+    for p in $(ls $out/bin/) ; do
+      wrapProgram $out/bin/$p --prefix PATH ":" ${jre}/bin ;
+    done
+
+    if [ -f $out/LICENSE ]; then
+      install -D $out/LICENSE $out/share/kotlin/LICENSE
+      rm $out/LICENSE
+    fi
+  '';
+
+  meta = {
+    description = "General purpose programming language";
+    longDescription = ''
+      Kotlin is a statically typed language that targets the JVM and JavaScript.
+      It is a general-purpose language intended for industry use.
+      It is developed by a team at JetBrains although it is an OSS language
+      and has external contributors.
+    '';
+    homepage = "https://kotlinlang.org/";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ SubhrajyotiSen ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/development/compilers/kotlin/native.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  jre,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kotlin-native";
+  version = "2.2.20";
+
+  src =
+    let
+      getArch =
+        {
+          "aarch64-darwin" = "macos-aarch64";
+          "x86_64-darwin" = "macos-x86_64";
+          "x86_64-linux" = "linux-x86_64";
+        }
+        .${stdenv.system} or (throw "${pname}-${version}: ${stdenv.system} is unsupported.");
+
+      getUrl =
+        version: arch:
+        "https://github.com/JetBrains/kotlin/releases/download/v${version}/kotlin-native-prebuilt-${arch}-${version}.tar.gz";
+
+      getHash =
+        arch:
+        {
+          "macos-aarch64" = "sha256-UnDl9wj/7RXrEaApuAaLczIfz0lscQPf+pCeSdJxJeY=";
+          "macos-x86_64" = "sha256-mmsBQrx0yKqvvhnD8CU+oxqhWsOT1RzvzSniN3CeG7g=";
+          "linux-x86_64" = "sha256-2Ff+4rTj/W0tQBo6lADcQMIN4dAj32UnIXF9PRme0Nw=";
+        }
+        .${arch};
+    in
+    fetchurl {
+      url = getUrl version getArch;
+      sha256 = getHash getArch;
+    };
+
+  nativeBuildInputs = [
+    jre
+    makeWrapper
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    mv * $out
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/run_konan --prefix PATH ":" ${lib.makeBinPath [ jre ]}
+  '';
+
+  meta = {
+    homepage = "https://kotlinlang.org/";
+    description = "Modern programming language that makes developers happier";
+    longDescription = ''
+      Kotlin/Native is a technology for compiling Kotlin code to native
+      binaries, which can run without a virtual machine. It is an LLVM based
+      backend for the Kotlin compiler and native implementation of the Kotlin
+      standard library.
+    '';
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ fabianhjr ];
+    platforms = [ "x86_64-linux" ] ++ lib.platforms.darwin;
+  };
+}