push sheeet

pkgs/development/libraries/libva/1.nix

@@ -0,0 +1,73 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  autoreconfHook,
+  libX11,
+  pkg-config,
+  libXext,
+  libdrm,
+  libXfixes,
+  wayland,
+  wayland-scanner,
+  libffi,
+  libGL,
+  mesa,
+  minimal ? false,
+  libva1-minimal,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libva" + lib.optionalString minimal "-minimal";
+  # nixpkgs-update: no auto update
+  version = "1.8.3";
+
+  src = fetchFromGitHub {
+    owner = "intel";
+    repo = "libva";
+    rev = version;
+    sha256 = "sha256-ur59cqdZqXIY2dDUSie9XsxyRomVBxIW2IVKAgWYC38=";
+  };
+
+  outputs = [
+    "dev"
+    "out"
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    libdrm
+  ]
+  ++ lib.optionals (!minimal) [
+    libva1-minimal
+    libX11
+    libXext
+    libXfixes
+    wayland
+    libffi
+    libGL
+  ];
+  # TODO: share libs between minimal and !minimal - perhaps just symlink them
+
+  # Add FHS paths for non-NixOS applications.
+  configureFlags =
+    lib.optionals stdenv.hostPlatform.isLinux [
+      "--with-drivers-path=${mesa.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri"
+    ]
+    ++ lib.optionals (!minimal) [ "--enable-glx" ];
+
+  installFlags = [ "dummy_drv_video_ladir=$(out)/lib/dri" ];
+
+  meta = with lib; {
+    homepage = "https://www.freedesktop.org/wiki/Software/vaapi/";
+    license = licenses.mit;
+    description = "VAAPI library: Video Acceleration API";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+  };
+}

pkgs/development/libraries/libva/default.nix

@@ -0,0 +1,120 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  meson,
+  pkg-config,
+  ninja,
+  wayland-scanner,
+  libdrm,
+  minimal ? false,
+  libX11,
+  libxcb,
+  libXext,
+  libXfixes,
+  wayland,
+  libffi,
+  libGL,
+  mesa,
+  # for passthru.tests
+  intel-compute-runtime,
+  intel-media-driver,
+  mpv,
+  intel-vaapi-driver,
+  vlc,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libva" + lib.optionalString minimal "-minimal";
+  version = "2.22.0";
+
+  src = fetchFromGitHub {
+    owner = "intel";
+    repo = "libva";
+    rev = finalAttrs.version;
+    sha256 = "sha256-0eOYxyMt2M2lkhoWOhoUQgP/1LYY3QQqSF5TdRUuCbs=";
+  };
+
+  outputs = [
+    "dev"
+    "out"
+  ];
+
+  depsBuildBuild = [ pkg-config ];
+
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja
+  ]
+  ++ lib.optional (!minimal) wayland-scanner;
+
+  buildInputs = [
+    libdrm
+  ]
+  ++ lib.optionals (!minimal) [
+    libX11
+    libxcb
+    libXext
+    libXfixes
+    wayland
+    libffi
+    libGL
+  ];
+
+  mesonFlags = lib.optionals stdenv.hostPlatform.isLinux [
+    # Add FHS and Debian paths for non-NixOS applications
+    "-Ddriverdir=${mesa.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri:/usr/lib/x86_64-linux-gnu/dri:/usr/lib/i386-linux-gnu/dri"
+  ];
+
+  env =
+    lib.optionalAttrs (stdenv.cc.bintools.isLLVM && lib.versionAtLeast stdenv.cc.bintools.version "17")
+      {
+        NIX_LDFLAGS = "--undefined-version";
+      }
+    // lib.optionalAttrs (stdenv.targetPlatform.useLLVM or false) {
+      NIX_CFLAGS_COMPILE = "-DHAVE_SECURE_GETENV";
+    };
+
+  passthru.tests = {
+    # other drivers depending on libva and selected application users.
+    # Please get a confirmation from the maintainer before adding more applications.
+    inherit
+      intel-compute-runtime
+      intel-media-driver
+      intel-vaapi-driver
+      mpv
+      vlc
+      ;
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = with lib; {
+    description = "Implementation for VA-API (Video Acceleration API)";
+    longDescription = ''
+      VA-API is an open-source library and API specification, which provides
+      access to graphics hardware acceleration capabilities for video
+      processing. It consists of a main library (this package) and
+      driver-specific acceleration backends for each supported hardware vendor.
+    '';
+    homepage = "https://01.org/linuxmedia/vaapi";
+    changelog = "https://raw.githubusercontent.com/intel/libva/${finalAttrs.version}/NEWS";
+    license = licenses.mit;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+    pkgConfigModules = [
+      "libva"
+      "libva-drm"
+    ]
+    ++ lib.optionals (!minimal) [
+      "libva-glx"
+      "libva-wayland"
+      "libva-x11"
+    ];
+    platforms = platforms.unix;
+    badPlatforms = [
+      # Mandatory libva shared library.
+      lib.systems.inspect.platformPatterns.isStatic
+    ];
+  };
+})

pkgs/development/libraries/libva/utils.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  libdrm,
+  libva,
+  libX11,
+  libXext,
+  libXfixes,
+  wayland,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libva-utils";
+  version = "2.22.0";
+
+  src = fetchFromGitHub {
+    owner = "intel";
+    repo = "libva-utils";
+    rev = version;
+    sha256 = "sha256-CmhdhNNRO2j8lH7awp9YiKWMvV17GTBsXdrNY06jT2w=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    libdrm
+    libva
+    libX11
+    libXext
+    libXfixes
+    wayland
+  ];
+
+  meta = with lib; {
+    description = "Collection of utilities and examples for VA-API";
+    longDescription = ''
+      libva-utils is a collection of utilities and examples to exercise VA-API
+      in accordance with the libva project.
+    '';
+    homepage = "https://github.com/intel/libva-utils";
+    changelog = "https://raw.githubusercontent.com/intel/libva-utils/${version}/NEWS";
+    license = licenses.mit;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+    platforms = platforms.unix;
+  };
+}