push sheeet

pkgs/development/ocaml-modules/gitlab/default.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildDunePackage,
+  fetchFromGitHub,
+  uri,
+  cohttp-lwt,
+  atdgen,
+  atdgen-runtime,
+  yojson,
+  iso8601,
+  stringext,
+}:
+
+buildDunePackage rec {
+  pname = "gitlab";
+  version = "0.1.8";
+
+  src = fetchFromGitHub {
+    owner = "tmcgilchrist";
+    repo = "ocaml-gitlab";
+    rev = version;
+    hash = "sha256-7pUpH1SoP4eW8ild5j+Tcy+aTXq0+eSkhKUOXJ6Z30k=";
+  };
+
+  postPatch = ''
+    substituteInPlace lib/dune --replace-warn 'atdgen str' 'atdgen-runtime str'
+  '';
+
+  minimalOCamlVersion = "4.08";
+
+  buildInputs = [ stringext ];
+
+  nativeBuildInputs = [ atdgen ];
+
+  propagatedBuildInputs = [
+    uri
+    cohttp-lwt
+    atdgen-runtime
+    yojson
+    iso8601
+  ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    homepage = "https://github.com/tmcgilchrist/ocaml-gitlab";
+    description = "Native OCaml bindings to Gitlab REST API v4";
+    license = licenses.bsd3;
+    changelog = "https://github.com/tmcgilchrist/ocaml-gitlab/releases/tag/${version}";
+    maintainers = with maintainers; [ zazedd ];
+  };
+}

pkgs/development/ocaml-modules/gitlab/jsoo.nix

@@ -0,0 +1,27 @@
+{
+  buildDunePackage,
+  gitlab,
+  cohttp,
+  cohttp-lwt-jsoo,
+  js_of_ocaml-lwt,
+}:
+
+buildDunePackage {
+  pname = "gitlab-jsoo";
+  inherit (gitlab) version src;
+
+  minimalOCamlVersion = "4.08";
+
+  propagatedBuildInputs = [
+    gitlab
+    cohttp
+    cohttp-lwt-jsoo
+    js_of_ocaml-lwt
+  ];
+
+  doCheck = true;
+
+  meta = gitlab.meta // {
+    description = "Gitlab APIv4 JavaScript library";
+  };
+}

pkgs/development/ocaml-modules/gitlab/unix.nix

@@ -0,0 +1,43 @@
+{
+  buildDunePackage,
+  gitlab,
+  cmdliner,
+  cohttp,
+  cohttp-lwt-unix,
+  tls,
+  lwt,
+  stringext,
+  alcotest,
+}:
+
+buildDunePackage {
+  pname = "gitlab-unix";
+  inherit (gitlab) version src;
+
+  minimalOCamlVersion = "4.08";
+
+  postPatch = ''
+    substituteInPlace unix/dune --replace-fail "gitlab bytes" "gitlab"
+  '';
+
+  buildInputs = [
+    cohttp
+    tls
+    stringext
+  ];
+
+  propagatedBuildInputs = [
+    gitlab
+    cmdliner
+    cohttp-lwt-unix
+    lwt
+  ];
+
+  checkInputs = [ alcotest ];
+
+  doCheck = true;
+
+  meta = gitlab.meta // {
+    description = "Gitlab APIv4 Unix library";
+  };
+}