push sheeet

pkgs/development/libraries/icu/default.nix

@@ -0,0 +1,90 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  fetchpatch,
+  fixDarwinDylibNames,
+  testers,
+  buildPackages,
+  updateAutotoolsGnuConfigScriptsHook,
+}:
+
+let
+  make-icu = (import ./make-icu.nix) {
+    inherit
+      stdenv
+      lib
+      buildPackages
+      fetchurl
+      fixDarwinDylibNames
+      testers
+      updateAutotoolsGnuConfigScriptsHook
+      ;
+  };
+in
+{
+  icu77 = make-icu {
+    version = "77.1";
+    hash = "sha256-WI5DH3cyfDkDH/u4hDwOO8EiwhE3RIX6h9xfP6/yQGE=";
+  };
+  icu76 = make-icu {
+    version = "76.1";
+    hash = "sha256-36y0a/5HR0EEcs4+EUS/KKEC/uqk44dbrJtMbPMPTz4=";
+  };
+  icu75 = make-icu {
+    version = "75.1";
+    hash = "sha256-y5aN8+TS6H6LEcSaXQHHh70TuVRSgPxmQvgmUnYYyu8=";
+  };
+  icu74 = make-icu {
+    version = "74.2";
+    hash = "sha256-aNsIIhKpbW9T411g9H04uWLp+dIHp0z6x4Apro/14Iw=";
+  };
+  icu73 = make-icu {
+    version = "73.2";
+    hash = "sha256-gYqAcS7TyqzZtlIwXgGvx/oWfm8ulJltpEuQwqtgTOE=";
+  };
+  icu72 = make-icu {
+    version = "72.1";
+    hash = "sha256-otLTghcJKn7VZjXjRGf5L5drNw4gGCrTJe3qZoGnHWg=";
+  };
+  icu71 = make-icu {
+    version = "71.1";
+    hash = "sha256-Z6fm5R9h+vEwa2k1Mz4TssSKvY2m0vRs5q3KJLHiHr8=";
+  };
+  icu70 = make-icu {
+    version = "70.1";
+    hash = "sha256-jSBUKMF78Tu1NTAGae0oszihV7HAGuZtMdDT4tR8P9U=";
+  };
+  icu69 = make-icu {
+    version = "69.1";
+    hash = "sha256-TLp7es0dPELES7DBS+ZjcJjH+vKzMM6Ha8XzuRXQl0U=";
+  };
+  icu67 = make-icu {
+    version = "67.1";
+    hash = "sha256-lKgM1vJRpTvSqZf28bWsZlP+eR36tm4esCJ3QPuG1dw=";
+  };
+  icu66 = make-icu {
+    version = "66.1";
+    hash = "sha256-UqPyIJq5VVnBzwoU8kM4AB84lhW/AOJYXvPbxD7PCi4=";
+  };
+  icu64 = make-icu {
+    version = "64.2";
+    hash = "sha256-Yn1dhHjm2W/IyQ/tSFEjkHmlYaaoueSLCJLyToLTHWw=";
+  };
+  icu63 = make-icu {
+    version = "63.1";
+    hash = "sha256-BcSQtpRU/OWGC36OKCEjFnSvChHX7y/r6poyUSmYy50=";
+    patches = [
+      # https://bugzilla.mozilla.org/show_bug.cgi?id=1499398
+      (fetchpatch {
+        url = "https://github.com/unicode-org/icu/commit/8baff8f03e07d8e02304d0c888d0bb21ad2eeb01.patch";
+        sha256 = "1awfa98ljcf95a85cssahw6bvdnpbq5brf1kgspy14w4mlmhd0jb";
+      })
+    ];
+    patchFlags = [ "-p3" ];
+  };
+  icu60 = make-icu {
+    version = "60.2";
+    hash = "sha256-8HPqjzW5JtcLsz5ld1CKpkKosxaoA/Eb4grzhIEdtBg=";
+  };
+}

pkgs/development/libraries/icu/make-icu.nix

