push sheeet

pkgs/development/gnuradio-modules/bladeRF/default.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  mkDerivation,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  boost,
+  doxygen,
+  gmp,
+  gnuradio,
+  libbladeRF,
+  mpir,
+  osmosdr,
+  python,
+  spdlog,
+}:
+
+mkDerivation {
+  pname = "gr-bladeRF";
+  version = "0-unstable-2023-11-20";
+
+  src = fetchFromGitHub {
+    owner = "Nuand";
+    repo = "gr-bladeRF";
+    rev = "27de2898dbee75d55c61f541315e3853e602e526";
+    hash = "sha256-josovHEp2VxgZqItkTAISdY1LARMIvQKD604fh4iZWc=";
+  };
+
+  buildInputs = [
+    boost
+    doxygen
+    gmp
+    gnuradio
+    libbladeRF
+    mpir
+    osmosdr
+    spdlog
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.numpy
+    python.pkgs.pybind11
+  ];
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_PYTHON" (gnuradio.hasFeature "python-support"))
+  ];
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.mako
+    python.pkgs.pygccxml
+  ];
+
+  meta = {
+    description = "GNU Radio source and sink blocks for bladeRF devices";
+    homepage = "https://github.com/Nuand/gr-bladeRF";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ wucke13 ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/development/gnuradio-modules/fosphor/default.nix

@@ -0,0 +1,91 @@
+{
+  lib,
+  mkDerivation,
+  fetchgit,
+  gnuradio,
+  cmake,
+  pkg-config,
+  logLib,
+  mpir,
+  gmp,
+  boost,
+  libGL,
+  opencl-headers,
+  ocl-icd,
+  freetype,
+  fftwFloat,
+  qt5,
+  python,
+  enableGLFW ? true,
+  glfw3,
+  enablePNG ? true,
+  libpng,
+  gnuradioOlder,
+  gnuradioAtLeast,
+}:
+
+mkDerivation {
+  pname = "gr-fosphor";
+  version = "unstable-2024-03-23";
+
+  # It is a gitea instance, but its archive service doesn't work very well so
+  # we can't use it.
+  src = fetchgit {
+    url = "https://gitea.osmocom.org/sdr/gr-fosphor.git";
+    rev = "74d54fc0b3ec9aeb7033686526c5e766f36eaf24";
+    hash = "sha256-FBmH4DmKATl0FPFU7T30OrYYmxlSTTLm1SZpt0o1qkw=";
+  };
+  disabled = gnuradioOlder "3.9" || gnuradioAtLeast "3.11";
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "gr-qtgui") [
+    qt5.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    logLib
+    mpir
+    gmp
+    boost
+    libGL
+    opencl-headers
+    ocl-icd
+    freetype
+    fftwFloat
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "gr-qtgui") [
+    qt5.qtbase
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.pybind11
+    python.pkgs.numpy
+  ]
+  ++ lib.optionals enableGLFW [
+    glfw3
+  ]
+  ++ lib.optionals enablePNG [
+    libpng
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_QT" (gnuradio.hasFeature "gr-qtgui"))
+    (lib.cmakeBool "ENABLE_PYTHON" (gnuradio.hasFeature "python-support"))
+    (lib.cmakeBool "ENABLE_GLFW" enableGLFW)
+    (lib.cmakeBool "ENABLE_PNG" enablePNG)
+  ];
+
+  meta = {
+    description = "GNU Radio block for RTSA-like spectrum visualization using OpenCL and OpenGL acceleration";
+    longDescription = ''
+      You'll need to install an OpenCL ICD for it to work.
+      See https://nixos.org/manual/nixos/stable/#sec-gpu-accel-opencl
+    '';
+    homepage = "https://projects.osmocom.org/projects/sdr/wiki/Fosphor";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ chuangzhu ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/development/gnuradio-modules/lora_sdr/default.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  mkDerivation,
+  fetchFromGitHub,
+  gnuradio,
+  cmake,
+  pkg-config,
+  logLib,
+  mpir,
+  gmp,
+  boost,
+  python,
+  gnuradioOlder,
+}:
+
+mkDerivation {
+  pname = "gr-lora_sdr";
+  version = "unstable-2025-01-09";
+
+  src = fetchFromGitHub {
+    owner = "tapparelj";
+    repo = "gr-lora_sdr";
+    rev = "9befbad3e6120529918acf1a742e25465f6b95e4";
+    hash = "sha256-9oBdzoS2aWWXmiUk5rI0gG3g+BJqUDgMu3/PmZSUkuU=";
+  };
+  disabled = gnuradioOlder "3.10";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    logLib
+    mpir
+    gmp
+    boost
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.pybind11
+    python.pkgs.numpy
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_PYTHON" (gnuradio.hasFeature "python-support"))
+  ];
+
+  meta = {
+    description = "Fully-functional GNU Radio software-defined radio (SDR) implementation of a LoRa transceiver";
+    homepage = "https://www.epfl.ch/labs/tcl/resources-and-sw/lora-phy/";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ chuangzhu ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/development/gnuradio-modules/mkDerivation.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  unwrapped,
+}:
+
+mkDerivation:
+
+args:
+
+# Check if it's supposed to not get built for the current gnuradio version
+if (builtins.hasAttr "disabled" args) && args.disabled then
+  let
+    name = args.name or "${args.pname}";
+  in
+  throw "Package ${name} is incompatible with GNURadio ${unwrapped.versionAttr.major}"
+else
+
+if builtins.hasAttr "disabledForGRafter" args then
+  throw ''
+    `disabledForGRafter` is superseded by `disabled`.
+    Use `disabled = gnuradioAtLeast "${args.disabledForGRafter}";` instead.
+  ''
+else
+
+  let
+    args_ = {
+      enableParallelBuilding = args.enableParallelBuilding or true;
+      nativeBuildInputs = (args.nativeBuildInputs or [ ]);
+      # We add gnuradio and volk itself by default - most gnuradio based packages
+      # will not consider it a dependency worth mentioning and it will almost
+      # always be needed
+      buildInputs = (args.buildInputs or [ ]) ++ [
+        unwrapped
+        unwrapped.volk
+      ];
+    };
+  in
+  mkDerivation (args // args_)

pkgs/development/gnuradio-modules/osmosdr/default.nix

@@ -0,0 +1,90 @@
+{
+  lib,
+  stdenv,
+  mkDerivation,
+  fetchgit,
+  gnuradio,
+  cmake,
+  pkg-config,
+  logLib,
+  libsndfile,
+  mpir,
+  boost,
+  gmp,
+  thrift,
+  fftwFloat,
+  python,
+  uhd,
+  icu,
+  airspy,
+  hackrf,
+  libbladeRF,
+  rtl-sdr,
+  soapysdr-with-plugins,
+  gnuradioAtLeast,
+}:
+
+mkDerivation rec {
+  pname = "gr-osmosdr";
+  version = "0.2.6";
+
+  src = fetchgit {
+    url = "https://gitea.osmocom.org/sdr/gr-osmosdr";
+    rev = "v${version}";
+    hash = "sha256-jCUzBY1pYiEtcRQ97t9F6uEMVYw2NU0eoB5Xc2H6pGQ=";
+  };
+
+  disabled = gnuradioAtLeast "3.11";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  buildInputs = [
+    logLib
+    mpir
+    boost
+    fftwFloat
+    gmp
+    icu
+    airspy
+    hackrf
+    libbladeRF
+    rtl-sdr
+    soapysdr-with-plugins
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "gr-blocks") [
+    libsndfile
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "gr-uhd") [
+    uhd
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "gr-ctrlport") [
+    thrift
+    python.pkgs.thrift
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.numpy
+    python.pkgs.pybind11
+  ];
+  cmakeFlags = [
+    (if (gnuradio.hasFeature "python-support") then "-DENABLE_PYTHON=ON" else "-DENABLE_PYTHON=OFF")
+  ];
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ]
+  ++ lib.optionals (gnuradio.hasFeature "python-support") [
+    python.pkgs.mako
+    python
+  ];
+
+  meta = {
+    description = "Gnuradio block for OsmoSDR and rtl-sdr";
+    homepage = "https://sdr.osmocom.org/trac/wiki/GrOsmoSDR";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ bjornfor ];
+    platforms = lib.platforms.unix;
+  };
+}