push sheeet

pkgs/development/libraries/sqlite/archive-version.nix

@@ -0,0 +1,9 @@
+lib: version:
+
+let
+  fragments = lib.splitVersion version;
+  major = lib.head fragments;
+  minor = lib.concatMapStrings (lib.fixedWidthNumber 2) (lib.tail fragments);
+in
+
+major + minor + "00"

pkgs/development/libraries/sqlite/default.nix

@@ -0,0 +1,158 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  zlib,
+  readline,
+  ncurses,
+
+  # for tests
+  python3Packages,
+  sqldiff,
+  sqlite-analyzer,
+  sqlite-rsync,
+  tinysparql,
+
+  # uses readline & ncurses for a better interactive experience if set to true
+  interactive ? false,
+
+  gitUpdater,
+  buildPackages,
+}:
+
+let
+  archiveVersion = import ./archive-version.nix lib;
+in
+
+stdenv.mkDerivation rec {
+  pname = "sqlite${lib.optionalString interactive "-interactive"}";
+  version = "3.50.4";
+
+  # nixpkgs-update: no auto update
+  # NB! Make sure to update ./tools.nix src (in the same directory).
+  src = fetchurl {
+    url = "https://sqlite.org/2025/sqlite-autoconf-${archiveVersion version}.tar.gz";
+    hash = "sha256-o9tYehuS7l3awvZrPttBsm+chnJ1eC1Gw6CIl31qWxg=";
+  };
+  docsrc = fetchurl {
+    url = "https://sqlite.org/2025/sqlite-doc-${archiveVersion version}.zip";
+    hash = "sha256-+KA89GFQAxDHp4XJ1vhhIayUZWAZgs3Kxt4MWYfb/C8=";
+  };
+
+  outputs = [
+    "bin"
+    "dev"
+    "man"
+    "doc"
+    "out"
+  ];
+  separateDebugInfo = stdenv.hostPlatform.isLinux;
+
+  depsBuildBuild = [
+    buildPackages.stdenv.cc
+  ];
+
+  nativeBuildInputs = [
+    unzip
+  ];
+  buildInputs = [
+    zlib
+  ]
+  ++ lib.optionals interactive [
+    readline
+    ncurses
+  ];
+
+  # required for aarch64 but applied for all arches for simplicity
+  preConfigure = ''
+    patchShebangs configure
+  '';
+
+  # sqlite relies on autosetup now; so many of the
+  # previously-understood flags are gone. They should instead be set
+  # on a per-output basis.
+  setOutputFlags = false;
+
+  configureFlags = [
+    "--bindir=${placeholder "bin"}/bin"
+    "--includedir=${placeholder "dev"}/include"
+    "--libdir=${placeholder "out"}/lib"
+  ]
+  ++ lib.optional (!interactive) "--disable-readline"
+  # autosetup only looks up readline.h in predefined set of directories.
+  ++ lib.optional interactive "--with-readline-header=${lib.getDev readline}/include/readline/readline.h"
+  ++ lib.optional (stdenv.hostPlatform.isStatic) "--disable-shared";
+
+  env.NIX_CFLAGS_COMPILE = toString [
+    "-DSQLITE_ENABLE_COLUMN_METADATA"
+    "-DSQLITE_ENABLE_DBSTAT_VTAB"
+    "-DSQLITE_ENABLE_JSON1"
+    "-DSQLITE_ENABLE_FTS3"
+    "-DSQLITE_ENABLE_FTS3_PARENTHESIS"
+    "-DSQLITE_ENABLE_FTS3_TOKENIZER"
+    "-DSQLITE_ENABLE_FTS4"
+    "-DSQLITE_ENABLE_FTS5"
+    "-DSQLITE_ENABLE_GEOPOLY"
+    "-DSQLITE_ENABLE_MATH_FUNCTIONS"
+    "-DSQLITE_ENABLE_PREUPDATE_HOOK"
+    "-DSQLITE_ENABLE_RBU"
+    "-DSQLITE_ENABLE_RTREE"
+    "-DSQLITE_ENABLE_SESSION"
+    "-DSQLITE_ENABLE_STMT_SCANSTATUS"
+    "-DSQLITE_ENABLE_UNLOCK_NOTIFY"
+    "-DSQLITE_SOUNDEX"
+    "-DSQLITE_SECURE_DELETE"
+    "-DSQLITE_MAX_VARIABLE_NUMBER=250000"
+    "-DSQLITE_MAX_EXPR_DEPTH=10000"
+  ];
+
+  # Test for features which may not be available at compile time
+  preBuild = ''
+    # Necessary for FTS5 on Linux
+    export NIX_CFLAGS_LINK="$NIX_CFLAGS_LINK -lm"
+
+    echo ""
+    echo "NIX_CFLAGS_COMPILE = $NIX_CFLAGS_COMPILE"
+    echo ""
+  '';
+
+  postInstall = ''
+    mkdir -p $doc/share/doc
+    unzip $docsrc
+    mv sqlite-doc-${archiveVersion version} $doc/share/doc/sqlite
+  '';
+
+  doCheck = false; # fails to link against tcl
+
+  passthru = {
+    tests = {
+      inherit (python3Packages) sqlalchemy;
+      inherit
+        sqldiff
+        sqlite-analyzer
+        sqlite-rsync
+        tinysparql
+        ;
+    };
+
+    updateScript = gitUpdater {
+      # No nicer place to look for latest version.
+      url = "https://github.com/sqlite/sqlite.git";
+      # Expect tags like "version-3.43.0".
+      rev-prefix = "version-";
+    };
+  };
+
+  meta = with lib; {
+    changelog = "https://www.sqlite.org/releaselog/${lib.replaceStrings [ "." ] [ "_" ] version}.html";
+    description = "Self-contained, serverless, zero-configuration, transactional SQL database engine";
+    downloadPage = "https://sqlite.org/download.html";
+    homepage = "https://www.sqlite.org/";
+    license = licenses.publicDomain;
+    mainProgram = "sqlite3";
+    maintainers = with maintainers; [ np ];
+    platforms = platforms.unix ++ platforms.windows;
+    pkgConfigModules = [ "sqlite3" ];
+  };
+}

