push sheeet

pkgs/games/fteqw/default.nix

@@ -0,0 +1,102 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gzip,
+  libvorbis,
+  libmad,
+  SDL2,
+  SDL2_mixer,
+  libpng,
+  alsa-lib,
+  gnutls,
+  zlib,
+  libjpeg,
+  vulkan-loader,
+  vulkan-headers,
+  speex,
+  libopus,
+  xorg,
+  libGL,
+}@attrs:
+{
+  fteqw = import ./generic.nix (
+    rec {
+      pname = "fteqw";
+
+      buildFlags = [ "m-rel" ];
+
+      nativeBuildInputs = [
+        vulkan-headers
+      ];
+
+      buildInputs = [
+        gzip
+        libvorbis
+        libmad
+        SDL2
+        SDL2_mixer
+        libGL
+        libpng
+        alsa-lib
+        gnutls
+        libjpeg
+        vulkan-loader
+        speex
+        libopus
+        xorg.libXrandr
+        xorg.libXcursor
+        xorg.libXScrnSaver
+      ];
+
+      postFixup = ''
+        patchelf $out/bin/${pname} \
+          --add-needed ${SDL2}/lib/libSDL2.so \
+          --add-needed ${libGL}/lib/libGLX.so \
+          --add-needed ${libGL}/lib/libGL.so \
+          --add-needed ${lib.getLib gnutls}/lib/libgnutls.so \
+          --add-needed ${vulkan-loader}/lib/libvulkan.so
+      '';
+
+      description = "Hybrid and versatile game engine";
+    }
+    // attrs
+  );
+
+  fteqw-dedicated = import ./generic.nix (
+    rec {
+      pname = "fteqw-dedicated";
+      releaseFile = "fteqw-sv";
+
+      buildFlags = [ "sv-rel" ];
+
+      buildInputs = [
+        gnutls
+        zlib
+      ];
+
+      postFixup = ''
+        patchelf $out/bin/${pname} \
+          --add-needed ${gnutls}/lib/libgnutls.so \
+      '';
+
+      description = "Dedicated server for FTEQW";
+    }
+    // attrs
+  );
+
+  fteqcc = import ./generic.nix (
+    {
+      pname = "fteqcc";
+
+      buildFlags = [ "qcc-rel" ];
+
+      buildInputs = [
+        zlib
+      ];
+
+      description = "User friendly QuakeC compiler";
+    }
+    // attrs
+  );
+}

pkgs/games/fteqw/generic.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  libopus,
+  xorg,
+  pname,
+  releaseFile ? pname,
+  buildFlags,
+  buildInputs,
+  nativeBuildInputs ? [ ],
+  postFixup ? "",
+  description,
+  ...
+}:
+
+stdenv.mkDerivation {
+  inherit
+    pname
+    buildFlags
+    buildInputs
+    nativeBuildInputs
+    postFixup
+    ;
+  version = "0-unstable-2025-06-25";
+
+  src = fetchFromGitHub {
+    owner = "fte-team";
+    repo = "fteqw";
+    rev = "41f35720eda2d1e54d039975db28f46d68a963cb";
+    hash = "sha256-g8dKNRHAZvNfCT3ciDSyKJVqjENml39k26NqkP7sQvA=";
+  };
+
+  makeFlags = [
+    "PKGCONFIG=$(PKG_CONFIG)"
+    "-C"
+    "engine"
+  ];
+
+  enableParallelBuilding = true;
+  postPatch = ''
+    substituteInPlace ./engine/Makefile \
+      --replace "I/usr/include/opus" "I${libopus.dev}/include/opus"
+    substituteInPlace ./engine/gl/gl_vidlinuxglx.c \
+      --replace 'Sys_LoadLibrary("libXrandr"' 'Sys_LoadLibrary("${xorg.libXrandr}/lib/libXrandr.so"'
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 engine/release/${releaseFile} $out/bin/${pname}
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    inherit description;
+    homepage = "https://fteqw.org";
+    longDescription = ''
+      FTE is a game engine baed on QuakeWorld able to
+      play games such as Quake 1, 2, 3, and Hexen 2.
+      It includes various features such as extended map
+      limits, vulkan and OpenGL renderers, a dedicated
+      server, and fteqcc, for easier QuakeC development
+    '';
+    maintainers = with maintainers; [ necrophcodr ];
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}