push sheeet

pkgs/os-specific/darwin/apple-source-releases/libffi/package.nix

@@ -0,0 +1,124 @@
+{
+  lib,
+  autoreconfHook,
+  dejagnu,
+  mkAppleDerivation,
+  stdenv,
+  testers,
+  texinfo,
+
+  # test suite depends on dejagnu which cannot be used during bootstrapping
+  # dejagnu also requires tcl which can't be built statically at the moment
+  doCheck ? !(stdenv.hostPlatform.isStatic),
+}:
+
+mkAppleDerivation (finalAttrs: {
+  releaseName = "libffi";
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+    "info"
+  ];
+
+  patches = [
+    # Clang 18 requires that no non-private symbols by defined after cfi_startproc. Apply the upstream libffi fix.
+    ./patches/llvm-18-compatibility.patch
+    # Fix a memory leak when using the trampoline dylib. See https://github.com/libffi/libffi/pull/621#discussion_r955298301.
+    ./patches/fix-tramponline-memory-leak.patch
+    # Fix automake-18.18 compatibility, https://github.com/libffi/libffi/issues/853#issuecomment-2909994482
+    ./patches/automake-1.18.patch
+  ];
+
+  # Make sure libffi is using the trampolines dylib in this package not the system one.
+  postPatch = ''
+    substituteInPlace src/closures.c --replace-fail /usr/lib "$out/lib"
+  '';
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [
+    autoreconfHook
+    texinfo
+  ];
+
+  configurePlatforms = [
+    "build"
+    "host"
+  ];
+
+  configureFlags = [
+    "--with-gcc-arch=generic" # no detection of -march= or -mtune=
+    "--enable-builddir=build"
+  ];
+
+  postConfigure = ''
+    # Use Apple’s configuration instead of the one generated by the `configure` script.
+    cp darwin/include/fficonfig_${stdenv.hostPlatform.darwinArch}.h build/fficonfig.h
+    cp darwin/include/ffitarget_${
+      if stdenv.hostPlatform.isAarch64 then "arm64" else "x86"
+    }.h build/include/ffitarget.h
+    # Use `macCatalyst` instead of `iosmac` to avoid errors due to invalid availability annotations.
+    substitute darwin/include/ffi.h build/include/ffi.h \
+      --replace-fail iosmac macCatalyst
+  '';
+
+  postBuild = lib.optionalString stdenv.hostPlatform.isAarch64 ''
+    $CC -Os -Wl,-allowable_client,! -Wl,-not_for_dyld_shared_cache -Wl,-no_compact_unwind \
+      src/aarch64/trampoline.S -dynamiclib -o libffi-trampolines.dylib \
+      -Iinclude -Ibuild -Ibuild/include \
+      -install_name "$out/lib/libffi-trampoline.dylib" -Wl,-compatibility_version,1 -Wl,-current_version,1
+  '';
+
+  postInstall =
+    # The Darwin SDK puts the headers in `include/ffi`. Add a symlink for compatibility.
+    ''
+      ln -s "$dev/include" "$dev/include/ffi"
+    ''
+    # Install the trampoline dylib since it is build manually.
+    + lib.optionalString stdenv.hostPlatform.isAarch64 ''
+      cp libffi-trampolines.dylib "$out/lib/libffi-trampolines.dylib"
+    '';
+
+  preCheck = ''
+    # The tests use -O0 which is not compatible with -D_FORTIFY_SOURCE.
+    NIX_HARDENING_ENABLE=''${NIX_HARDENING_ENABLE/fortify3/}
+    NIX_HARDENING_ENABLE=''${NIX_HARDENING_ENABLE/fortify/}
+  '';
+
+  dontStrip = stdenv.hostPlatform != stdenv.buildPlatform; # Don't run the native `strip' when cross-compiling.
+
+  inherit doCheck;
+
+  nativeCheckInputs = [ dejagnu ];
+
+  passthru = {
+    tests = {
+      pkg-config = testers.hasPkgConfigModules {
+        package = finalAttrs.finalPackage;
+      };
+    };
+  };
+
+  meta = {
+    description = "Foreign function call interface library";
+    longDescription = ''
+      The libffi library provides a portable, high level programming
+      interface to various calling conventions.  This allows a
+      programmer to call any function specified by a call interface
+      description at run-time.
+
+      FFI stands for Foreign Function Interface.  A foreign function
+      interface is the popular name for the interface that allows code
+      written in one language to call code written in another
+      language.  The libffi library really only provides the lowest,
+      machine dependent layer of a fully featured foreign function
+      interface.  A layer must exist above libffi that handles type
+      conversions for values passed between the two languages.
+    '';
+    homepage = "https://github.com/apple-oss-distributions/libffi/";
+    license = lib.licenses.mit;
+    pkgConfigModules = [ "libffi" ];
+  };
+})