pkgs/development/libraries/sqlite/sqlar.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fuse,
+  zlib,
+  withFuse ? true,
+}:
+
+stdenv.mkDerivation {
+  pname = "sqlar";
+  version = "2018-01-07";
+
+  src = fetchurl {
+    url = "https://www.sqlite.org/sqlar/tarball/4824e73896/sqlar-src-4824e73896.tar.gz";
+    sha256 = "09pikkbp93gqypn3da9zi0dzc47jyypkwc9vnmfzhmw7kpyv8nm9";
+  };
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace 'gcc' '${stdenv.cc.targetPrefix}cc'
+  '';
+
+  buildInputs = [ zlib ] ++ lib.optional withFuse fuse;
+
+  buildFlags = [
+    "CFLAGS=-Wno-error"
+    "sqlar"
+  ]
+  ++ lib.optional withFuse "sqlarfs";
+
+  installPhase = ''
+    install -D -t $out/bin sqlar
+  ''
+  + lib.optionalString withFuse ''
+    install -D -t $out/bin sqlarfs
+  '';
+
+  meta = with lib; {
+    homepage = "https://sqlite.org/sqlar";
+    description = "SQLite Archive utilities";
+    license = licenses.bsd2;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ dtzWill ];
+  };
+}

pkgs/development/libraries/sqlite/tools.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  sqlite,
+  tcl,
+}:
+
+let
+  archiveVersion = import ./archive-version.nix lib;
+  mkTool =
+    {
+      pname,
+      makeTarget,
+      description,
+      homepage,
+      mainProgram,
+    }:
+    stdenv.mkDerivation rec {
+      inherit pname;
+      version = "3.50.4";
+
+      # nixpkgs-update: no auto update
+      src =
+        assert version == sqlite.version;
+        fetchurl {
+          url = "https://sqlite.org/2025/sqlite-src-${archiveVersion version}.zip";
+          hash = "sha256-t7TcBg82BTkC+2WzRLu+1ZLmSyKRomrAb+d+7Al4UOk=";
+        };
+
+      nativeBuildInputs = [ unzip ];
+      buildInputs = [ tcl ];
+
+      makeFlags = [ makeTarget ];
+
+      installPhase = "install -Dt $out/bin ${makeTarget}";
+
+      meta = with lib; {
+        inherit description homepage mainProgram;
+        downloadPage = "http://sqlite.org/download.html";
+        license = licenses.publicDomain;
+        maintainers = with maintainers; [ johnazoidberg ];
+        platforms = platforms.unix;
+      };
+    };
+in
+{
+  sqldiff = mkTool {
+    pname = "sqldiff";
+    makeTarget = "sqldiff";
+    description = "Tool that displays the differences between SQLite databases";
+    homepage = "https://www.sqlite.org/sqldiff.html";
+    mainProgram = "sqldiff";
+  };
+  sqlite-analyzer = mkTool {
+    pname = "sqlite-analyzer";
+    makeTarget = "sqlite3_analyzer";
+    description = "Tool that shows statistics about SQLite databases";
+    homepage = "https://www.sqlite.org/sqlanalyze.html";
+    mainProgram = "sqlite3_analyzer";
+  };
+  sqlite-rsync = mkTool {
+    pname = "sqlite-rsync";
+    makeTarget = "sqlite3_rsync";
+    description = "Database remote-copy tool for SQLite";
+    homepage = "https://www.sqlite.org/rsync.html";
+    mainProgram = "sqlite3_rsync";
+  };
+}