push sheeet

pkgs/development/ocaml-modules/github/data.nix

@@ -0,0 +1,29 @@
+{
+  buildDunePackage,
+  github,
+  yojson,
+  atdgen,
+  atdgen-runtime,
+}:
+
+buildDunePackage {
+  pname = "github-data";
+  inherit (github) version src;
+
+  postPatch = ''
+    substituteInPlace lib_data/dune --replace-warn 'atdgen)' 'atdgen-runtime)'
+  '';
+
+  nativeBuildInputs = [
+    atdgen
+  ];
+
+  propagatedBuildInputs = [
+    yojson
+    atdgen-runtime
+  ];
+
+  meta = github.meta // {
+    description = "GitHub APIv3 data library";
+  };
+}

pkgs/development/ocaml-modules/github/default.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  buildDunePackage,
+  fetchFromGitHub,
+  uri,
+  cohttp,
+  lwt,
+  cohttp-lwt,
+  github-data,
+  yojson,
+  stringext,
+}:
+
+buildDunePackage rec {
+  pname = "github";
+  version = "4.5.0";
+
+  src = fetchFromGitHub {
+    owner = "mirage";
+    repo = "ocaml-github";
+    rev = version;
+    sha256 = "sha256-/IRoaGh4nYcdv4ir3LOS1d9UHLfWJ6DdPyFoFVCS+p4=";
+  };
+
+  duneVersion = "3";
+
+  propagatedBuildInputs = [
+    uri
+    cohttp
+    lwt
+    cohttp-lwt
+    github-data
+    yojson
+    stringext
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mirage/ocaml-github";
+    description = "GitHub APIv3 OCaml library";
+    license = licenses.mit;
+    maintainers = with maintainers; [ niols ];
+  };
+}

pkgs/development/ocaml-modules/github/jsoo.nix

@@ -0,0 +1,25 @@
+{
+  buildDunePackage,
+  github,
+  cohttp,
+  cohttp-lwt-jsoo,
+  js_of_ocaml-lwt,
+}:
+
+buildDunePackage {
+  pname = "github-jsoo";
+  inherit (github) version src;
+
+  duneVersion = "3";
+
+  propagatedBuildInputs = [
+    github
+    cohttp
+    cohttp-lwt-jsoo
+    js_of_ocaml-lwt
+  ];
+
+  meta = github.meta // {
+    description = "GitHub APIv3 JavaScript library";
+  };
+}

pkgs/development/ocaml-modules/github/unix.nix

@@ -0,0 +1,31 @@
+{
+  buildDunePackage,
+  github,
+  cohttp,
+  cohttp-lwt-unix,
+  stringext,
+  cmdliner,
+  lwt,
+}:
+
+buildDunePackage {
+  pname = "github-unix";
+  inherit (github) version src;
+
+  postPatch = ''
+    substituteInPlace unix/dune --replace 'github bytes' 'github'
+  '';
+
+  propagatedBuildInputs = [
+    github
+    cohttp
+    cohttp-lwt-unix
+    stringext
+    cmdliner
+    lwt
+  ];
+
+  meta = github.meta // {
+    description = "GitHub APIv3 Unix library";
+  };
+}