push sheeet

pkgs/development/python-modules/ipykernel/default.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  callPackage,
+  fetchPypi,
+  hatchling,
+  pythonOlder,
+  appnope,
+  comm,
+  ipython,
+  jupyter-client,
+  jupyter-core,
+  matplotlib-inline,
+  nest-asyncio,
+  packaging,
+  psutil,
+  pyzmq,
+  tornado,
+  traitlets,
+
+  # Reverse dependency
+  sage,
+}:
+
+buildPythonPackage rec {
+  pname = "ipykernel";
+  version = "6.30.1";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-arsnAWGJZALna5E5T83OXRvl1F9FZnHlCAVy+FBb45s=";
+  };
+
+  # debugpy is optional, see https://github.com/ipython/ipykernel/pull/767
+  pythonRemoveDeps = [ "debugpy" ];
+
+  nativeBuildInputs = [ hatchling ];
+
+  propagatedBuildInputs = [
+    comm
+    ipython
+    jupyter-client
+    jupyter-core
+    matplotlib-inline
+    nest-asyncio
+    packaging
+    psutil
+    pyzmq
+    tornado
+    traitlets
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [ appnope ];
+
+  # check in passthru.tests.pytest to escape infinite recursion with ipyparallel
+  doCheck = false;
+
+  passthru.tests = {
+    pytest = callPackage ./tests.nix { };
+    inherit sage;
+  };
+
+  meta = {
+    description = "IPython Kernel for Jupyter";
+    homepage = "https://ipython.org/";
+    changelog = "https://github.com/ipython/ipykernel/releases/tag/v${version}";
+    license = lib.licenses.bsd3;
+    teams = [ lib.teams.jupyter ];
+  };
+}

pkgs/development/python-modules/ipykernel/tests.nix

@@ -0,0 +1,74 @@
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  pythonOlder,
+  flaky,
+  ipykernel,
+  ipyparallel,
+  pre-commit,
+  pytestCheckHook,
+  pytest-asyncio,
+  pytest-timeout,
+}:
+
+buildPythonPackage {
+  pname = "ipykernel-tests";
+  inherit (ipykernel) version src;
+  format = "other";
+
+  dontBuild = true;
+  dontInstall = true;
+
+  nativeCheckInputs = [
+    flaky
+    ipykernel
+    ipyparallel
+    pre-commit
+    pytestCheckHook
+    pytest-asyncio
+    pytest-timeout
+  ];
+
+  preCheck = ''
+    export HOME=$(mktemp -d)
+  '';
+
+  disabledTests = [
+    # The following three tests fail for unclear reasons.
+    # pytest.PytestUnhandledThreadExceptionWarning: Exception in thread Thread-8
+    "test_asyncio_interrupt"
+
+    # DeprecationWarning: Passing unrecognized arguments to super(IPythonKernel)
+    "test_embed_kernel_func"
+
+    # traitlets.config.configurable.MultipleInstanceError: An incompatible siblin...
+    "test_install_kernelspec"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin (
+    [
+      # see https://github.com/NixOS/nixpkgs/issues/76197
+      "test_subprocess_print"
+      "test_subprocess_error"
+      "test_ipython_start_kernel_no_userns"
+
+      # https://github.com/ipython/ipykernel/issues/506
+      "test_unc_paths"
+    ]
+    ++ lib.optionals (pythonOlder "3.8") [
+      # flaky test https://github.com/ipython/ipykernel/issues/485
+      "test_shutdown"
+
+      # test regression https://github.com/ipython/ipykernel/issues/486
+      "test_sys_path_profile_dir"
+      "test_save_history"
+      "test_help_output"
+      "test_write_kernel_spec"
+      "test_ipython_start_kernel_userns"
+      "ZMQDisplayPublisherTests"
+    ]
+  );
+
+  # Some of the tests use localhost networking.
+  __darwinAllowLocalNetworking = true;
+}