push sheeet

pkgs/development/libraries/libqtdbustest/default.nix

@@ -0,0 +1,106 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  fetchpatch,
+  testers,
+  cmake,
+  cmake-extras,
+  dbus,
+  dbus-test-runner,
+  gtest,
+  pkg-config,
+  procps,
+  python3,
+  qtbase,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libqtdbustest";
+  version = "0.3.2";
+
+  src = fetchFromGitLab {
+    owner = "ubports";
+    repo = "development/core/libqtdbustest";
+    rev = finalAttrs.version;
+    hash = "sha256-yqqyKxsbqiVTrkas79YoPMi28dKFNntiE7+dx1v+Qh4=";
+  };
+
+  patches = [
+    # Tests are overly pedantic when looking for launched process names in `ps`, break on python wrapper vs real python
+    # Just check if basename + arguments match, like libqtdbusmock does
+    ./less-pedantic-process-finding.patch
+
+    # Disable QProcess start timeout
+    (fetchpatch {
+      url = "https://salsa.debian.org/ubports-team/libqtdbustest/-/raw/debian/0.3.2-3/debian/patches/1003_no-QProcess-waitForstarted-timeout.patch";
+      hash = "sha256-ThDbn6URvkj5ARDMj+xO0fb1Qh2YQRzVy24O03KglHI=";
+    })
+
+    # More robust dbus address reading
+    (fetchpatch {
+      url = "https://salsa.debian.org/ubports-team/libqtdbustest/-/raw/debian/0.3.2-3/debian/patches/1004_make-reading-address-from-dbus-daemon-more-robust.patch";
+      hash = "sha256-hq8pdducp/udxoGWGt1dgL/7VHcbJO/oT1dOY1zew8M=";
+    })
+  ];
+
+  strictDeps = true;
+
+  postPatch = lib.optionalString (!finalAttrs.finalPackage.doCheck) ''
+    # Don't build tests when we're not running them
+    sed -i -e '/add_subdirectory(tests)/d' CMakeLists.txt
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    cmake-extras
+    qtbase
+  ];
+
+  nativeCheckInputs = [
+    dbus
+    dbus-test-runner
+    procps
+    (python3.withPackages (
+      ps: with ps; [
+        python-dbusmock
+      ]
+    ))
+  ];
+
+  checkInputs = [
+    gtest
+  ];
+
+  dontWrapQtApps = true;
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  enableParallelChecking = false;
+
+  checkPhase = ''
+    runHook preCheck
+
+    dbus-test-runner -t make -p test -p "''${enableParallelChecking:+-j $NIX_BUILD_CORES}"
+
+    runHook postCheck
+  '';
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = with lib; {
+    description = "Library for testing DBus interactions using Qt";
+    homepage = "https://launchpad.net/libqtdbustest";
+    license = licenses.lgpl3Only;
+    platforms = platforms.unix;
+    teams = [ teams.lomiri ];
+    mainProgram = "qdbus-simple-test-runner";
+    pkgConfigModules = [
+      "libqtdbustest-1"
+    ];
+  };
+})

pkgs/development/libraries/libqtdbustest/less-pedantic-process-finding.patch

