push sheeet

pkgs/development/interpreters/ruby/default.nix

@@ -0,0 +1,442 @@
+{
+  stdenv,
+  buildPackages,
+  lib,
+  fetchurl,
+  fetchpatch,
+  zlib,
+  gdbm,
+  ncurses,
+  readline,
+  groff,
+  libyaml,
+  libffi,
+  jemalloc,
+  autoreconfHook,
+  bison,
+  autoconf,
+  libiconv,
+  libunwind,
+  buildEnv,
+  bundler,
+  bundix,
+  cargo,
+  rustPlatform,
+  rustc,
+  makeBinaryWrapper,
+  buildRubyGem,
+  defaultGemConfig,
+  removeReferencesTo,
+  openssl,
+  linuxPackages,
+  libsystemtap,
+  gitUpdater,
+}@args:
+
+let
+  op = lib.optional;
+  ops = lib.optionals;
+  opString = lib.optionalString;
+  rubygems = import ./rubygems {
+    inherit
+      stdenv
+      lib
+      fetchurl
+      gitUpdater
+      ;
+  };
+
+  # Contains the ruby version heuristics
+  rubyVersion = import ./ruby-version.nix { inherit lib; };
+
+  generic =
+    {
+      version,
+      hash,
+      cargoHash ? null,
+    }:
+    let
+      ver = version;
+      atLeast31 = lib.versionAtLeast ver.majMin "3.1";
+      atLeast32 = lib.versionAtLeast ver.majMin "3.2";
+      # https://github.com/ruby/ruby/blob/v3_2_2/yjit.h#L21
+      yjitSupported =
+        atLeast32
+        && (
+          stdenv.hostPlatform.isx86_64 || (!stdenv.hostPlatform.isWindows && stdenv.hostPlatform.isAarch64)
+        );
+      rubyDrv = lib.makeOverridable (
+        {
+          stdenv,
+          buildPackages,
+          lib,
+          fetchurl,
+          fetchpatch,
+          rubygemsSupport ? true,
+          zlib,
+          zlibSupport ? true,
+          openssl,
+          opensslSupport ? true,
+          gdbm,
+          gdbmSupport ? true,
+          ncurses,
+          readline,
+          cursesSupport ? true,
+          groff,
+          docSupport ? true,
+          libyaml,
+          yamlSupport ? true,
+          libffi,
+          fiddleSupport ? true,
+          jemalloc,
+          jemallocSupport ? false,
+          linuxPackages,
+          systemtap ? linuxPackages.systemtap,
+          libsystemtap,
+          dtraceSupport ? false,
+          # By default, ruby has 3 observed references to stdenv.cc:
+          #
+          # - If you run:
+          #     ruby -e "puts RbConfig::CONFIG['configure_args']"
+          # - In:
+          #     $out/${passthru.libPath}/${stdenv.hostPlatform.system}/rbconfig.rb
+          #   Or (usually):
+          #     $(nix-build -A ruby)/lib/ruby/2.6.0/x86_64-linux/rbconfig.rb
+          # - In $out/lib/libruby.so and/or $out/lib/libruby.dylib
+          removeReferencesTo,
+          jitSupport ? yjitSupport,
+          cargo,
+          rustPlatform,
+          rustc,
+          yjitSupport ? yjitSupported,
+          autoreconfHook,
+          bison,
+          autoconf,
+          buildEnv,
+          bundler,
+          bundix,
+          libiconv,
+          libunwind,
+          makeBinaryWrapper,
+          buildRubyGem,
+          defaultGemConfig,
+          baseRuby ? buildPackages.ruby.override {
+            docSupport = false;
+            rubygemsSupport = false;
+          },
+          useBaseRuby ? stdenv.hostPlatform != stdenv.buildPlatform,
+          gitUpdater,
+        }:
+        stdenv.mkDerivation (finalAttrs: {
+          pname = "ruby";
+          inherit version;
+
+          src = fetchurl {
+            url = "https://cache.ruby-lang.org/pub/ruby/${ver.majMin}/ruby-${ver}.tar.gz";
+            inherit hash;
+          };
+
+          # Have `configure' avoid `/usr/bin/nroff' in non-chroot builds.
+          NROFF = if docSupport then "${groff}/bin/nroff" else null;
+
+          outputs = [ "out" ] ++ lib.optional docSupport "devdoc";
+
+          strictDeps = true;
+
+          nativeBuildInputs = [
+            autoreconfHook
+            bison
+            removeReferencesTo
+          ]
+          ++ (op docSupport groff)
+          ++ (ops (dtraceSupport && stdenv.hostPlatform.isLinux) [
+            systemtap
+            libsystemtap
+          ])
+          ++ ops yjitSupport [
+            rustPlatform.cargoSetupHook
+            cargo
+            rustc
+          ]
+          ++ op useBaseRuby baseRuby;
+          buildInputs = [
+            autoconf
+          ]
+          ++ (op fiddleSupport libffi)
+          ++ (ops cursesSupport [
+            ncurses
+            readline
+          ])
+          ++ (op zlibSupport zlib)
+          ++ (op opensslSupport openssl)
+          ++ (op gdbmSupport gdbm)
+          ++ (op yamlSupport libyaml)
+          # Looks like ruby fails to build on darwin without readline even if curses
+          # support is not enabled, so add readline to the build inputs if curses
+          # support is disabled (if it's enabled, we already have it) and we're
+          # running on darwin
+          ++ op (!cursesSupport && stdenv.hostPlatform.isDarwin) readline
+          ++ ops stdenv.hostPlatform.isDarwin [
+            libiconv
+            libunwind
+          ];
+          propagatedBuildInputs = op jemallocSupport jemalloc;
+
+          enableParallelBuilding = true;
+          # /build/ruby-2.7.7/lib/fileutils.rb:882:in `chmod':
+          #   No such file or directory @ apply2files - ...-ruby-2.7.7-devdoc/share/ri/2.7.0/system/ARGF/inspect-i.ri (Errno::ENOENT)
+          # make: *** [uncommon.mk:373: do-install-all] Error 1
+          enableParallelInstalling = false;
+
+          patches =
+            op (lib.versionOlder ver.majMin "3.1") ./do-not-regenerate-revision.h.patch
+            ++ op useBaseRuby (
+              if atLeast32 then ./do-not-update-gems-baseruby-3.2.patch else ./do-not-update-gems-baseruby.patch
+            )
+            ++ ops (ver.majMin == "3.0") [
+              # Ruby 3.0 adds `-fdeclspec` to $CC instead of $CFLAGS. Fixed in later versions.
+              (fetchpatch {
+                url = "https://github.com/ruby/ruby/commit/0acc05caf7518cd0d63ab02bfa036455add02346.patch";
+                hash = "sha256-43hI9L6bXfeujgmgKFVmiWhg7OXvshPCCtQ4TxqK1zk=";
+              })
+            ]
+            ++ ops atLeast31 [
+              # When using a baseruby, ruby always sets "libdir" to the build
+              # directory, which nix rejects due to a reference in to /build/ in
+              # the final product. Removing this reference doesn't seem to break
+              # anything and fixes cross compilation.
+              ./dont-refer-to-build-dir.patch
+            ];
+
+          cargoRoot = opString yjitSupport "yjit";
+
+          cargoDeps =
+            if yjitSupport then
+              rustPlatform.fetchCargoVendor {
+                inherit (finalAttrs) src cargoRoot;
+                hash =
+                  assert cargoHash != null;
+                  cargoHash;
+              }
+            else
+              null;
+
+          postUnpack = opString rubygemsSupport ''
+            rm -rf $sourceRoot/{lib,test}/rubygems*
+            cp -r ${rubygems}/lib/rubygems* $sourceRoot/lib
+          '';
+
+          # Ruby >= 2.1.0 tries to download config.{guess,sub}; copy it from autoconf instead.
+          postPatch = ''
+            sed -i configure.ac -e '/config.guess/d'
+            cp --remove-destination ${autoconf}/share/autoconf/build-aux/config.{guess,sub} tool/
+          '';
+
+          configureFlags = [
+            (lib.enableFeature (!stdenv.hostPlatform.isStatic) "shared")
+            (lib.enableFeature true "pthread")
+            (lib.withFeatureAs true "soname" "ruby-${version}")
+            (lib.withFeatureAs useBaseRuby "baseruby" "${baseRuby}/bin/ruby")
+            (lib.enableFeature dtraceSupport "dtrace")
+            (lib.enableFeature jitSupport "jit-support")
+            (lib.enableFeature yjitSupport "yjit")
+            (lib.enableFeature docSupport "install-doc")
+            (lib.withFeature jemallocSupport "jemalloc")
+            (lib.withFeatureAs docSupport "ridir" "${placeholder "devdoc"}/share/ri")
+            # ruby enables -O3 for gcc, however our compiler hardening wrapper
+            # overrides that by enabling `-O2` which is the minimum optimization
+            # needed for `_FORTIFY_SOURCE`.
+          ]
+          ++ lib.optional stdenv.cc.isGNU "CFLAGS=-O3"
+          ++ [
+          ]
+          ++ ops stdenv.hostPlatform.isDarwin [
+            # on darwin, we have /usr/include/tk.h -- so the configure script detects
+            # that tk is installed
+            "--with-out-ext=tk"
+            # on yosemite, "generating encdb.h" will hang for a very long time without this flag
+            "--with-setjmp-type=setjmp"
+          ]
+          ++ ops stdenv.hostPlatform.isFreeBSD [
+            "rb_cv_gnu_qsort_r=no"
+            "rb_cv_bsd_qsort_r=yes"
+          ];
+
+          preConfigure = opString docSupport ''
+            # rdoc creates XDG_DATA_DIR (defaulting to $HOME/.local/share) even if
+            # it's not going to be used.
+            export HOME=$TMPDIR
+          '';
+
+          # fails with "16993 tests, 2229489 assertions, 105 failures, 14 errors, 89 skips"
+          # mostly TZ- and patch-related tests
+          # TZ- failures are caused by nix sandboxing, I didn't investigate others
+          doCheck = false;
+
+          preInstall = ''
+            # Ruby installs gems here itself now.
+            mkdir -pv "$out/${finalAttrs.passthru.gemPath}"
+            export GEM_HOME="$out/${finalAttrs.passthru.gemPath}"
+          '';
+
+          installFlags = lib.optional docSupport "install-doc";
+          # Bundler tries to create this directory
+          postInstall = ''
+            rbConfig=$(find $out/lib/ruby -name rbconfig.rb)
+            # Remove references to the build environment from the closure
+            sed -i '/^  CONFIG\["\(BASERUBY\|SHELL\|GREP\|EGREP\|MKDIR_P\|MAKEDIRS\|INSTALL\)"\]/d' $rbConfig
+            # Remove unnecessary groff reference from runtime closure, since it's big
+            sed -i '/NROFF/d' $rbConfig
+            ${lib.optionalString (!jitSupport) ''
+              # Get rid of the CC runtime dependency
+              remove-references-to \
+                -t ${stdenv.cc} \
+                $out/lib/libruby*
+              remove-references-to \
+                -t ${stdenv.cc} \
+                $rbConfig
+              sed -i '/CC_VERSION_MESSAGE/d' $rbConfig
+            ''}
+
+            # Allow to override compiler. This is important for cross compiling as
+            # we need to set a compiler that is different from the build one.
+            sed -i "$rbConfig" \
+              -e 's/CONFIG\["CC"\] = "\(.*\)"/CONFIG["CC"] = if ENV["CC"].nil? || ENV["CC"].empty? then "\1" else ENV["CC"] end/' \
+              -e 's/CONFIG\["CXX"\] = "\(.*\)"/CONFIG["CXX"] = if ENV["CXX"].nil? || ENV["CXX"].empty? then "\1" else ENV["CXX"] end/'
+
+            # Remove unnecessary external intermediate files created by gems
+            extMakefiles=$(find $out/${finalAttrs.passthru.gemPath} -name Makefile)
+            for makefile in $extMakefiles; do
+              make -C "$(dirname "$makefile")" distclean
+            done
+            find "$out/${finalAttrs.passthru.gemPath}" \( -name gem_make.out -o -name mkmf.log -o -name exts.mk \) -delete
+            # Bundler tries to create this directory
+            mkdir -p $out/nix-support
+            cat > $out/nix-support/setup-hook <<EOF
+            addGemPath() {
+              addToSearchPath GEM_PATH \$1/${finalAttrs.passthru.gemPath}
+            }
+            addRubyLibPath() {
+              addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby
+              addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby/${ver.libDir}
+              addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby/${ver.libDir}/${stdenv.hostPlatform.system}
+            }
+
+            addEnvHooks "$hostOffset" addGemPath
+            addEnvHooks "$hostOffset" addRubyLibPath
+            EOF
+          ''
+          + opString docSupport ''
+            # Prevent the docs from being included in the closure
+            sed -i "s|\$(DESTDIR)$devdoc|\$(datarootdir)/\$(RI_BASE_NAME)|" $rbConfig
+            sed -i "s|'--with-ridir=$devdoc/share/ri'||" $rbConfig
+
+            # Add rbconfig shim so ri can find docs
+            mkdir -p $devdoc/lib/ruby/site_ruby
+            cp ${./rbconfig.rb} $devdoc/lib/ruby/site_ruby/rbconfig.rb
+          ''
+          + opString useBaseRuby ''
+            # Prevent the baseruby from being included in the closure.
+            remove-references-to \
+              -t ${baseRuby} \
+              $rbConfig $out/lib/libruby*
+          '';
+
+          installCheckPhase = ''
+            overriden_cc=$(CC=foo $out/bin/ruby -rrbconfig -e 'puts RbConfig::CONFIG["CC"]')
+            if [[ "$overriden_cc" != "foo" ]]; then
+               echo "CC cannot be overwritten: $overriden_cc != foo" >&2
+               false
+            fi
+
+            fallback_cc=$(unset CC; $out/bin/ruby -rrbconfig -e 'puts RbConfig::CONFIG["CC"]')
+            if [[ "$fallback_cc" != "$CC" ]]; then
+               echo "CC='$fallback_cc' should be '$CC' by default" >&2
+               false
+            fi
+          '';
+          doInstallCheck = true;
+
+          disallowedRequisites = op (!jitSupport) stdenv.cc ++ op useBaseRuby baseRuby;
+
+          meta = with lib; {
+            description = "Object-oriented language for quick and easy programming";
+            homepage = "https://www.ruby-lang.org/";
+            license = licenses.ruby;
+            maintainers = with maintainers; [ manveru ];
+            platforms = platforms.all;
+            mainProgram = "ruby";
+            knownVulnerabilities = op (lib.versionOlder ver.majMin "3.0") "This Ruby release has reached its end of life. See https://www.ruby-lang.org/en/downloads/branches/.";
+          };
+
+          passthru = rec {
+            version = ver;
+            rubyEngine = "ruby";
+            libPath = "lib/${rubyEngine}/${ver.libDir}";
+            gemPath = "lib/${rubyEngine}/gems/${ver.libDir}";
+            devEnv = import ./dev.nix {
+              inherit buildEnv bundler bundix;
+              ruby = finalAttrs.finalPackage;
+            };
+
+            inherit rubygems;
+            inherit
+              (import ../../ruby-modules/with-packages {
+                inherit
+                  lib
+                  stdenv
+                  makeBinaryWrapper
+                  buildRubyGem
+                  buildEnv
+                  ;
+                gemConfig = defaultGemConfig;
+                ruby = finalAttrs.finalPackage;
+              })
+              withPackages
+              buildGems
+              gems
+              ;
+          }
+          // lib.optionalAttrs useBaseRuby {
+            inherit baseRuby;
+          };
+        })
+      ) args;
+    in
+    rubyDrv;
+
+in
+{
+  mkRubyVersion = rubyVersion;
+  mkRuby = generic;
+
+  ruby_3_1 = generic {
+    version = rubyVersion "3" "1" "7" "";
+    hash = "sha256-BVas1p8UHdrOA/pd2NdufqDY9SMu3wEkKVebzaqzDns=";
+  };
+
+  ruby_3_2 = generic {
+    version = rubyVersion "3" "2" "9" "";
+    hash = "sha256-q7rZjbmusVJ3Ow01ho5QADuMRn89BhUld8Tf7Z2I7So=";
+    cargoHash = "sha256-CMVx5/+ugDNEuLAvyPN0nGHwQw6RXyfRsMO9I+kyZpk=";
+  };
+
+  ruby_3_3 = generic {
+    version = rubyVersion "3" "3" "9" "";
+    hash = "sha256-0ZkWkKThcjPsazx4RMHhJFwK3OPgDXE1UdBFhGe3J7E=";
+    cargoHash = "sha256-xE7Cv+NVmOHOlXa/Mg72CTSaZRb72lOja98JBvxPvSs=";
+  };
+
+  ruby_3_4 = generic {
+    version = rubyVersion "3" "4" "7" "";
+    hash = "sha256-I4FabQlWlveRkJD9w+L5RZssg9VyJLLkRs4fX3Mz7zY=";
+    cargoHash = "sha256-5Tp8Kth0yO89/LIcU8K01z6DdZRr8MAA0DPKqDEjIt0=";
+  };
+
+  ruby_3_5 = generic {
+    version = rubyVersion "3" "5" "0" "preview1";
+    hash = "sha256-7PCcfrkC6Rza+cxVPNAMypuEiz/A4UKXhQ+asIzdRvA=";
+    cargoHash = "sha256-z7NwWc4TaR042hNx0xgRkh/BQEpEJtE53cfrN0qNiE0=";
+  };
+
+}

