push sheeet

pkgs/development/libraries/physics/hepmc3/default.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  coreutils,
+  python,
+  root,
+}:
+
+let
+  pythonVersion = with lib.versions; "${major python.version}${minor python.version}";
+  withPython = python != null;
+  # ensure that root is built with the same python interpreter, as it links against numpy
+  root_py = if withPython then root.override { python3 = python; } else root;
+in
+
+stdenv.mkDerivation rec {
+  pname = "hepmc3";
+  version = "3.3.1";
+
+  src = fetchurl {
+    url = "http://hepmc.web.cern.ch/hepmc/releases/HepMC3-${version}.tar.gz";
+    sha256 = "sha256-CCQBYLDyjcMpOqTWHOZeLWfNWXrPb6ykOfLkZiX355M=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ]
+  ++ lib.optional withPython python.pkgs.pythonImportsCheckHook;
+
+  buildInputs = [
+    root_py
+  ]
+  ++ lib.optional withPython python;
+
+  # error: invalid version number in 'MACOSX_DEPLOYMENT_TARGET=11.0'
+  preConfigure =
+    lib.optionalString
+      (stdenv.hostPlatform.isDarwin && lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11")
+      ''
+        MACOSX_DEPLOYMENT_TARGET=10.16
+      '';
+
+  cmakeFlags = [
+    "-DHEPMC3_CXX_STANDARD=17"
+    "-DHEPMC3_ENABLE_PYTHON=${if withPython then "ON" else "OFF"}"
+  ]
+  ++ lib.optionals withPython [
+    "-DHEPMC3_PYTHON_VERSIONS=${if python.isPy3k then "3.X" else "2.X"}"
+    "-DHEPMC3_Python_SITEARCH${pythonVersion}=${placeholder "out"}/${python.sitePackages}"
+  ];
+
+  postInstall = ''
+    substituteInPlace "$out"/bin/HepMC3-config \
+      --replace-fail '$(greadlink' '$(${coreutils}/bin/readlink' \
+      --replace-fail '$(readlink' '$(${coreutils}/bin/readlink'
+  '';
+
+  pythonImportsCheck = [ "pyHepMC3" ];
+
+  meta = with lib; {
+    description = "HepMC package is an object oriented, C++ event record for High Energy Physics Monte Carlo generators and simulation";
+    mainProgram = "HepMC3-config";
+    license = licenses.gpl3;
+    homepage = "http://hepmc.web.cern.ch/hepmc/";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ veprbl ];
+  };
+}

pkgs/development/libraries/physics/pythia/default.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  boost,
+  fastjet,
+  fixDarwinDylibNames,
+  hepmc,
+  lhapdf,
+  rsync,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pythia";
+  version = "8.315";
+
+  src = fetchurl {
+    url = "https://pythia.org/download/pythia83/pythia${
+      builtins.replaceStrings [ "." ] [ "" ] version
+    }.tgz";
+    sha256 = "sha256-Sy/nNB4z6QtyJv3Koqe/kyeYezNU6EwE8f2SVoY2kK4=";
+  };
+
+  nativeBuildInputs = [ rsync ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ fixDarwinDylibNames ];
+  buildInputs = [
+    boost
+    fastjet
+    hepmc
+    zlib
+    lhapdf
+  ];
+
+  configureFlags = [
+    "--enable-shared"
+    "--with-lhapdf6=${lhapdf}"
+  ]
+  ++ (
+    if lib.versions.major hepmc.version == "3" then
+      [
+        "--with-hepmc3=${hepmc}"
+      ]
+    else
+      [
+        "--with-hepmc2=${hepmc}"
+      ]
+  );
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Program for the generation of high-energy physics events";
+    mainProgram = "pythia8-config";
+    license = licenses.gpl2Only;
+    homepage = "https://pythia.org";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ veprbl ];
+  };
+}