push sheeet

pkgs/development/python-modules/mss/default.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  pythonOlder,
+  stdenv,
+  replaceVars,
+
+  # build-system
+  hatchling,
+
+  # native dependencies
+  xorg,
+
+  # tests
+  lsof,
+  pillow,
+  pytest-cov-stub,
+  pytest,
+  pyvirtualdisplay,
+  xvfb-run,
+}:
+
+buildPythonPackage rec {
+  pname = "mss";
+  version = "10.1.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.6";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-cYK69+4WylaeKAQCi2q5vL9r5cRvwogIQPM7UTuctPg=";
+  };
+
+  patches = lib.optionals stdenv.hostPlatform.isLinux [
+    (replaceVars ./linux-paths.patch {
+      x11 = "${xorg.libX11}/lib/libX11.so";
+      xfixes = "${xorg.libXfixes}/lib/libXfixes.so";
+      xrandr = "${xorg.libXrandr}/lib/libXrandr.so";
+    })
+  ];
+
+  build-system = [ hatchling ];
+
+  doCheck = stdenv.hostPlatform.isLinux;
+
+  nativeCheckInputs = [
+    lsof
+    pillow
+    pytest-cov-stub
+    pytest
+    pyvirtualdisplay
+    xvfb-run
+  ];
+
+  checkPhase = ''
+    runHook preCheck
+    xvfb-run pytest -k "not test_grab_with_tuple and not test_grab_with_tuple_percents and not test_resource_leaks"
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "mss" ];
+
+  meta = with lib; {
+    description = "Cross-platform multiple screenshots module";
+    mainProgram = "mss";
+    homepage = "https://github.com/BoboTiG/python-mss";
+    changelog = "https://github.com/BoboTiG/python-mss/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ austinbutler ];
+  };
+}

pkgs/development/python-modules/mss/linux-paths.patch

@@ -0,0 +1,17 @@
+diff --git a/src/mss/linux.py b/src/mss/linux.py
+index 6dac52b..c90bd93 100644
+--- a/src/mss/linux.py
++++ b/src/mss/linux.py
+@@ -185,9 +185,9 @@ class XWindowAttributes(Structure):
+ 
+ 
+ _ERROR = {}
+-_X11 = find_library("X11")
+-_XFIXES = find_library("Xfixes")
+-_XRANDR = find_library("Xrandr")
++_X11 = "@x11@"
++_XFIXES = "@xfixes@"
++_XRANDR = "@xrandr@"
+ 
+ 
+ @CFUNCTYPE(c_int, POINTER(Display), POINTER(XErrorEvent))