pkgs/development/interpreters/ruby/dev.nix

@@ -0,0 +1,29 @@
+/*
+  An environment for development that bundles ruby, bundler and bundix
+  together. This avoids version conflicts where each is using a different
+  version of each-other.
+*/
+{
+  buildEnv,
+  ruby,
+  bundler,
+  bundix,
+}:
+let
+  bundler_ = bundler.override {
+    ruby = ruby;
+  };
+  bundix_ = bundix.override {
+    bundler = bundler_;
+  };
+in
+buildEnv {
+  name = "${ruby.rubyEngine}-dev-${ruby.version}";
+  paths = [
+    bundix_
+    bundler_
+    ruby
+  ];
+  pathsToLink = [ "/bin" ];
+  ignoreCollisions = true;
+}

pkgs/development/interpreters/ruby/do-not-regenerate-revision.h.patch

@@ -0,0 +1,23 @@
+Do not regenerate revision.h
+
+Ruby's makefile compares the shipped version with the git revision to regenerate
+revision.h [1], but since we don't include git in buildInputs, this comparison
+fails and it can't find $(REVISION_H).
+
+[1] https://github.com/ruby/ruby/commit/97a5af62a318fcd93a4e5e4428d576c0280ddbae
+
+diff -Naur ruby.old/defs/gmake.mk ruby.new/defs/gmake.mk
+--- ruby.old/defs/gmake.mk
++++ ruby.new/defs/gmake.mk
+@@ -325,11 +325,9 @@
+ 
+ REVISION_IN_HEADER := $(shell sed -n 's/^\#define RUBY_FULL_REVISION "\(.*\)"/\1/p' $(srcdir)/revision.h 2>/dev/null)
+ REVISION_LATEST := $(shell $(CHDIR) $(srcdir) && git log -1 --format=%H 2>/dev/null)
+-ifneq ($(REVISION_IN_HEADER),$(REVISION_LATEST))
+ # GNU make treat the target as unmodified when its dependents get
+ # updated but it is not updated, while others may not.
+ $(srcdir)/revision.h: $(REVISION_H)
+-endif
+ 
+ # Query on the generated rdoc
+ #