@@ -0,0 +1,87 @@
+diff '--color=auto' -ur '--color=never' a/tests/libqtdbustest/TestDBusTestRunner.cpp b/tests/libqtdbustest/TestDBusTestRunner.cpp
+--- a/tests/libqtdbustest/TestDBusTestRunner.cpp	2023-01-20 21:36:16.948292559 +0100
++++ b/tests/libqtdbustest/TestDBusTestRunner.cpp	2023-01-20 21:55:40.554530221 +0100
+@@ -44,7 +44,7 @@
+ TEST_F(TestDBusTestRunner, StartsSessionService) {
+ 	QSharedPointer<QProcessDBusService> process(
+ 			new QProcessDBusService("test.session.name",
+-					QDBusConnection::SessionBus, "/usr/bin/python3",
++					QDBusConnection::SessionBus, "python3",
+ 					QStringList() << "-m" << "dbusmock" << "test.session.name"
+ 							<< "/test/object" << "test.Interface"));
+ 
+@@ -58,15 +58,14 @@
+ 	pgrep.waitForFinished();
+ 	pgrep.waitForReadyRead();
+ 
+-	EXPECT_EQ(
+-			"/usr/bin/python3 -m dbusmock test.session.name /test/object test.Interface",
+-			QString::fromUtf8(pgrep.readAll().trimmed()).toStdString());
++	EXPECT_TRUE(
++			pgrep.readAll().contains("python3 -m dbusmock test.session.name /test/object test.Interface"));
+ }
+ 
+ TEST_F(TestDBusTestRunner, StartsSystemService) {
+ 	QSharedPointer<QProcessDBusService> process(
+ 			new QProcessDBusService("test.system.name",
+-					QDBusConnection::SystemBus, "/usr/bin/python3",
++					QDBusConnection::SystemBus, "python3",
+ 					QStringList() << "-m" << "dbusmock" << "-s"
+ 							<< "test.system.name" << "/test/object"
+ 							<< "test.Interface"));
+@@ -81,9 +80,8 @@
+ 	pgrep.waitForFinished();
+ 	pgrep.waitForReadyRead();
+ 
+-	EXPECT_EQ(
+-			"/usr/bin/python3 -m dbusmock -s test.system.name /test/object test.Interface",
+-			QString::fromUtf8(pgrep.readAll().trimmed()).toStdString());
++	EXPECT_TRUE(
++			pgrep.readAll().contains("python3 -m dbusmock -s test.system.name /test/object test.Interface"));
+ }
+ 
+ TEST_F(TestDBusTestRunner, SetsEnvironmentVariables) {
+diff '--color=auto' -ur '--color=never' a/tests/libqtdbustest/TestQProcessDBusService.cpp b/tests/libqtdbustest/TestQProcessDBusService.cpp
+--- a/tests/libqtdbustest/TestQProcessDBusService.cpp	2023-01-20 21:36:16.948292559 +0100
++++ b/tests/libqtdbustest/TestQProcessDBusService.cpp	2023-01-20 21:54:34.633384937 +0100
+@@ -45,7 +45,7 @@
+ 
+ TEST_F(TestQProcessDBusService, WaitsForServiceAppeared) {
+ 	QProcessDBusService process("test.name", QDBusConnection::SessionBus,
+-			"/usr/bin/python3",
++			"python3",
+ 			QStringList() << "-m" << "dbusmock" << "test.name" << "/test/object"
+ 					<< "test.Interface");
+ 
+@@ -58,14 +58,13 @@
+ 	pgrep.waitForFinished();
+ 	pgrep.waitForReadyRead();
+ 
+-	EXPECT_EQ(
+-			"/usr/bin/python3 -m dbusmock test.name /test/object test.Interface",
+-			QString::fromUtf8(pgrep.readAll().trimmed()).toStdString());
++	EXPECT_TRUE(
++			pgrep.readAll().contains("python3 -m dbusmock test.name /test/object test.Interface"));
+ }
+ 
+ TEST_F(TestQProcessDBusService, ThrowsErrorForFailToStart) {
+ 	QProcessDBusService process("test.name", QDBusConnection::SessionBus,
+-			"/usr/bin/python3",
++			"python3",
+ 			QStringList() << "-m" << "dbusmock" << "not.test.name"
+ 					<< "/test/object" << "test.Interface");
+ 
+diff '--color=auto' -ur '--color=never' a/tests/libqtdbustest/TestSuicidalProcess.cpp b/tests/libqtdbustest/TestSuicidalProcess.cpp
+--- a/tests/libqtdbustest/TestSuicidalProcess.cpp	2023-01-20 21:36:16.948292559 +0100
++++ b/tests/libqtdbustest/TestSuicidalProcess.cpp	2023-01-20 21:55:07.219951081 +0100
+@@ -51,9 +51,7 @@
+ 	pgrep.waitForFinished();
+ 	pgrep.waitForReadyRead();
+
+-	EXPECT_TRUE(QString::fromUtf8(pgrep.readAll().trimmed())
+-                .toStdString()
+-                .find("sleep 5") != std::string::npos);
++	EXPECT_TRUE(pgrep.readAll().contains("sleep 5"));
+ }
+ 
+ } // namespace