pkgs/os-specific/darwin/apple-source-releases/libffi/patches/automake-1.18.patch

@@ -0,0 +1,14 @@
+The hunk is used from https://github.com/libffi/libffi/issues/853#issuecomment-2909994482
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -4,6 +4,10 @@ AUTOMAKE_OPTIONS = foreign subdir-objects
+ 
+ ACLOCAL_AMFLAGS = -I m4
+ 
++# Alias required by AX_ENABLE_BUILDDIR / config-ml
++.PHONY: all-configured
++all-configured: all
++
+ SUBDIRS = include testsuite man
+ if BUILD_DOCS
+ ## This hack is needed because it doesn't seem possible to make a

pkgs/os-specific/darwin/apple-source-releases/libffi/patches/fix-tramponline-memory-leak.patch

@@ -0,0 +1,13 @@
+diff --git a/src/closures.c b/src/closures.c
+index 01f9950cd0..1dfd375cff 100644
+--- a/src/closures.c
++++ b/src/closures.c
+@@ -329,7 +329,7 @@
+     table->next->prev = table->prev;
+ 
+   /* Deallocate pages */
+-  vm_deallocate (mach_task_self (), table->config_page, PAGE_MAX_SIZE * 2);
++  vm_deallocate (mach_task_self (), table->config_page, FFI_TRAMPOLINE_ALLOCATION_PAGE_COUNT * PAGE_MAX_SIZE);
+ 
+   /* Deallocate free list */
+   free (table->free_list_pool);

pkgs/os-specific/darwin/apple-source-releases/libffi/patches/llvm-18-compatibility.patch

@@ -0,0 +1,34 @@
+diff --git a/src/aarch64/sysv.S b/src/aarch64/sysv.S
+index eeaf3f8..329889c 100644
+--- a/src/aarch64/sysv.S
++++ b/src/aarch64/sysv.S
+@@ -76,8 +76,8 @@ SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.  */
+    x5 closure
+ */
+ 
+-	cfi_startproc
+ CNAME(ffi_call_SYSV):
++	cfi_startproc
+ 	/* Sign the lr with x1 since that is where it will be stored */
+ 	SIGN_LR_WITH_REG(x1)
+ 
+@@ -268,8 +268,8 @@ CNAME(ffi_closure_SYSV_V):
+ #endif
+ 
+ 	.align	4
+-	cfi_startproc
+ CNAME(ffi_closure_SYSV):
++	cfi_startproc
+ 	SIGN_LR
+ 	stp     x29, x30, [sp, #-ffi_closure_SYSV_FS]!
+ 	cfi_adjust_cfa_offset (ffi_closure_SYSV_FS)
+@@ -500,8 +500,8 @@ CNAME(ffi_go_closure_SYSV_V):
+ #endif
+ 
+ 	.align	4
+-	cfi_startproc
+ CNAME(ffi_go_closure_SYSV):
++	cfi_startproc
+ 	stp     x29, x30, [sp, #-ffi_closure_SYSV_FS]!
+ 	cfi_adjust_cfa_offset (ffi_closure_SYSV_FS)
+ 	cfi_rel_offset (x29, 0)