pkgs/development/interpreters/ruby/do-not-update-gems-baseruby-3.2.patch

@@ -0,0 +1,13 @@
+diff --git a/common.mk b/common.mk
+index 3798f82bc6..4d07b28aa4 100644
+--- a/common.mk
++++ b/common.mk
+@@ -1374,7 +1374,7 @@ update-config_files: PHONY
+ 	    config.guess config.sub
+ 
+ refresh-gems: update-bundled_gems prepare-gems
+-prepare-gems: $(HAVE_BASERUBY:yes=update-gems) $(HAVE_BASERUBY:yes=extract-gems)
++prepare-gems:
+ extract-gems: $(HAVE_BASERUBY:yes=update-gems)
+ 
+ update-gems$(gnumake:yes=-sequential): PHONY

pkgs/development/interpreters/ruby/do-not-update-gems-baseruby.patch

@@ -0,0 +1,14 @@
+Do not update gems when building with base ruby
+
+diff -Naur ruby.old/defs/gmake.mk ruby.new/defs/gmake.mk
+--- ruby.old/common.mk
++++ ruby.new/common.mk
+@@ -1298,7 +1298,7 @@ update-config_files: PHONY
+ 	    config.guess config.sub
+ 
+ refresh-gems: update-bundled_gems prepare-gems
+-prepare-gems: $(HAVE_BASERUBY:yes=update-gems) $(HAVE_BASERUBY:yes=extract-gems)
++prepare-gems:
+ 
+ update-gems$(gnumake:yes=-nongnumake): PHONY
+ 	$(ECHO) Downloading bundled gem files...

