push sheeet

pkgs/development/interpreters/rakudo/default.nix

@@ -0,0 +1,56 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  perl,
+  icu,
+  zlib,
+  gmp,
+  lib,
+  nqp,
+  removeReferencesTo,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rakudo";
+  version = "2025.06.1";
+
+  # nixpkgs-update: no auto update
+  src = fetchFromGitHub {
+    owner = "rakudo";
+    repo = "rakudo";
+    rev = version;
+    hash = "sha256-cofiX6VHHeki8GQcMamDyPYoVMUKiuhKVz8Gh8L9qu0=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ removeReferencesTo ];
+
+  buildInputs = [
+    icu
+    zlib
+    gmp
+    perl
+  ];
+  configureScript = "perl ./Configure.pl";
+  configureFlags = [
+    "--backends=moar"
+    "--with-nqp=${nqp}/bin/nqp"
+  ];
+
+  disallowedReferences = [ stdenv.cc.cc ];
+  postFixup = ''
+    remove-references-to -t ${stdenv.cc.cc} "$(readlink -f $out/share/perl6/runtime/dynext/libperl6_ops_moar${stdenv.hostPlatform.extensions.sharedLibrary})"
+  '';
+
+  meta = {
+    description = "Raku implementation on top of Moar virtual machine";
+    homepage = "https://rakudo.org";
+    license = lib.licenses.artistic2;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      thoughtpolice
+      sgo
+      prince213
+    ];
+  };
+}

pkgs/development/interpreters/rakudo/moarvm.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  perl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "moarvm";
+  version = "2025.06";
+
+  # nixpkgs-update: no auto update
+  src = fetchFromGitHub {
+    owner = "moarvm";
+    repo = "moarvm";
+    rev = version;
+    hash = "sha256-QtJ8cLAbsFJ26wkfQCbIMVU1ArWlAXjsQ/RJbQ0wRNo=";
+    fetchSubmodules = true;
+  };
+
+  postPatch = ''
+    patchShebangs .
+  ''
+  + lib.optionalString stdenv.hostPlatform.isDarwin ''
+    substituteInPlace Configure.pl \
+      --replace '`/usr/bin/arch`' '"${stdenv.hostPlatform.darwinArch}"' \
+      --replace '/usr/bin/arch' "$(type -P true)" \
+      --replace '/usr/' '/nope/'
+    substituteInPlace 3rdparty/dyncall/configure \
+      --replace '`sw_vers -productVersion`' '"11.0"'
+  '';
+
+  buildInputs = [ perl ];
+  doCheck = false; # MoarVM does not come with its own test suite
+
+  configureScript = "${perl}/bin/perl ./Configure.pl";
+
+  meta = {
+    description = "VM with adaptive optimization and JIT compilation, built for Rakudo";
+    homepage = "https://moarvm.org";
+    license = lib.licenses.artistic2;
+    maintainers = with lib.maintainers; [
+      thoughtpolice
+      sgo
+      prince213
+    ];
+    mainProgram = "moar";
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/development/interpreters/rakudo/nqp.nix

@@ -0,0 +1,53 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  perl,
+  lib,
+  moarvm,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nqp";
+  version = "2025.06.1";
+
+  # nixpkgs-update: no auto update
+  src = fetchFromGitHub {
+    owner = "raku";
+    repo = "nqp";
+    rev = version;
+    hash = "sha256-zM3JilRBbx2r8s+dj9Yn8m2SQfQFnn1bxOUiz3Q7FT8=";
+    fetchSubmodules = true;
+  };
+
+  buildInputs = [ perl ];
+
+  configureScript = "${perl}/bin/perl ./Configure.pl";
+
+  # Fix for issue where nqp expects to find files from moarvm in the same output:
+  # https://github.com/Raku/nqp/commit/e6e069507de135cc71f77524455fc6b03b765b2f
+  #
+  preBuild = ''
+    share_dir="share/nqp/lib/MAST"
+    mkdir -p $out/$share_dir
+    ln -fs ${moarvm}/$share_dir/{Nodes,Ops}.nqp $out/$share_dir
+  '';
+
+  configureFlags = [
+    "--backends=moar"
+    "--with-moar=${moarvm}/bin/moar"
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Lightweight Raku-like environment for virtual machines";
+    homepage = "https://github.com/Raku/nqp";
+    license = lib.licenses.artistic2;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      thoughtpolice
+      sgo
+      prince213
+    ];
+  };
+}

pkgs/development/interpreters/rakudo/zef.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  rakudo,
+  makeBinaryWrapper,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "zef";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "ugexe";
+    repo = "zef";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-TUsEevaxB8DYMNhAsF8qFf1owv5ML8xSyGS9C0IkfbI=";
+  };
+
+  nativeBuildInputs = [
+    makeBinaryWrapper
+  ];
+
+  buildInputs = [
+    rakudo
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out"
+    # TODO: Find better solution. zef stores cache stuff in $HOME with the
+    # default config.
+    env HOME=$TMPDIR ${rakudo}/bin/raku -I. ./bin/zef --/depends --/test-depends --/build-depends --install-to=$out install .
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/zef --prefix RAKUDOLIB , "inst#$out"
+  '';
+
+  meta = {
+    description = "Raku / Perl6 Module Management";
+    homepage = "https://github.com/ugexe/zef";
+    license = lib.licenses.artistic2;
+    mainProgram = "zef";
+    maintainers = with lib.maintainers; [ sgo ];
+    platforms = lib.platforms.unix;
+  };
+})