push sheeet

pkgs/os-specific/linux/xone/default.nix

@@ -0,0 +1,48 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  kernel,
+  kernelModuleMakeFlags,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xone";
+  version = "0.4.8";
+
+  src = fetchFromGitHub {
+    owner = "dlundqvist";
+    repo = "xone";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-EXJBqzO4e2SJGrPvB0VYzIQf09uo5OfNdBQw5UqskYg=";
+  };
+
+  setSourceRoot = ''
+    export sourceRoot=$(pwd)/${finalAttrs.src.name}
+  '';
+
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  makeFlags = kernelModuleMakeFlags ++ [
+    "-C"
+    "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
+    "M=$(sourceRoot)"
+    "VERSION=${finalAttrs.version}"
+  ];
+
+  enableParallelBuilding = true;
+  buildFlags = [ "modules" ];
+  installFlags = [ "INSTALL_MOD_PATH=${placeholder "out"}" ];
+  installTargets = [ "modules_install" ];
+
+  meta = with lib; {
+    description = "Linux kernel driver for Xbox One and Xbox Series X|S accessories";
+    homepage = "https://github.com/dlundqvist/xone";
+    license = licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      rhysmdnz
+      fazzi
+    ];
+    platforms = platforms.linux;
+    broken = kernel.kernelOlder "6";
+  };
+})