push sheeet

pkgs/development/python-modules/imageio-ffmpeg/default.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  replaceVars,
+  ffmpeg,
+
+  # build-system
+  setuptools,
+
+  # checks
+  psutil,
+  pytestCheckHook,
+  python,
+}:
+
+buildPythonPackage rec {
+  pname = "imageio-ffmpeg";
+  version = "0.6.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "imageio";
+    repo = "imageio-ffmpeg";
+    tag = "v${version}";
+    hash = "sha256-Yy2PTNBGPP/BAR7CZck/9qr2g/s4ntiuydqXz77hR7E=";
+  };
+
+  patches = [
+    (replaceVars ./ffmpeg-path.patch {
+      ffmpeg = lib.getExe ffmpeg;
+    })
+  ];
+
+  build-system = [ setuptools ];
+
+  nativeCheckInputs = [
+    psutil
+    pytestCheckHook
+  ];
+
+  disabledTestPaths = [
+    # network access
+    "tests/test_io.py"
+    "tests/test_special.py"
+    "tests/test_terminate.py"
+  ];
+
+  postCheck = ''
+    ${python.interpreter} << EOF
+    from imageio_ffmpeg import get_ffmpeg_version
+    assert get_ffmpeg_version() == '${ffmpeg.version}'
+    EOF
+  '';
+
+  pythonImportsCheck = [ "imageio_ffmpeg" ];
+
+  meta = with lib; {
+    changelog = "https://github.com/imageio/imageio-ffmpeg/releases/tag/${src.tag}";
+    description = "FFMPEG wrapper for Python";
+    homepage = "https://github.com/imageio/imageio-ffmpeg";
+    license = licenses.bsd2;
+    maintainers = [ maintainers.pmiddend ];
+  };
+}

pkgs/development/python-modules/imageio-ffmpeg/ffmpeg-path.patch

@@ -0,0 +1,32 @@
+--- a/imageio_ffmpeg/_utils.py
++++ b/imageio_ffmpeg/_utils.py
+@@ -38,28 +38,7 @@ def get_ffmpeg_exe():
+ 
+ @lru_cache()
+ def _get_ffmpeg_exe():
+-    plat = get_platform()
+-
+-    # 2. Try from here
+-    exe = os.path.join(_get_bin_dir(), FNAME_PER_PLATFORM.get(plat, ""))
+-    if exe and os.path.isfile(exe) and _is_valid_exe(exe):
+-        return exe
+-
+-    # 3. Try binary from conda package
+-    # (installed e.g. via `conda install ffmpeg -c conda-forge`)
+-    if plat.startswith("win"):
+-        exe = os.path.join(sys.prefix, "Library", "bin", "ffmpeg.exe")
+-    else:
+-        exe = os.path.join(sys.prefix, "bin", "ffmpeg")
+-    if exe and os.path.isfile(exe) and _is_valid_exe(exe):
+-        return exe
+-
+-    # 4. Try system ffmpeg command
+-    exe = "ffmpeg"
+-    if _is_valid_exe(exe):
+-        return exe
+-
+-    return None
++    return "@ffmpeg@"
+ 
+ 
+ def _get_bin_dir():