push sheeet

pkgs/development/interpreters/janet/default.nix

@@ -0,0 +1,77 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  nix-update-script,
+  runCommand,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "janet";
+  version = "1.39.1";
+
+  src = fetchFromGitHub {
+    owner = "janet-lang";
+    repo = "janet";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Hd8DueT9f7vmK0QFJdRx7FgZ8BYh5prQyM++5Yb6tg4=";
+  };
+
+  postPatch = ''
+    substituteInPlace janet.1 \
+      --replace /usr/local/ $out/
+  ''
+  + lib.optionalString stdenv.hostPlatform.isDarwin ''
+    # error: Socket is not connected
+    substituteInPlace meson.build \
+      --replace "'test/suite-ev.janet'," ""
+  '';
+
+  nativeBuildInputs = [
+    meson
+    ninja
+  ];
+
+  mesonBuildType = "release";
+  mesonFlags = [ "-Dgit_hash=release" ];
+
+  doCheck = true;
+
+  doInstallCheck = true;
+
+  installCheckPhase = ''
+    $out/bin/janet -e '(+ 1 2 3)'
+  '';
+
+  passthru = {
+    tests.run =
+      runCommand "janet-test-run"
+        {
+          nativeBuildInputs = [ finalAttrs.finalPackage ];
+        }
+        ''
+          echo "(+ 1 2 3)" | janet | tail -n 1 > arithmeticTest.txt;
+          diff -U3 --color=auto <(cat arithmeticTest.txt) <(echo "6");
+
+          echo "(print \"Hello, World!\")" | janet | tail -n 2 > ioTest.txt;
+          diff -U3 --color=auto <(cat ioTest.txt) <(echo -e "Hello, World!\nnil");
+
+          touch $out;
+        '';
+    updateScript = nix-update-script { };
+  };
+
+  meta = with lib; {
+    description = "Janet programming language";
+    mainProgram = "janet";
+    homepage = "https://janet-lang.org/";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      andrewchambers
+      peterhoeg
+    ];
+    platforms = platforms.all;
+  };
+})

pkgs/development/interpreters/janet/jpm.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  janet,
+}:
+
+let
+  platformFiles = {
+    aarch64-darwin = "macos_config.janet";
+    aarch64-linux = "linux_config.janet";
+    x86_64-darwin = "macos_config.janet";
+    x86_64-linux = "linux_config.janet";
+  };
+
+  platformFile = platformFiles.${stdenv.hostPlatform.system};
+
+in
+stdenv.mkDerivation rec {
+  pname = "jpm";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "janet-lang";
+    repo = "jpm";
+    rev = "v${version}";
+    sha256 = "sha256-lPB4jew6RkJlDp8xOQ4YA9MkgLBImaBHcvv4WF/sLRc=";
+  };
+
+  # `auto-shebangs true` gives us a shebang line that points to janet inside the
+  # jpm bin folder
+  postPatch = ''
+    substituteInPlace configs/${platformFile} \
+      --replace 'auto-shebang true' 'auto-shebang false' \
+      --replace /usr/local $out
+  '';
+
+  dontConfigure = true;
+
+  buildInputs = [ janet ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{lib/janet,share/man/man1}
+
+    janet bootstrap.janet configs/${platformFile}
+
+    runHook postInstall
+  '';
+
+  doInstallCheck = true;
+
+  installCheckPhase = ''
+    $out/bin/jpm help
+  '';
+
+  meta = janet.meta // {
+    description = "Janet Project Manager for the Janet programming language";
+    mainProgram = "jpm";
+    platforms = lib.attrNames platformFiles;
+  };
+}