push sheeet

pkgs/development/libraries/librdf/raptor2.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  libxml2,
+  curl,
+  libxslt,
+  pkg-config,
+  cmake,
+  fetchFromGitHub,
+  perl,
+  bison,
+  flex,
+  fetchpatch,
+  static ? stdenv.hostPlatform.isStatic,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "raptor2";
+  version = "2.0.16";
+  underscoredVersion = lib.strings.replaceStrings [ "." ] [ "_" ] version;
+
+  src = fetchFromGitHub {
+    owner = "dajobe";
+    repo = "raptor";
+    rev = "${pname}_${underscoredVersion}";
+    sha256 = "sha256-Eic63pV2p154YkSmkqWr86fGTr+XmVGy5l5/6q14LQM=";
+  };
+
+  cmakeFlags = [
+    # Build defaults to static libraries.
+    "-DBUILD_SHARED_LIBS=${if static then "OFF" else "ON"}"
+  ];
+
+  patches = [
+    # pull upstream fix for libxml2-2.11 API compatibility, part of unreleased 2.0.17
+    #   https://github.com/dajobe/raptor/pull/58
+    (fetchpatch {
+      name = "libxml2-2.11.patch";
+      url = "https://github.com/dajobe/raptor/commit/4dbc4c1da2a033c497d84a1291c46f416a9cac51.patch";
+      hash = "sha256-fHfvncGymzMtxjwtakCNSr/Lem12UPIHAAcAac648w4=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+    perl
+    bison
+    flex
+  ];
+  buildInputs = [
+    curl
+    libxml2
+    libxslt
+  ];
+
+  # Fix the build with CMake 4.
+  #
+  # See: <https://github.com/dajobe/raptor/issues/75>
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail \
+        'CMAKE_MINIMUM_REQUIRED(VERSION 2.8.7)' \
+        'CMAKE_MINIMUM_REQUIRED(VERSION 3.10)'
+  '';
+
+  meta = {
+    description = "RDF Parser Toolkit";
+    mainProgram = "rapper";
+    homepage = "https://librdf.org/raptor";
+    license = with lib.licenses; [
+      lgpl21
+      asl20
+    ];
+    maintainers = with lib.maintainers; [ marcweber ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/development/libraries/librdf/rasqal.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  librdf_raptor2,
+  gmp,
+  pkg-config,
+  libxml2,
+  perl,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rasqal";
+  version = "0.9.33";
+
+  src = fetchurl {
+    url = "http://download.librdf.org/source/rasqal-${finalAttrs.version}.tar.gz";
+    sha256 = "0z6rrwn4jsagvarg8d5zf0j352kjgi33py39jqd29gbhcnncj939";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    gmp
+    libxml2
+  ];
+
+  propagatedBuildInputs = [ librdf_raptor2 ];
+
+  confiugureFlags = [
+    # uses 'regex.h' as a fallback, which is preferrable
+    "--disable-pcre"
+  ];
+
+  postInstall = "rm -rvf $out/share/gtk-doc";
+
+  nativeCheckInputs = [ perl ];
+  doCheck = false; # fails with "No testsuite plan file sparql-query-plan.ttl could be created in build/..."
+  doInstallCheck = false; # fails with "rasqal-config does not support (--help|--version)"
+
+  passthru.tests = {
+    # rasqal-config --version just checks the pkg-config module.
+    # That check is broken, checking the pkg-config ourselves is a good replacement.
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "Library that handles Resource Description Framework (RDF)";
+    homepage = "https://librdf.org/rasqal";
+    license = with lib.licenses; [
+      lgpl21
+      asl20
+    ];
+    maintainers = with lib.maintainers; [ marcweber ];
+    platforms = lib.platforms.unix;
+    pkgConfigModules = [ "rasqal" ];
+  };
+})

pkgs/development/libraries/librdf/redland.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  openssl,
+  libxslt,
+  perl,
+  curl,
+  libxml2,
+  librdf_rasqal,
+  gmp,
+  libmysqlclient,
+  withMysql ? false,
+  libpq,
+  withPostgresql ? false,
+  sqlite,
+  withSqlite ? true,
+  db,
+  withBdb ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "redland";
+  version = "1.0.17";
+
+  src = fetchurl {
+    url = "http://download.librdf.org/source/redland-${version}.tar.gz";
+    sha256 = "de1847f7b59021c16bdc72abb4d8e2d9187cd6124d69156f3326dd34ee043681";
+  };
+
+  nativeBuildInputs = [
+    perl
+    pkg-config
+  ]
+  ++ lib.optional withPostgresql libpq.pg_config;
+
+  buildInputs = [
+    openssl
+    libxslt
+    curl
+    libxml2
+    gmp
+  ]
+  ++ lib.optional withMysql libmysqlclient
+  ++ lib.optional withSqlite sqlite
+  ++ lib.optional withPostgresql libpq
+  ++ lib.optional withBdb db;
+
+  propagatedBuildInputs = [ librdf_rasqal ];
+
+  postInstall = "rm -rvf $out/share/gtk-doc";
+
+  configureFlags = [
+    "--with-threads"
+  ]
+  ++ lib.optionals withBdb [
+    "--with-bdb-include=${db.dev}/include"
+    "--with-bdb-lib=${db.out}/lib"
+  ];
+
+  # Fix broken DT_NEEDED in lib/redland/librdf_storage_sqlite.so.
+  NIX_CFLAGS_LINK = "-lraptor2";
+
+  doCheck = false; # fails 1 out of 17 tests with a segmentation fault
+
+  meta = with lib; {
+    description = "C libraries that provide support for the Resource Description Framework (RDF)";
+    homepage = "https://librdf.org/";
+    platforms = platforms.unix;
+    license = licenses.asl20;
+  };
+}