push sheeet

pkgs/development/python-modules/pbr/default.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  buildPythonPackage,
+  callPackage,
+  distutils,
+  fetchPypi,
+  setuptools,
+}:
+
+buildPythonPackage rec {
+  pname = "pbr";
+  version = "7.0.1";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-PsvLEdK4VRWI7IFrN1ax60OUGGw7aJsX4EhQ38IPflc=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    distutils # for distutils.command in pbr/packaging.py
+    setuptools # for pkg_resources
+  ];
+
+  # check in passthru.tests.pytest to escape infinite recursion with fixtures
+  doCheck = false;
+
+  passthru.tests = {
+    tests = callPackage ./tests.nix { };
+  };
+
+  pythonImportsCheck = [ "pbr" ];
+
+  meta = with lib; {
+    description = "Python Build Reasonableness";
+    mainProgram = "pbr";
+    homepage = "https://github.com/openstack/pbr";
+    license = licenses.asl20;
+    teams = [ teams.openstack ];
+  };
+}

pkgs/development/python-modules/pbr/tests.nix

@@ -0,0 +1,54 @@
+{
+  buildPythonPackage,
+  build,
+  git,
+  gnupg,
+  pbr,
+  sphinx,
+  stestr,
+  testresources,
+  testscenarios,
+  virtualenv,
+}:
+
+buildPythonPackage {
+  pname = "pbr";
+  inherit (pbr) version src;
+  format = "other";
+
+  postPatch = ''
+    # only a small portion of the listed packages are actually needed for running the tests
+    # so instead of removing them one by one remove everything
+    rm test-requirements.txt
+  '';
+
+  dontBuild = true;
+  dontInstall = true;
+  preConfigure = ''
+    pythonOutputDistPhase() { touch $dist; }
+  '';
+
+  nativeCheckInputs = [
+    pbr
+    build
+    git
+    gnupg
+    sphinx
+    stestr
+    testresources
+    testscenarios
+    virtualenv
+  ];
+
+  checkPhase = ''
+    stestr run -e <(echo "
+    pbr.tests.test_core.TestCore.test_console_script_develop
+    pbr.tests.functional.test_console_scripts.TestConsoleScripts.test_console_script_install
+    pbr.tests.functional.test_wsgi_scripts.TestWsgiScripts.test_with_argument
+    pbr.tests.functional.test_wsgi_scripts.TestWsgiScripts.test_wsgi_script_run
+    # Tests are failing because of fixture timeouts
+    pbr.tests.functional.test_pep517.TestPEP517Support.test_pep_517_support
+    pbr.tests.functional.test_requirements.TestRequirementParsing.test_requirement_parsing
+    ")
+  '';
+}