pkgs/development/interpreters/ruby/dont-refer-to-build-dir.patch

@@ -0,0 +1,12 @@
+diff --git a/tool/fake.rb b/tool/fake.rb
+index 91dfb041c4..9c235f1e3a 100644
+--- a/tool/fake.rb
++++ b/tool/fake.rb
+@@ -48,7 +48,6 @@ class File
+   $builtruby ||= File.join(builddir, config['RUBY_INSTALL_NAME'] + config['EXEEXT'])
+   RbConfig.fire_update!("builddir", builddir)
+   RbConfig.fire_update!("buildlibdir", builddir)
+-  RbConfig.fire_update!("libdir", builddir)
+   RbConfig.fire_update!("prefix", $topdir)
+   RbConfig.fire_update!("top_srcdir", $top_srcdir ||= top_srcdir)
+   RbConfig.fire_update!("extout", $extout)

pkgs/development/interpreters/ruby/rbconfig.rb

@@ -0,0 +1,25 @@
+# This is a shim around whatever real rbconfig.rb is in the LOAD_PATH,
+# so that RbConfig::CONFIG["ridir"] can be overridden to point to the
+# custom location of the ri docs, without the main derivation having
+# those docs in its closure.
+
+MY_PATH = File.realpath(__FILE__)
+
+candidates = $LOAD_PATH.map { |dir| File.join(dir, "rbconfig.rb") }
+
+# First, drop everything _before_ this file in the LOAD_PATH, just on
+# the off-chance somebody is composing shims like this for some reason.
+candidates.drop_while { |c| !File.exist?(c) || File.realpath(c) != MY_PATH }
+
+# Now, the wrapped rbconfig.rb is the next rbconfig.rb in the LOAD_PATH
+# that isn't this same file. (Yes, duplicate LOAD_PATH entries are a
+# thing we have to deal with.)
+next_rbconfig = candidates.find { |c|
+  File.exist?(c) && File.realpath(c) != MY_PATH
+}
+
+# Load the wrapped rbconfig.rb
+require next_rbconfig
+
+# Now we have RbConfig, and can modify it for our own ends.
+RbConfig::CONFIG["ridir"] = File.expand_path("../../../share/ri", __dir__)

