push sheeet

pkgs/development/python-modules/paddlepaddle/binary-hashes.nix

@@ -0,0 +1,34 @@
+{
+  x86_64-linux = {
+    platform = "manylinux1_x86_64";
+    cpu = {
+      cp312 = "sha256-gafFsQFQsHUh0c0Ukdyh+3b/YhsU2xDomdlZ86d5Neo=";
+      cp313 = "sha256-j8SGXv02Vu6ZQkEkeSy4imQhUbTVkafW1KXGr9rpWVk=";
+    };
+    gpu = {
+      cp311 = "sha256-KWlGhjg9k1+wlm3Tk/mvMqh9LWZ0yGA1g99bCPlFf0U=";
+      cp312 = "sha256-KJ2drJWLuwdaYsCj7egh1nQV4j35vT+UgH0qTdxoyHk=";
+    };
+  };
+  aarch64-linux = {
+    platform = "manylinux2014_aarch64";
+    cpu = {
+      cp312 = "sha256-3aqZaosKANvkJp2iHWUFKHfsNpOiLswHucraPs0RaIY=";
+      cp313 = "sha256-u8TVc7NdJKJi4C1yaW6A9bSu5B9phnGvlXTe6xqD5vc=";
+    };
+  };
+  x86_64-darwin = {
+    platform = "macosx_10_9_x86_64";
+    cpu = {
+      cp312 = "sha256-3P6/sQ3rFaoz0qLWbVoS2d5lRh2KQNJofi+zIhFQ0Lo=";
+      cp313 = "sha256-UsQB/+Sq5WMWZgozAVpv11XNoj09cKKLE7c9cMvbuMs=";
+    };
+  };
+  aarch64-darwin = {
+    platform = "macosx_11_0_arm64";
+    cpu = {
+      cp312 = "sha256-hnfo1C/2b3T7yjL/Mti2S749Vu0pqS1D3EGPDxaPy2k=";
+      cp313 = "sha256-nRBR8uII2h1Dna7nyGG8tQJA8JcSSW62Hpzoxhj68vk=";
+    };
+  };
+}

pkgs/development/python-modules/paddlepaddle/default.nix

@@ -0,0 +1,127 @@
+{
+  config,
+  lib,
+  stdenv,
+  buildPythonPackage,
+  fetchPypi,
+  python,
+  pythonOlder,
+  pythonAtLeast,
+  zlib,
+  setuptools,
+  cudaSupport ? config.cudaSupport or false,
+  cudaPackages,
+  addDriverRunpath,
+  # runtime dependencies
+  httpx,
+  numpy,
+  protobuf,
+  pillow,
+  decorator,
+  astor,
+  opt-einsum,
+  typing-extensions,
+}:
+
+let
+  pname = "paddlepaddle" + lib.optionalString cudaSupport "-gpu";
+  version = if cudaSupport then "2.6.2" else "3.0.0";
+  format = "wheel";
+  pyShortVersion = "cp${builtins.replaceStrings [ "." ] [ "" ] python.pythonVersion}";
+  cpuOrGpu = if cudaSupport then "gpu" else "cpu";
+  allHashAndPlatform = import ./binary-hashes.nix;
+  hash =
+    allHashAndPlatform."${stdenv.hostPlatform.system}"."${cpuOrGpu}"."${pyShortVersion}"
+      or (throw "${pname} has no binary-hashes.nix entry for '${stdenv.hostPlatform.system}.${cpuOrGpu}.${pyShortVersion}' attribute");
+  platform = allHashAndPlatform."${stdenv.hostPlatform.system}".platform;
+  src = fetchPypi {
+    inherit
+      version
+      format
+      hash
+      platform
+      ;
+    pname = builtins.replaceStrings [ "-" ] [ "_" ] pname;
+    dist = pyShortVersion;
+    python = pyShortVersion;
+    abi = pyShortVersion;
+  };
+in
+buildPythonPackage {
+  inherit
+    pname
+    version
+    format
+    src
+    ;
+
+  disabled =
+    if cudaSupport then
+      (pythonOlder "3.11" || pythonAtLeast "3.13")
+    else
+      (pythonOlder "3.12" || pythonAtLeast "3.14");
+
+  nativeBuildInputs = [ addDriverRunpath ];
+
+  dependencies = [
+    setuptools
+    httpx
+    numpy
+    protobuf
+    pillow
+    decorator
+    astor
+    opt-einsum
+    typing-extensions
+  ];
+
+  pythonImportsCheck = [ "paddle" ];
+
+  # no tests
+  doCheck = false;
+
+  postFixup = lib.optionalString stdenv.hostPlatform.isLinux (
+    let
+      libraryPath = lib.makeLibraryPath (
+        [
+          zlib
+          (lib.getLib stdenv.cc.cc)
+        ]
+        ++ lib.optionals cudaSupport (
+          with cudaPackages;
+          [
+            cudatoolkit.lib
+            cudatoolkit.out
+            cudnn
+          ]
+        )
+      );
+    in
+    ''
+      function fixRunPath {
+        p=$(patchelf --print-rpath $1)
+        patchelf --set-rpath "$p:${libraryPath}" $1
+        ${lib.optionalString cudaSupport ''
+          addDriverRunpath $1
+        ''}
+      }
+      fixRunPath $out/${python.sitePackages}/paddle/base/libpaddle.so
+      fixRunPath $out/${python.sitePackages}/paddle/libs/lib*.so
+    ''
+  );
+
+  meta = {
+    description = "Machine Learning Framework from Industrial Practice";
+    homepage = "https://github.com/PaddlePaddle/Paddle";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ happysalada ];
+    platforms = [
+      "x86_64-linux"
+    ]
+    ++ lib.optionals (!cudaSupport) [
+      "aarch64-linux"
+      "x86_64-darwin"
+      "aarch64-darwin"
+    ];
+  };
+}