push sheeet

pkgs/development/tools/prospector/default.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3,
+}:
+
+let
+  setoptconf-tmp = python3.pkgs.callPackage ./setoptconf.nix { };
+in
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "prospector";
+  version = "1.9.0";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "PyCQA";
+    repo = pname;
+    rev = "refs/tags/v${version}";
+    hash = "sha256-94JGKX91d2kul+KMYohga9KCOj6RN/YKpD8e4nWSOOM=";
+  };
+
+  pythonRelaxDeps = [
+    "pyflakes"
+    "pep8-naming"
+    "flake8"
+  ];
+
+  nativeBuildInputs = with python3.pkgs; [
+    poetry-core
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    bandit
+    dodgy
+    flake8
+    gitpython
+    mccabe
+    mypy
+    pep8-naming
+    pycodestyle
+    pydocstyle
+    pyflakes
+    pylint
+    pylint-celery
+    pylint-django
+    pylint-flask
+    pylint-plugin-utils
+    pyroma
+    pyyaml
+    requirements-detector
+    setoptconf-tmp
+    setuptools
+    toml
+    vulture
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "prospector"
+  ];
+
+  disabledTestPaths = [
+    # distutils.errors.DistutilsArgError: no commands supplied
+    "tests/tools/pyroma/test_pyroma_tool.py"
+  ];
+
+  meta = with lib; {
+    description = "Tool to analyse Python code and output information about errors, potential problems, convention violations and complexity";
+    homepage = "https://github.com/PyCQA/prospector";
+    changelog = "https://github.com/PyCQA/prospector/blob/v${version}/CHANGELOG.rst";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ kamadorueda ];
+  };
+}

pkgs/development/tools/prospector/setoptconf.nix

@@ -0,0 +1,28 @@
+{
+  buildPythonPackage,
+  fetchPypi,
+  lib,
+}:
+
+buildPythonPackage rec {
+  pname = "setoptconf-tmp";
+  version = "0.3.1";
+  format = "setuptools";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0y2pgpraa36wzlzkxigvmz80mqd3mzcc9wv2yx9bliqks7fhlj70";
+  };
+
+  # Base tests provided via PyPi are broken
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://pypi.org/project/setoptconf-tmp";
+    description = "Module for retrieving program settings from various sources in a consistant method";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      kamadorueda
+    ];
+  };
+}