pkgs/development/interpreters/ruby/ruby-version.nix

@@ -0,0 +1,91 @@
+# Contains the ruby version heuristics
+{ lib }:
+
+let
+  # The returned set should be immutable
+  rubyVersion = major: minor: tiny: tail: rec {
+    inherit
+      major
+      minor
+      tiny
+      tail
+      ;
+
+    # Contains the patch number "223" if tail is "p223" or null
+    patchLevel =
+      let
+        p = lib.removePrefix "p" tail;
+        isPosInt =
+          num:
+          0 == lib.stringLength (
+            lib.replaceStrings
+              [
+                "0"
+                "1"
+                "2"
+                "3"
+                "4"
+                "5"
+                "6"
+                "7"
+                "8"
+                "9"
+              ]
+              [
+                ""
+                ""
+                ""
+                ""
+                ""
+                ""
+                ""
+                ""
+                ""
+                ""
+              ]
+              num
+          );
+      in
+      if lib.hasPrefix "p" tail && isPosInt p then p else null;
+
+    # Shortcuts
+    majMin = "${major}.${minor}";
+    majMinTiny = "${major}.${minor}.${tiny}";
+
+    # Ruby separates lib and gem folders by ABI version which isn't very
+    # consistent.
+    libDir =
+      if lib.versionAtLeast majMinTiny "2.1.0" then
+        "${majMin}.0"
+      else if lib.versionAtLeast majMinTiny "2.0.0" then
+        "2.0.0"
+      else if lib.versionAtLeast majMinTiny "1.9.1" then
+        "1.9.1"
+      else
+        throw "version ${majMinTiny} is not supported";
+
+    # How ruby releases are tagged on github.com/ruby/ruby
+    gitTag =
+      let
+        base = "v${major}_${minor}_${tiny}";
+      in
+      if patchLevel != null then
+        "${base}_${patchLevel}"
+      else if tail != "" then
+        "${base}_${tail}"
+      else
+        base;
+
+    # Implements the builtins.toString interface.
+    __toString =
+      self:
+      self.majMinTiny
+      + (
+        if self.patchLevel != null then
+          "-p${self.patchLevel}"
+        else
+          lib.optionalString (self.tail != "") "-${self.tail}"
+      );
+  };
+in
+rubyVersion

