push sheeet

pkgs/development/python-modules/molecule/default.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  ansible-compat,
+  ansible-core,
+  buildPythonPackage,
+  click-help-colors,
+  enrich,
+  fetchPypi,
+  jsonschema,
+  molecule,
+  packaging,
+  pluggy,
+  pythonOlder,
+  rich,
+  setuptools,
+  setuptools-scm,
+  testers,
+  wcmatch,
+  withPlugins ? true,
+  molecule-plugins,
+  yamllint,
+}:
+
+buildPythonPackage rec {
+  pname = "molecule";
+  version = "25.9.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.10";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-GlbSg7H7VIhDnqyUWXHb1mt3LtQ7LGandpIsuT05+/0=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    setuptools-scm
+  ];
+
+  propagatedBuildInputs = [
+    ansible-compat
+    ansible-core
+    click-help-colors
+    enrich
+    jsonschema
+    packaging
+    pluggy
+    rich
+    yamllint
+    wcmatch
+  ]
+  ++ lib.optional withPlugins molecule-plugins;
+
+  pythonImportsCheck = [ "molecule" ];
+
+  # tests can't be easily run without installing things from ansible-galaxy
+  doCheck = false;
+
+  passthru.tests.version =
+    (testers.testVersion {
+      package = molecule;
+      command = "PY_COLORS=0 ${pname} --version";
+    }).overrideAttrs
+      (old: {
+        # workaround the error: Permission denied: '/homeless-shelter'
+        HOME = "$(mktemp -d)";
+      });
+
+  meta = with lib; {
+    description = "Aids in the development and testing of Ansible roles";
+    homepage = "https://github.com/ansible-community/molecule";
+    changelog = "https://github.com/ansible/molecule/releases/tag/v${version}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ dawidd6 ];
+    mainProgram = "molecule";
+  };
+}

pkgs/development/python-modules/molecule/plugins.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  setuptools-scm,
+  python-vagrant,
+  docker,
+}:
+
+buildPythonPackage rec {
+  pname = "molecule-plugins";
+  version = "23.5.3";
+  format = "pyproject";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-orFDfVMtc24/vG23pp7FM+IzSyEV/5JFoLJ3LtlzjSM=";
+  };
+
+  # reverse the dependency
+  pythonRemoveDeps = [ "molecule" ];
+
+  nativeBuildInputs = [
+    setuptools-scm
+  ];
+
+  optional-dependencies = {
+    docker = [ docker ];
+    vagrant = [ python-vagrant ];
+  };
+
+  pythonImportsCheck = [ "molecule_plugins" ];
+
+  # Tests require container runtimes
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Collection on molecule plugins";
+    homepage = "https://github.com/ansible-community/molecule-plugins";
+    maintainers = with maintainers; [ dawidd6 ];
+    license = licenses.mit;
+  };
+}