push sheeet

pkgs/development/python-modules/faiss/default.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  buildPythonPackage,
+  callPackage,
+  faiss-build,
+  numpy,
+  packaging,
+  setuptools,
+  pip,
+}:
+
+buildPythonPackage {
+  inherit (faiss-build) pname version;
+  pyproject = true;
+
+  src = "${lib.getOutput "dist" faiss-build}";
+
+  postPatch = ''
+    mkdir dist
+    mv *.whl dist/
+  '';
+
+  build-system = [
+    setuptools
+    pip
+  ];
+
+  dependencies = [
+    numpy
+    packaging
+  ];
+
+  # E.g. cuda libraries; needed because reference scanning
+  # can't see inside the wheels
+  inherit (faiss-build) buildInputs;
+
+  dontBuild = true;
+
+  pythonImportsCheck = [ "faiss" ];
+
+  passthru = {
+    inherit (faiss-build) cudaSupport cudaPackages pythonSupport;
+
+    tests = {
+      pytest = callPackage ./pytest.nix { inherit faiss-build; };
+    };
+  };
+
+  meta = lib.pipe (faiss-build.meta or { }) [
+    (lib.flip removeAttrs [ "mainProgram" ])
+    (m: m // { description = "Bindings for faiss, the similarity search library"; })
+  ];
+}

pkgs/development/python-modules/faiss/pytest.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  buildPythonPackage,
+  faiss,
+  faiss-build,
+  scipy,
+  pytestCheckHook,
+}:
+
+assert faiss.pythonSupport;
+
+buildPythonPackage {
+  pname = "faiss-pytest-suite";
+  inherit (faiss) version;
+
+  format = "other";
+
+  src = "${faiss-build.src}/tests";
+
+  dontBuild = true;
+  dontInstall = true;
+
+  # Tests that need GPUs and would fail in the sandbox
+  disabledTestPaths = lib.optionals faiss.cudaSupport [ "test_contrib.py" ];
+
+  disabledTests = [
+    # https://github.com/facebookresearch/faiss/issues/2836
+    "test_update_codebooks_with_double"
+  ];
+
+  nativeCheckInputs = [
+    faiss
+    pytestCheckHook
+    scipy
+  ];
+
+  meta = faiss.meta // {
+    description = "Faiss test suite";
+  };
+}