pkgs/development/interpreters/ruby/rubygems/0001-add-post-extract-hook.patch

@@ -0,0 +1,34 @@
+From a6485cfcdf51ff8be452980f93cebfea97f34dec Mon Sep 17 00:00:00 2001
+From: zimbatm <zimbatm@zimbatm.com>
+Date: Wed, 21 Sep 2016 09:32:34 +0100
+Subject: [PATCH 1/3] add post-extract hook
+
+Allows nix to execute scripts just after the gem extraction
+---
+ lib/rubygems/installer.rb | 10 +++++++++-
+ 1 file changed, 9 insertions(+), 1 deletion(-)
+
+diff --git a/lib/rubygems/installer.rb b/lib/rubygems/installer.rb
+index d26b1e88..bf18fb7f 100644
+--- a/lib/rubygems/installer.rb
++++ b/lib/rubygems/installer.rb
+@@ -848,7 +848,15 @@ TEXT
+   # Ensures that files can't be installed outside the gem directory.
+ 
+   def extract_files
+-    @package.extract_files gem_dir
++    ret = @package.extract_files gem_dir
++    if ENV['NIX_POST_EXTRACT_FILES_HOOK']
++      puts
++      puts "running NIX_POST_EXTRACT_FILES_HOOK #{ENV['NIX_POST_EXTRACT_FILES_HOOK']} #{gem_dir}"
++      system(ENV['NIX_POST_EXTRACT_FILES_HOOK'], gem_dir.to_s)
++      puts "running NIX_POST_EXTRACT_FILES_HOOK done"
++      puts
++    end
++    ret
+   end
+ 
+   ##
+-- 
+2.21.0
+