@@ -0,0 +1,177 @@
+{
+  stdenv,
+  lib,
+  buildPackages,
+  fetchurl,
+  fixDarwinDylibNames,
+  testers,
+  updateAutotoolsGnuConfigScriptsHook,
+}:
+
+{
+  version,
+  hash,
+  patches ? [ ],
+  patchFlags ? [ ],
+  withStatic ? stdenv.hostPlatform.isStatic,
+}:
+
+let
+  # Cross-compiled icu4c requires a build-root of a native compile
+  nativeBuildRoot = buildPackages."icu${lib.versions.major version}".buildRootOnly;
+
+  pname = "icu4c";
+
+  release = lib.replaceStrings [ "." ] [ "-" ] version;
+  # To test rc versions of ICU replace the line above with the line below.
+  #release = lib.replaceStrings [ "." ] [ "-" ] (
+  #  if lib.hasSuffix "rc" version then lib.replaceStrings [ "1" ] [ "" ] version else version
+  #);
+
+  baseAttrs = {
+    src = fetchurl {
+      url = "https://github.com/unicode-org/icu/releases/download/release-${release}/icu4c-${
+        lib.replaceStrings [ "." ] [ "_" ] version
+      }-src.tgz";
+      inherit hash;
+    };
+
+    postUnpack = ''
+      sourceRoot=''${sourceRoot}/source
+      echo Source root reset to ''${sourceRoot}
+    '';
+
+    # https://sourceware.org/glibc/wiki/Release/2.26#Removal_of_.27xlocale.h.27
+    postPatch =
+      if
+        (stdenv.hostPlatform.libc == "glibc" || stdenv.hostPlatform.libc == "musl")
+        && lib.versionOlder version "62.1"
+      then
+        "substituteInPlace i18n/digitlst.cpp --replace '<xlocale.h>' '<locale.h>'"
+      else
+        null; # won't find locale_t on darwin
+
+    inherit patchFlags patches;
+
+    preConfigure = ''
+      sed -i -e "s|/bin/sh|${stdenv.shell}|" configure
+
+      # $(includedir) is different from $(prefix)/include due to multiple outputs
+      sed -i -e 's|^\(CPPFLAGS = .*\) -I\$(prefix)/include|\1 -I$(includedir)|' config/Makefile.inc.in
+    ''
+    + lib.optionalString stdenv.hostPlatform.isAarch32 ''
+      # From https://archlinuxarm.org/packages/armv7h/icu/files/icudata-stdlibs.patch
+      sed -e 's/LDFLAGSICUDT=-nodefaultlibs -nostdlib/LDFLAGSICUDT=/' -i config/mh-linux
+    '';
+
+    dontDisableStatic = withStatic;
+
+    configureFlags = [
+      "--disable-debug"
+    ]
+    ++ lib.optional (stdenv.hostPlatform.isFreeBSD || stdenv.hostPlatform.isDarwin) "--enable-rpath"
+    ++ lib.optional (
+      stdenv.buildPlatform != stdenv.hostPlatform
+    ) "--with-cross-build=${nativeBuildRoot}"
+    ++ lib.optional withStatic "--enable-static";
+
+    enableParallelBuilding = true;
+
+    meta = with lib; {
+      description = "Unicode and globalization support library";
+      homepage = "https://icu.unicode.org/";
+      maintainers = with maintainers; [ raskin ];
+      pkgConfigModules = [
+        "icu-i18n"
+        "icu-io"
+        "icu-uc"
+      ];
+      platforms = platforms.all;
+    };
+  };
+
+  realAttrs = baseAttrs // {
+    inherit pname version;
+
+    outputs = [
+      "out"
+      "dev"
+    ]
+    ++ lib.optional withStatic "static";
+    outputBin = "dev";
+
+    nativeBuildInputs = [
+      updateAutotoolsGnuConfigScriptsHook
+    ]
+    ++
+      # FIXME: This fixes dylib references in the dylibs themselves, but
+      # not in the programs in $out/bin.
+      lib.optional stdenv.hostPlatform.isDarwin fixDarwinDylibNames;
+
+    # remove dependency on bootstrap-tools in early stdenv build
+    postInstall =
+      lib.optionalString withStatic ''
+        mkdir -p $static/lib
+        mv -v lib/*.a $static/lib
+      ''
+      + lib.optionalString stdenv.hostPlatform.isDarwin ''
+        sed -i 's/INSTALL_CMD=.*install/INSTALL_CMD=install/' $out/lib/icu/${lib.versions.majorMinor version}/pkgdata.inc
+      ''
+      + (
+        let
+          replacements = [
+            {
+              from = "\${prefix}/include";
+              to = "${placeholder "dev"}/include";
+            } # --cppflags-searchpath
+            {
+              from = "\${pkglibdir}/Makefile.inc";
+              to = "${placeholder "dev"}/lib/icu/Makefile.inc";
+            } # --incfile
+            {
+              from = "\${pkglibdir}/pkgdata.inc";
+              to = "${placeholder "dev"}/lib/icu/pkgdata.inc";
+            } # --incpkgdatafile
+          ];
+        in
+        ''
+          rm $out/share/icu/${lib.versions.majorMinor version}/install-sh $out/share/icu/${lib.versions.majorMinor version}/mkinstalldirs # Avoid having a runtime dependency on bash
+
+          substituteInPlace "$dev/bin/icu-config" \
+            ${lib.concatMapStringsSep " " (r: "--replace '${r.from}' '${r.to}'") replacements}
+        ''
+      );
+
+    postFixup = ''moveToOutput lib/icu "$dev" '';
+  };
+
+  buildRootOnlyAttrs = baseAttrs // {
+    pname = pname + "-build-root";
+    inherit version;
+
+    preConfigure = baseAttrs.preConfigure + ''
+      mkdir build
+      cd build
+      configureScript=../configure
+    '';
+
+    postBuild = ''
+      cd ..
+      mv build $out
+      echo "Doing build-root only, exiting now" >&2
+      exit 0
+    '';
+  };
+
+  mkWithAttrs =
+    attrs:
+    stdenv.mkDerivation (
+      finalAttrs:
+      attrs
+      // {
+        passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+        passthru.buildRootOnly = mkWithAttrs buildRootOnlyAttrs;
+      }
+    );
+in
+mkWithAttrs realAttrs