push sheeet

pkgs/development/tcl-modules/by-name/tc/tcl-fcgi/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  fetchFromGitHub,
+  mkTclDerivation,
+  tclx,
+}:
+
+mkTclDerivation {
+  pname = "tcl-fcgi";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "mpcjanssen";
+    repo = "tcl-fcgi";
+    rev = "62452dbf3177ba9458fbb42457834ca77bdf5a82";
+    sha256 = "sha256-RLuV4ARmGWCJTmhs7DbMWENQGj3d5ZXWb821WrgG0qA=";
+  };
+
+  buildInputs = [
+    tclx
+  ];
+
+  unpackPhase = ''
+    mkdir -p $out/lib/tcl-fcgi
+    cp -r $src/tcl-src/* $out/lib/tcl-fcgi/
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/mpcjanssen/tcl-fcgi";
+    description = "Tcl interface for the FastCGI protocol";
+    license = licenses.bsd2;
+    platforms = tclx.meta.platforms;
+    maintainers = with maintainers; [ nat-418 ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tclcurl/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  mkTclDerivation,
+  fetchFromGitHub,
+  curl,
+}:
+
+mkTclDerivation rec {
+  pname = "tclcurl";
+  version = "7.22.1";
+
+  src = fetchFromGitHub {
+    owner = "flightaware";
+    repo = "tclcurl-fa";
+    tag = "v${version}";
+    hash = "sha256-XQuP+SiqvGX3ckBShUxsGBADjV3QdvYpU4hW6LMbMMQ=";
+  };
+
+  buildInputs = [ curl ];
+
+  # Uses curl-config
+  strictDeps = false;
+
+  makeFlags = [ "LDFLAGS=-lcurl" ];
+
+  meta = {
+    description = "Curl support in Tcl";
+    homepage = "https://github.com/flightaware/tclcurl-fa";
+    changelog = "https://github.com/flightaware/tclcurl-fa/blob/master/ChangeLog.txt";
+    license = lib.licenses.tcltk;
+    maintainers = with lib.maintainers; [ fgaz ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tcllib/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  fetchzip,
+  mkTclDerivation,
+  critcl,
+  withCritcl ? true,
+}:
+
+mkTclDerivation rec {
+  pname = "tcllib";
+  version = "2.0";
+
+  src = fetchzip {
+    url = "mirror://sourceforge/tcllib/tcllib-${version}.tar.gz";
+    hash = "sha256-LoY6y7p9n1dXk4eSa/HuyA4bIXa0rN7F2OGESk2tROI=";
+  };
+
+  nativeBuildInputs = lib.optional withCritcl critcl;
+
+  buildFlags = [ "all" ] ++ lib.optional withCritcl "critcl";
+
+  meta = {
+    homepage = "https://core.tcl-lang.org/tcllib/";
+    description = "Tcl-only library of standard routines for Tcl";
+    license = lib.licenses.tcltk;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ fgaz ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tclmagick/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  mkTclDerivation,
+  fetchzip,
+  graphicsmagick,
+  tk,
+}:
+
+mkTclDerivation rec {
+  pname = "tclmagick";
+  version = "1.3.43";
+
+  src = fetchzip {
+    url = "mirror://sourceforge/graphicsmagick/GraphicsMagick-${version}.tar.xz";
+    hash = "sha256-CpZztiBF0HqH4XWIAyE9IbZVpBcgrDzyASv47wTneQ0=";
+  };
+
+  sourceRoot = src.name + "/TclMagick";
+
+  buildInputs = [
+    graphicsmagick
+    tk
+  ];
+
+  configureFlags = [
+    "--with-tk=${lib.getLib tk}/lib"
+    "--with-tkinclude=${lib.getDev tk}/include"
+  ];
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Tcl and Tk Interfaces to GraphicsMagick and ImageMagick";
+    homepage = "http://www.graphicsmagick.org/TclMagick/doc/";
+    license = lib.licenses.tcltk;
+    maintainers = with lib.maintainers; [ fgaz ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tclreadline/package.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  automake,
+  autoconf,
+  libtool,
+  readline,
+  mkTclDerivation,
+  tk,
+}:
+
+mkTclDerivation rec {
+  pname = "tclreadline";
+  version = "2.4.1";
+
+  src = fetchFromGitHub {
+    owner = "flightaware";
+    repo = "tclreadline";
+    rev = "v${version}";
+    sha256 = "sha256-6FIQJsAm28jPIfNG+7xsMlCJSLw9JStOVzDemw2P+EI=";
+  };
+
+  nativeBuildInputs = [
+    automake
+    autoconf
+    libtool
+  ];
+  buildInputs = [
+    readline
+    tk
+  ];
+
+  preConfigure = "NOCONFIGURE=1 ./autogen.sh";
+
+  configureFlags = [
+    "--enable-tclshrl"
+    "--enable-wishrl"
+    "--with-tk=${tk}/lib"
+    "--with-readline-includes=${readline.dev}/include/readline"
+    "--with-libtool=${libtool}"
+  ];
+
+  # The provided makefile leaves a wrong reference to /build/ in RPATH,
+  # so we fix it after checking that everything is also present in $out
+  preFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
+    needed_libraries=$(ls .libs | grep '\.\(so\|la\)$')
+    for lib in $needed_libraries; do
+      if ! ls $out/lib | grep "$lib"; then
+        echo "$lib was not installed correctly"
+        exit 1
+      fi
+    done
+    for executable in $out/bin/{wishrl,tclshrl}; do
+      patchelf --set-rpath \
+        "$(patchelf --print-rpath "$executable" | sed "s@$builddir/.libs@$out/lib@")" \
+        "$executable"
+    done
+  '';
+
+  meta = with lib; {
+    description = "GNU readline for interactive tcl shells";
+    homepage = "https://github.com/flightaware/tclreadline";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ fgaz ];
+    platforms = platforms.all;
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tcltls/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  fetchurl,
+  mkTclDerivation,
+  openssl,
+}:
+
+mkTclDerivation rec {
+  pname = "tcltls";
+  version = "1.7.22";
+
+  src = fetchurl {
+    url = "https://core.tcl-lang.org/tcltls/uv/tcltls-${version}.tar.gz";
+    sha256 = "sha256-6E4reideyCxKqp0bH5eG2+Q1jIFekXU5/+f2Z/9Lw7Q=";
+  };
+
+  buildInputs = [ openssl ];
+
+  configureFlags = [
+    "--with-ssl-dir=${openssl.dev}"
+  ];
+
+  meta = {
+    homepage = "https://core.tcl-lang.org/tcltls/index";
+    description = "OpenSSL / RSA-bsafe Tcl extension";
+    maintainers = [ lib.maintainers.agbrooks ];
+    license = lib.licenses.tcltk;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tcludp/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  mkTclDerivation,
+  fetchfossil,
+}:
+
+mkTclDerivation rec {
+  pname = "tcludp";
+  version = "1.0.11";
+
+  src = fetchfossil {
+    url = "https://core.tcl-lang.org/tcludp";
+    rev = "ver_" + lib.replaceStrings [ "." ] [ "_" ] version;
+    hash = "sha256-PckGwUqL2r5KJEet8sS4U504G63flX84EkQEkQdMifY=";
+  };
+
+  # Add missing pkgIndex.tcl.in
+  postPatch = ''
+    test ! -e pkgIndex.tcl.in
+    cat > pkgIndex.tcl.in <<EOF
+    package ifneeded @PACKAGE_NAME@ @PACKAGE_VERSION@ \
+    [list load [file join $dir @PKG_LIB_FILE@] @PACKAGE_NAME@]
+    EOF
+  '';
+
+  # Some tests fail because of the sandbox.
+  # However, tcltest always returns exit code 0, so this always succeeds.
+  # https://wuhrr.wordpress.com/2013/09/13/tcltest-part-9-provides-exit-code/
+  doInstallCheck = true;
+
+  installCheckTarget = "test";
+
+  meta = {
+    description = "UDP socket support for Tcl";
+    homepage = "https://core.tcl-lang.org/tcludp";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fgaz ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tclvfs/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  mkTclDerivation,
+  fetchzip,
+}:
+
+mkTclDerivation {
+  pname = "tclvfs";
+  version = "1.4-unstable-2023-11-23";
+
+  src = fetchzip {
+    url = "https://core.tcl-lang.org/tclvfs/tarball/8cdab08997fe82d8/tclvfs-8cdab08997fe82d8.tar.gz";
+    hash = "sha256-DzZ4Puwscbr0KarMyEKeah7jDJy7cfKNBbBSh0boaUw=";
+  };
+
+  meta = {
+    description = "Tcl extension that exposes Tcl's Virtual File System (VFS) subsystem to the script level";
+    homepage = "https://core.tcl.tk/tclvfs";
+    license = lib.licenses.tcltk;
+    longDescription = ''
+      The TclVfs project aims to provide an extension to the Tcl language which
+      allows Virtual Filesystems to be built using Tcl scripts only. It is also
+      a repository of such Tcl-implemented filesystems (metakit, zip, ftp, tar,
+      http, webdav, namespace, url)
+    '';
+    maintainers = with lib.maintainers; [ fgaz ];
+  };
+}

pkgs/development/tcl-modules/by-name/tc/tclx/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  fetchFromGitHub,
+  mkTclDerivation,
+}:
+
+mkTclDerivation rec {
+  pname = "tclx";
+  version = "8.6.3";
+
+  src = fetchFromGitHub {
+    owner = "flightaware";
+    repo = "tclx";
+    rev = "v${version}";
+    hash = "sha256-bzLF6qOF9o24joWnGR7B4S+Doj7zv9iTh/mo50iFbUs=";
+  };
+
+  # required in order for tclx to properly detect tclx.tcl at runtime
+  postInstall =
+    let
+      majorMinorVersion = lib.versions.majorMinor version;
+    in
+    ''
+      ln -s $prefix/lib/tclx${majorMinorVersion} $prefix/lib/tclx${majorMinorVersion}/tclx${majorMinorVersion}
+    '';
+
+  meta = {
+    homepage = "https://github.com/flightaware/tclx";
+    description = "Tcl extensions";
+    license = lib.licenses.tcltk;
+    maintainers = with lib.maintainers; [
+      kovirobi
+      fgaz
+    ];
+  };
+}