pkgs/development/interpreters/ruby/rubygems/0002-binaries-with-env-shebang.patch

@@ -0,0 +1,28 @@
+From 2e1328bcdddd35e557eabdff83ac07f3591dc693 Mon Sep 17 00:00:00 2001
+From: zimbatm <zimbatm@zimbatm.com>
+Date: Wed, 21 Sep 2016 19:37:05 +0100
+Subject: [PATCH 2/3] binaries with env shebang
+
+By default, don't point to the absolute ruby derivation path. As a user
+installing a gem in the home, it would freeze the selected ruby version
+to the currently-installed ruby derivation.
+---
+ lib/rubygems/dependency_installer.rb | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/lib/rubygems/dependency_installer.rb b/lib/rubygems/dependency_installer.rb
+index 34620860..00ab31d9 100644
+--- a/lib/rubygems/dependency_installer.rb
++++ b/lib/rubygems/dependency_installer.rb
+@@ -17,7 +17,7 @@ class Gem::DependencyInstaller
+   extend Gem::Deprecate
+ 
+   DEFAULT_OPTIONS = { # :nodoc:
+-    env_shebang: false,
++    env_shebang: true,
+     document: %w[ri],
+     domain: :both, # HACK: dup
+     force: false,
+-- 
+2.21.0
+

pkgs/development/interpreters/ruby/rubygems/0003-gem-install-default-to-user.patch

@@ -0,0 +1,26 @@
+From d69249d0ff210316121b44d971ddd2439b1bc393 Mon Sep 17 00:00:00 2001
+From: zimbatm <zimbatm@zimbatm.com>
+Date: Wed, 21 Sep 2016 09:40:39 +0100
+Subject: [PATCH 3/3] gem install default to user
+
+Default to not installing gems to the read-only system derivation.
+---
+ lib/rubygems/path_support.rb | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/lib/rubygems/path_support.rb b/lib/rubygems/path_support.rb
+index ed680d65..749b9ea6 100644
+--- a/lib/rubygems/path_support.rb
++++ b/lib/rubygems/path_support.rb
+@@ -24,7 +24,7 @@ class Gem::PathSupport
+   # hashtable, or defaults to ENV, the system environment.
+   #
+   def initialize(env)
+-    @home = normalize_home_dir(env["GEM_HOME"] || Gem.default_dir)
++    @home = normalize_home_dir(env["GEM_HOME"] || Gem.user_dir || Gem.default_dir)
+     @path = split_gem_path env["GEM_PATH"], @home
+ 
+     @spec_cache_dir = env["GEM_SPEC_CACHE"] || Gem.default_spec_cache_dir
+-- 
+2.21.0
+

pkgs/development/interpreters/ruby/rubygems/default.nix

@@ -0,0 +1,46 @@
+{
+  fetchurl,
+  gitUpdater,
+  lib,
+  stdenv,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rubygems";
+  version = "3.7.1";
+
+  src = fetchurl {
+    url = "https://rubygems.org/rubygems/rubygems-${version}.tgz";
+    hash = "sha256-dQyMdxGA1B7SNYNE5UYe3ugxWMCoG3eZaaEzmWG8EWM=";
+  };
+
+  patches = [
+    ./0001-add-post-extract-hook.patch
+    ./0002-binaries-with-env-shebang.patch
+    ./0003-gem-install-default-to-user.patch
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    cp -r . $out
+    runHook postInstall
+  '';
+
+  passthru.updateScript = gitUpdater {
+    url = "https://github.com/rubygems/rubygems.git";
+    rev-prefix = "v";
+    ignoredVersions = "(pre|alpha|beta|rc|bundler).*";
+  };
+
+  meta = with lib; {
+    description = "Package management framework for Ruby";
+    changelog = "https://github.com/rubygems/rubygems/blob/v${version}/CHANGELOG.md";
+    homepage = "https://rubygems.org/";
+    license = with licenses; [
+      mit # or
+      ruby
+    ];
+    mainProgram = "gem";
+    maintainers = with maintainers; [ zimbatm ];
+  };
+}