push sheeet

pkgs/os-specific/linux/minimal-bootstrap/gnused/common.nix

@@ -0,0 +1,12 @@
+{ lib }:
+
+{
+  meta = with lib; {
+    description = "GNU sed, a batch stream editor";
+    homepage = "https://www.gnu.org/software/sed";
+    license = licenses.gpl3Plus;
+    teams = [ teams.minimal-bootstrap ];
+    mainProgram = "sed";
+    platforms = platforms.unix;
+  };
+}

pkgs/os-specific/linux/minimal-bootstrap/gnused/default.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  buildPlatform,
+  hostPlatform,
+  fetchurl,
+  bash,
+  gnumake,
+  tinycc,
+  gnused,
+  gnugrep,
+  gnutar,
+  gzip,
+}:
+
+let
+  inherit (import ./common.nix { inherit lib; }) meta;
+  pname = "gnused";
+  # last version that can be bootstrapped with our slightly buggy gnused-mes
+  version = "4.2";
+
+  src = fetchurl {
+    url = "mirror://gnu/sed/sed-${version}.tar.gz";
+    hash = "sha256-20XNY/0BDmUFN9ZdXfznaJplJ0UjZgbl5ceCk3Jn2YM=";
+  };
+in
+bash.runCommand "${pname}-${version}"
+  {
+    inherit pname version meta;
+
+    nativeBuildInputs = [
+      gnumake
+      tinycc.compiler
+      gnused
+      gnugrep
+      gnutar
+      gzip
+    ];
+
+    passthru.tests.get-version =
+      result:
+      bash.runCommand "${pname}-get-version-${version}" { } ''
+        ${result}/bin/sed --version
+        mkdir ''${out}
+      '';
+  }
+  ''
+    # Unpack
+    tar xzf ${src}
+    cd sed-${version}
+
+    # Configure
+    export CC="tcc -B ${tinycc.libs}/lib"
+    export LD=tcc
+    ./configure \
+      --build=${buildPlatform.config} \
+      --host=${hostPlatform.config} \
+      --disable-shared \
+      --disable-nls \
+      --disable-dependency-tracking \
+      --prefix=$out
+
+    # Build
+    make AR="tcc -ar"
+
+    # Install
+    make install
+  ''

pkgs/os-specific/linux/minimal-bootstrap/gnused/mes.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  buildPlatform,
+  hostPlatform,
+  fetchurl,
+  bash,
+  gnumake,
+  tinycc,
+}:
+
+let
+  inherit (import ./common.nix { inherit lib; }) meta;
+  pname = "gnused-mes";
+  # last version that can be compiled with mes-libc
+  version = "4.0.9";
+
+  src = fetchurl {
+    url = "mirror://gnu/sed/sed-${version}.tar.gz";
+    sha256 = "0006gk1dw2582xsvgx6y6rzs9zw8b36rhafjwm288zqqji3qfrf3";
+  };
+
+  # Thanks to the live-bootstrap project!
+  # See https://github.com/fosslinux/live-bootstrap/blob/1bc4296091c51f53a5598050c8956d16e945b0f5/sysa/sed-4.0.9/sed-4.0.9.kaem
+  makefile = fetchurl {
+    url = "https://github.com/fosslinux/live-bootstrap/raw/1bc4296091c51f53a5598050c8956d16e945b0f5/sysa/sed-4.0.9/mk/main.mk";
+    sha256 = "0w1f5ri0g5zla31m6l6xyzbqwdvandqfnzrsw90dd6ak126w3mya";
+  };
+in
+bash.runCommand "${pname}-${version}"
+  {
+    inherit pname version meta;
+
+    nativeBuildInputs = [
+      gnumake
+      tinycc.compiler
+    ];
+
+    passthru.tests.get-version =
+      result:
+      bash.runCommand "${pname}-get-version-${version}" { } ''
+        ${result}/bin/sed --version
+        mkdir ''${out}
+      '';
+  }
+  ''
+    # Unpack
+    ungz --file ${src} --output sed.tar
+    untar --file sed.tar
+    rm sed.tar
+    cd sed-${version}
+
+    # Configure
+    cp ${makefile} Makefile
+    catm config.h
+
+    # Build
+    make \
+      CC="tcc -B ${tinycc.libs}/lib" \
+      LIBC=mes
+
+    # Install
+    make install PREFIX=$out
+  ''