push sheeet

pkgs/development/libraries/indicator-application/gtk2.nix

@@ -0,0 +1,73 @@
+{
+  stdenv,
+  fetchurl,
+  lib,
+  file,
+  pkg-config,
+  autoconf,
+  glib,
+  dbus-glib,
+  json-glib,
+  gtk2,
+  libindicator-gtk2,
+  libdbusmenu-gtk2,
+  libappindicator-gtk2,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "indicator-application-gtk2";
+  version = "12.10.0.1";
+
+  src = fetchurl {
+    url = "${meta.homepage}/indicator-application-gtk2/i-a-${version}/+download/indicator-application-${version}.tar.gz";
+    sha256 = "1xqsb6c1pwawabw854f7aybjrgyhc2r1316i9lyjspci51zk5m7v";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    autoconf
+    dbus-glib # dbus-binding-tool
+  ];
+
+  buildInputs = [
+    glib
+    dbus-glib
+    json-glib
+    gtk2
+    libindicator-gtk2
+    libdbusmenu-gtk2
+    libappindicator-gtk2
+  ];
+
+  postPatch = ''
+    substituteInPlace configure.ac \
+      --replace 'DBUSSERVICEDIR=`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`' \
+                "DBUSSERVICEDIR=$out/share/dbus-1/services"
+    autoconf
+    for f in {configure,ltmain.sh,m4/libtool.m4}; do
+      substituteInPlace $f \
+        --replace /usr/bin/file ${file}/bin/file
+    done
+    substituteInPlace src/Makefile.in \
+      --replace 'applicationlibdir = $(INDICATORDIR)' "applicationlibdir = $out/lib"
+  '';
+
+  configureFlags = [
+    "CFLAGS=-Wno-error"
+    "--sysconfdir=/etc"
+    "--localstatedir=/var"
+  ];
+
+  installFlags = [
+    "sysconfdir=\${out}/etc"
+    "localstatedir=\${TMPDIR}"
+  ];
+
+  meta = with lib; {
+    description = "Indicator to take menus from applications and place them in the panel (GTK 2 library for Xfce/LXDE)";
+    homepage = "https://launchpad.net/indicators-gtk2";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.msteen ];
+  };
+}

pkgs/development/libraries/indicator-application/gtk3.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchbzr,
+  pkg-config,
+  systemd,
+  autoreconfHook,
+  glib,
+  dbus-glib,
+  json-glib,
+  gtk3,
+  libindicator-gtk3,
+  libdbusmenu-gtk3,
+  libappindicator-gtk3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "indicator-application";
+  version = "12.10.1";
+
+  name = "${pname}-gtk3-${version}";
+
+  src = fetchbzr {
+    url = "https://code.launchpad.net/~indicator-applet-developers/${pname}/trunk.17.04";
+    rev = "260";
+    sha256 = "1f0jdyqqb5g86zdpbcyn16x94yjigsfiv2kf73dvni5rp1vafbq1";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    autoreconfHook
+    dbus-glib # dbus-binding-tool
+  ];
+
+  buildInputs = [
+    glib
+    dbus-glib
+    json-glib
+    systemd
+    gtk3
+    libindicator-gtk3
+    libdbusmenu-gtk3
+    libappindicator-gtk3
+  ];
+
+  postPatch = ''
+    substituteInPlace data/Makefile.am \
+      --replace "/etc/xdg/autostart" "$out/etc/xdg/autostart"
+  '';
+
+  configureFlags = [
+    "CFLAGS=-Wno-error"
+    "--sysconfdir=/etc"
+    "--localstatedir=/var"
+  ];
+
+  installFlags = [
+    "sysconfdir=\${out}/etc"
+    "localstatedir=\${TMPDIR}"
+  ];
+
+  PKG_CONFIG_SYSTEMD_SYSTEMDUSERUNITDIR = "$(out)/lib/systemd/user";
+  PKG_CONFIG_INDICATOR3_0_4_INDICATORDIR = "$(out)/lib/indicators3/7/";
+
+  # Upstart is not used in NixOS
+  postFixup = ''
+    rm -rf $out/share/indicator-application/upstart
+    rm -rf $out/share/upstart
+  '';
+
+  meta = with lib; {
+    description = "Indicator to take menus from applications and place them in the panel";
+    homepage = "https://launchpad.net/indicator-application";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.msteen ];
+  };
+}